100 ! THIS IS A TEXT EDITOR. IT CAN DO ONLY TWO THINGS...
110 ! LOCATE, AND FIND-REPLACE. TYPE FILENAME AFTER THE #.
120 ! THEN LOCATE: JUST TYPE THE STRING TO BE LOCATED
130 !      FIND REPLACE: OLD STRING_NEW STRING
140 ! EX. TO LOCATE ALL OCCURENCES OF LET JUST TYPY LET AFTER
150 ! THE *. TO REPLACE FNF$ WITH FNF1% JUST TYPE FNF$_FNF1% AFTER
160 ! THEN *. TO EXIT TYPE A LINE-FEED. A # WILL APPEAR. TYPE
170 ! /C--CHAIN, /O--OLD, OR /S--STOP.
180 ! YOU COULD ALSO TYPE ANOTHER FILENAME.
190 REM EDIT CLARK BAKER 1/72 C.O.G.
210 OPEN "KB:" AS FILE 3%
220 PRINT 'EDIT VER 1A'
230 T$=NUM$(ASCII(SYS(CHR$(6%)+CHR$(9%)))/2%):T$="0"+
	MID(T$,2%,LEN(T$)-2%):T$="EDIT"+RIGHT(T$,LEN(T$)-1%)+
	".TMP"
240 ON ERROR GO TO 330
250 PRINT "#";
260 INPUT LINE #3%,C$:C$=LEFT(C$,LEN(C$)-2%)
270 IF C$="/S" THEN 800
280 IF C$="/O" THEN CHAIN F$ 32767
290 IF C$="/C" THEN CHAIN F$
300 F$=C$
310 IF INSTR(1%,F$,".")=0% THEN F$=F$+".BAS"
320 OPEN F$ FOR INPUT AS FILE 4%:CLOSE 4%:Q9$=LEFT(F$,INSTR(1%,
	F$,":")):GO TO 360
330 E$=SYS(CHR$(6%)+CHR$(9%)+CHR$(ERR)+CHR$(0%))
340 PRINT MID(E$,3%,INSTR(5%,E$,CHR$(0%))-3%)
350 RESUME 250
360 A$=SYS(CHR$(0%)):PRINT "*";
370 INPUT LINE #3%,L$
380 A%=ASCII(RIGHT(L$,LEN(L$)))
390 IF A%=0% THEN 240
400 L$=LEFT(L$,LEN(L$)-2%)
410 I%=INSTR(1%,L$,"_")
420 IF I% THEN 530
430 O$=L$
440 PRINT "LOCATING: ";O$
450 OPEN F$ FOR INPUT AS FILE 2%
460 ON ERROR GO TO 500
470 INPUT LINE #2%,L$
480 IF INSTR(1%,L$,O$) THEN PRINT L$;
490 GO TO 470
500 IF ERR<>11% THEN PRINT "ERR #";ERR:RESUME 360
510 CLOSE 2
520 RESUME 360
530 O$=LEFT(L$,I%-1)
540 N$=RIGHT(L$,I%+1)
550 N%=LEN(N$)
560 O%=LEN(O$)
570 IF LEN(O$)=0% THEN PRINT "STRING HAS NO LENGTH":GO TO 360
580 OPEN Q9$+T$ FOR OUTPUT AS FILE 2%
590 OPEN F$ FOR INPUT AS FILE 1
600 PRINT O$;" WAS REPLACED BY ";N$;
610 ON ERROR GO TO 730
620 C%=0%
630 INPUT LINE #1,L$
640 S%=1%
650 I%=INSTR(S%,L$,O$)
660 IF I%=0% THEN 710
670 L$=LEFT(L$,I%-1%)+N$+RIGHT(L$,I%+O%)
680 C%=C%+1%
690 S%=I%+N%
700 GO TO 650
710 PRINT #2%,L$;
720 GO TO 630
730 IF ERR<>11% THEN PRINT "ERR #";ERR: GO TO 360
740 PRINT #2%,CHR$(26%);
750 PRINT C%;"TIMES."
760 CLOSE 1,2%
770 KILL F$
780 NAME Q9$+T$ AS F$
790 RESUME 360
800 CLOSE 3%
810 END