1	!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
	!!!!!	PROJECT DELTA	15-MAR-73	!!!!!
2	!!!!! PUNCH STRING ON PERFORATED TAPE	!!!!!
3	!!!!! 					!!!!!
4	!!!!! ONE OF THREE FORMATS:		!!!!!
5	!!!!!	1]  SENTENCE STRUCTURED, IE.;	!!!!!
6	!!!!!	  CAPITAL FIRST LETTER AND PERIOD. !!
7	!!!!!	2]  ALL CAPITALS.		!!!!!
8	!!!!!	3]  ALL SMALL LETTERS.		!!!!!
9	!!!!! 		BY PHIL ZUMSTEG		!!!!!
	!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
10 OPEN'PUNCH.MAT[1,2]' AS FILE 3%:DIM#3%,P%(95%,4%):
	OPEN'KB:' AS FILE 1% RECORDSIZE 512%:FIELD #1%, 512% AS I$
12 DIM S%(72%)
20 PRINT'     CREAT1  VER 5-C'
30 PRINT:INPUT'INSTRUCTIONS';Q$:
	IF Q$='NO' THEN 60 ELSE IF Q$='YES' THEN 40 ELSE 
	PRINT'DOES NOT COMPUTE...':GOTO30
40 OPEN'CREAT1.INS[1,3]' FOR OUTPUT AS FILE 2%:FIELD#2%, 512% AS I1$
45 ON ERROR GOTO 60
50 GET#2%:LSETI$=I1$:N%=INSTR(1%,I$,CHR$(26%)):I$=LEFT(I$,N%):
	PRINTI$
60 PRINT:INPUT'STRING, FORMAT [1,2,3]';S$,F%:X%=0%:
	IF F%=0% THEN PRINT'BAD FORMAT':GOTO60
65 PRINT'TURN THE PUNCH ON...':SLEEP(5%):
	PRINTCHR$(0%);FORX%=1%TO25%:ON F% GOTO 70,80,90
70 CHANGE S$ TO S%:FOR C%=1% TO S%(0%)
76 IF S%(C%)>=65% AND S%(C%)<=90% THEN GOTO 77 ELSE
	PRINT CHR$(P%((S%(C%)-32%),P1%));FORP1%=0%TO4%:GOTO78
77 IF X%=1% THEN PRINT CHR$(P%(S%(C%),P1%));FORP1%=0%TO4% ELSE
	PRINT CHR$(P%((S%(C%)-32%),P1%));FORP1%=0%TO4%:X%=1%
78 PRINT CHR$(0%);:NEXTC%:GOTO110
80 CHANGE S$ TO S%:FOR C%=1% TO S%(0%):
	S%(C%)=(S%(C%)-32%) IF S%(C%)<65% OR S%(C%)>90%
84 IF S%(C%)<0% OR S%(C%)>99% THEN S%(C%)=0%

86 PRINT CHR$(P%(S%(C%),P1%)); FOR P1%=0% TO 4%:
	PRINT CHR$(0%);:NEXT C%:GOTO110
90 CHANGE S$ TO S%:FOR C%=1% TO S%(0%):
	PRINT CHR$(P%(S%(C%)-32%,P1%)); FOR P1%=0% TO 4%:
	PRINT CHR$(0%);:NEXT C%
110 PRINTCHR$(0%);FORX%=1%TO25%:PRINT'PUNCH EXECUTED'
120 INPUT'ANOTHER PUNCH';Q$:IF Q$='YES' THEN 60
200 CLOSE 1%,2%,3%
9999 END
KEY