10 !THIS PROGRAM WRITTEN BY ELBERT C GREYNOLDS
   !REVISED AND MODIFIED BY DARRYL JOHNSON AND RICHARD D'ANGELO
   !BENTLEY COLLEGE OCTOBER 1972
20 PRINT:INPUT "WHAT IS THE REDEMPTION OR PAR VALUE OF THE BONDS";M
30 PRINT:INPUT "HOW MANY INTEREST PAYMENTS PER YEAR ON THE BONDS";A1
40 PRINT:INPUT "WHAT IS THE ANNUAL INTEREST RATE ON THE BONDS";A
50 PRINT:INPUT "HOW MANY INTEREST PAYMENTS REMAIN ON THE BONDS";N
60 PRINT:INPUT "HOW MUCH WAS PAID FOR THE BONDS";V
70 P=A*M/A1
80 PRINT:PRINT
90 I=0
100 I=I+.01
110 GOSUB 400
120 IF X=V THEN 340
130 IF X>V THEN 100
140 I=I-.01
150 I=I+.001
160 GOSUB 400
170 IF X=V THEN 340
180 IF X>V THEN 150
190 I=I-.001
200 I=I+.0001
210 GOSUB 400
220 IF X=V THEN 340
230 IF X>V THEN 200
240 I=I-.0001
250 I=I+.00001
260 GOSUB 400
270 IF X=V THEN 340
280 IF X>V THEN 250
290 I=I-.00001
300 I=I+.000001
310 GOSUB 400
320 IF X=V THEN 340
330 IF X>V THEN 300
340 I=I*100
350 A$="A YIELD OF ###.##% PER INTEREST PERIOD RETURNS A"
360 B$="CALCULATED BOND VALUE OF $$##,###.## COMPARED TO"
370 C$="THE ACTUAL VALUE OF YOUR BONDS $$##,###.##
380 PRINT USING A$,I:PRINT USING B$,X:PRINT USING C$,V
390 GOTO 420
400 X=(M*(1/((1+I)^N)))+(P*((1-(1+I)^(-N)))/I)
410 RETURN 
420 END