10 !    OVERHEAD VARIANCE PROGRAM
   !         PROGRAMMED BY
   !RICHARD D'ANGELO & DARRYL JOHNSON
   !   BENTLEY COLLEGE NOVEMBER '72
20 PRINT:PRINT "IS THE VARIANCE ANALYSIS BASED ON UNITS OR":
          PRINT "HOURS";:INPUT A$
30 IF LEFT(A$,3)="HOU" THEN B$="HOURS"
                        ELSE IF LEFT(A$,3)="UNI" THEN B$=
                             "UNITS"
40 IF B$="HOURS" OR B$="UNITS" THEN 70
50 PRINT "PLEASE ANSWER 'UNITS' OR 'HOURS'":GO TO 20
70 PRINT:PRINT "HOW MANY "B$;" AT NORMAL CAPACITY";:INPUT T
80 PRINT:PRINT "WHAT IS THE VARIABLE FACTORY OVERHEAD":
          PRINT "AT NORMAL CAPACITY IN DOLLARS";: INPUT T1
90 PRINT:PRINT "WHAT IS THE FIXED FACTORY OVERHEAD":
          PRINT "AT NORMAL CAPACITY IN DOLLARS";:INPUT T2
100 PRINT:PRINT "WHAT IS THE NUMBER OF ACTUAL ";B$;:INPUT T3
110 PRINT:PRINT "WHAT IS THE TOTAL ACTUAL OVERHEAD IN DOLLARS";:INPUT T4
120 PRINT:PRINT "WHAT IS THE STANDARD (OR ALLOWED) NUMBER":
          PRINT "OF ";B$;" AT THIS LEVEL OF PRODUCTION";:INPUT T6
130 S=INT((T1+T2)/T*100+.5)/100:P=INT(T6*S*100+.5)/100:
      V=INT((T4-P)*100+.5)/100
140 S1=INT(T1/T*100+.5)/100:Q=INT(T6*S1*100+.5)/100:
       P1=INT((T2+Q)*100+.5)/100:V1=INT((T4-P1)*100+.5)/100
150 V2=INT((P1-P)*100+.5)/100
160 Q1=INT(T3*S1*100+.5)/100:P2=INT((T2+Q1)*100+.5)/100:
       V3=INT((T4-P2)*100+.5)/100
170 P3=INT(T3*S*100+.5)/100:V4=INT((P2-P3)*100+.5)/100
180 V5=INT((P3-P)*100+.5)/100
190 V6=INT((T4-P2)*100+.5)/100
200 V7=INT((P2-P1)*100+.5)/100
210 S2=INT(T2/T*100+.5)/100:R=(T3*S2*100+.5)/100:
       R1=INT(T6*S2*100+.5)/100:V8=INT((R-R1)*100+.5)/100
220 X=INT(T*S2*100+.5)/100:X1=INT(T3*S2*100+.5)/100:
       V9=INT((X-X1)*100+.5)/100
230 A$=" (UNFAVORABLE)":A1$=" (FAVORABLE)":
        P$="$$###,###.##":P1$="###,###.##"
240 PRINT FOR X=1 TO 5
250 PRINT "OVERALL OR NET OVERHEAD VARIANCE";:
          IF V<0 THEN PRINT A1$; ELSE PRINT A$;
260 PRINT TAB(55);:PRINT USING P$,ABS(V)
270 PRINT FOR X=1 TO 3:PRINT TAB(25);"TWO-VARIANCE METHOD":
       PRINT:PRINT "CONTROLLABLE VARIANCE";:
        IF V1<0 THEN PRINT A1$; ELSE PRINT A$;
280 PRINT TAB(45);:PRINT USING P$,ABS(V1)
290 PRINT:PRINT "VOLUME VARIANCE";:
         IF V2<0 THEN PRINT A1$; ELSE PRINT A$;
300 PRINT TAB(47);:PRINT USING P1$,ABS(V2)
310 PRINT FOR X=1 TO 3:PRINT TAB(24);"THREE-VARIANCE METHOD":
          PRINT:PRINT "SPENDING VARIANCE";:
           IF V3<0 THEN PRINT A1$; ELSE PRINT A$;
320 PRINT TAB(45);:PRINT USING P$,ABS(V3)
330 PRINT:PRINT "IDLE CAPACITY VARIANCE";:
          IF V4<0 THEN PRINT A1$; ELSE PRINT A$;
340 PRINT TAB(47);: PRINT USING P1$,ABS(V4)
350 PRINT:PRINT "EFFICIENCY VARIANCE";:
          IF V5<0 THEN PRINT A1$; ELSE PRINT A$;
360 PRINT TAB(47);:PRINT USING P1$,ABS(V5)
370 PRINT FOR X=1 TO 3:PRINT TAB(25);"FOUR-VARIANCE METHOD":
       PRINT:PRINT "SPENDING VARIANCE";:
         IF V6<0 THEN PRINT A1$; ELSE PRINT A$;
380 PRINT TAB(45);:PRINT USING P$,ABS(V6)
390 PRINT:PRINT "VARIABLE EFFICIENCY VARIANCE";:
          IF V7<0 THEN PRINT A1$; ELSE PRINT A$;
400 PRINT TAB(47);:PRINT USING P1$,ABS(V7)
410 PRINT:PRINT "FIXED EFFICIENCY VARIANCE";:
          IF V8<0 THEN PRINT A1$; ELSE PRINT A$;
420 PRINT TAB(47);:PRINT USING P1$,ABS(V8)
430 PRINT:PRINT "IDLE CAPACITY VARIANCE";:
          IF V9<0 THEN PRINT A1$; ELSE PRINT A$;
440 PRINT TAB(47);:PRINT USING P1$,ABS(V9)
450 END