8999 REM REVISED MARCH 1972 ANDY ROTH  C.C.G.
9000 REM *****  FNCTS  *****  MATHEMATICS PROGRAM  *****
9001 REM *****  VERSION 1  *****  7/31/69  *****
9002 REM  TRIG FUNCTIONS OF A COMPLEX ARGUMENT
9003 PRINT "ENTER THE REAL AND IMAGINARY PARTS OF THE ARGUMENT"
9004 ON ERROR GO TO 9500
9005 INPUT"RE(Z)=";X
9006INPUT "IM(Z)=";Y
9007 PRINT"COSH,SINH, AND TANH ARE THE HYPERBOLIC FUNCTIONS"
9008 PRINT
9009 REM FNS, FNC ARE SING, COSH OF REAL VARIABLE.  THEY ARE USED
9010 REM IN FINDING THE OTHER FUNCTIONS.
9011 DEF FNS(W)=(EXP(W)-EXP(-W))/2
9012 DEF FNC(W)=(EXP(W)+EXP(-W))/2
9013 REM NEXT 3 LINES GIVE SINE OF COMPLEX VARIABLE
9014  S1=SIN(X)*FNC(Y)
9015  S2=COS(X)*FNS(Y)
9016 PRINT "SIN(Z):  RE=";S1,"IM=";S2
9017 REM NEXT 3 LINES GIVE COSINE OF COMPLEX VARIABLE
9018  C1=COS(X)*FNC(Y)
9019  C2=-SIN(X)*FNS(Y)
9020 PRINT "COS(Z):  RE=";C1,"IM=";C2
9021 REM NEXT 4 LINES GIVE TANGENT OF COMPLEX VARIABLE
9022 D=COS(2*X)+FNC(2*Y)
9023  T1=SIN(2*X)/D
9024  T2=FNS(2*Y)/D
9025 PRINT"TAN(Z):  RE=";T1,"IM=";T2
9026 REM NEXT 3 LINES GIVE HYPERBOLIC SINE OF COMPLEX VAR.
9027  S3=FNS(X)*COS(Y)
9028  S4=FNC(X)*SIN(Y)
9029 PRINT "SINH(Z): RE=";S3,"IM=";S4
9030 REM NEXT THREE LINES GIVE HYPERBOLIC COSINE OF COMPLEX VAR.
9031  C3=FNC(X)*COS(Y)
9032  C4=FNS(X)*SIN(Y)
9033 PRINT "COSH(Z): RE=";C3,"IM=";C4
9034 REM NEXT 4 LINES GIVE HYPERBOLIC TANGENT OF COMPLEX VARIABLE
9035 E=FNC(2*X)+COS(2*Y)
9036 T3=FNS(2*X)/E
9037 T4=SIN(2*Y)/E
9038 PRINT "TANH(Z): RE=";T3,"IM=";T4
9499 GO TO 9999
9500 PRINT" YOU MADE A MISTAKE, REENTER":RESUME 9005
9999 END