500 REM *******ROMINT ******MATHEMATICS PROGRAM****(HP)
510 REM VERSION 1  7/31/69
520 REM REVISED   APRIL 1972  ANDY ROTH  C.C.G.
530 REM ROMBERG INTEGRATION OF A FUNCTION
1000 INPUT "HAVE YOU DEFINED YOUR FUNCTION";D$
1010 IF D$="YES" THEN 1110
1030 PRINT"PLEASE ENTER YOUR FUNCTION IN THE FOLLOWING MANNER:"
1038 PRINT "AFTER THE FIRST READY"
1040 PRINT"PLEASE TYPE '1065 DEF FNF(X)=<YOUR FUNCTION>'"
1050 PRINT"YOUR FUNCTION SHOULD BE LIKE 'SIN(X) OR X^2'"
1060 PRINT "HIT 'RETURN' AND THEN TYPE'RUNNH'"
1063 GO TO 1370
1065 DEF FNF(X)=SIN(X)
1110 DIM Z(20)
1120 INPUT"WHAT IS THE LOWER LIMIT OF INTEGRATION";A
1130 INPUT"WHAT IS THE UPPER LIMIT OF INTEGRATION";B
1140 PRINT"WHAT IS THE ORDER OF INTEGRATION (USUALLY A 3 OR 4)"
1150 INPUT"IS SUFFICIENT";N
1160  Z7=(A-B)/2
1170  Z8=1
1180 Z(1)=(FNF(A)+FNF(B))/2
1190 FOR Z5=1 TO N
1200  Z6=0
1210 FOR Z9=1 TO 2*Z8-1 STEP 2
1220  Z6=Z6+FNF(A+Z7*Z9)
1230 NEXT Z9
1240  Z(Z5+1)=(Z6/Z8+Z(Z5))/2
1250  Z6=1
1260 FOR Z9=Z5 TO 1 STEP -1
1270  Z6=4*Z6
1280  Z(Z9)=Z(Z9+1)+(Z(Z9+1)-Z(Z9))/(Z6-1)
1290 NEXT Z9
1300  Z8=Z8*2
1310  Z7=Z7/2
1320 NEXT Z5
1330  V=Z(1)*(A-B)
1340 PRINT "INTEGRAL="V
1370 END