9000 REM *****BALSHT*****BUSINESS PROGRAM
9003 REM BALSHT**********VERSION #1 (7/31/69)*****PROFORMA INCOME STMT
9006 REM *****************************************& BALANCE SHEET *******
9009 REM
9012 PRINT "*  PROFORMA INCOME STATEMENT & BALANCE SHEET  *"
9015 PRINT
9018 PRINT "THIS PROGRAM WILL PROVIDE A LISTING OF A SIMPLE PROFORMA INCOME STATE-"
9021 PRINT "MENT AND BALANCE SHEET."
9024 PRINT
9027 PRINT "DO YOU WISH TO ENTER YOUR DATA FROM THE TELETYPE AS IT BECOMES"
9030 PRINT "NECESSARY, OR INTERNALLY WITH DATA-STATEMENTS? (ENTER 'T' OR 'D')";
9033 INPUT A$
9036 PRINT
9039 IF A$="T" THEN 9060
9045 READ B1,B2,B4,B5,B6,S2,S3,R1,R2,R3,R6
9048 FOR J=1 TO 6
9051 READ L(J,1),L(J,2),L(J,3),L(J,4)
9054 NEXT J
9057 GOTO 9378
9060 PRINT "PLEASE ENTER THE FOLLOWING VALUES:"
9063 REM
9066 REM  B1 = BASE PERIOD SALES TOTAL
9069 REM  B2 = BASE PERIOD NET FIXED ASSETS
9072 REM  B4 = BASE PERIOD LONG-TERM DEBT REMAINING
9075 REM  B5 = BASE PERIOD TOTAL OWNER'S EQUITY
9078 REM  B6 = BASE PERIOD ACCUMULATED RETAINED EARNINGS
9081 REM  S2 = FEDERAL CORPORATE TAX RATE ON PROFIT
9084 REM  S3 = PROMISED PERIOD DIVIDENDS
9087 REM  R1 = AMOUNT OF CASH THE USER WISHES TO HOLD AFTER THE BASE
9090 REM       PERIOD
9093 REM  R2 = ACCOUNTS/RECEIVABLE TURNOVER
9096 REM  R3 = INVENTORY TURNOVER
9099 REM  R6 = ACCOUNTS/PAYABLE TURNOVER (I.E.  A/P AS % OF SALES)
9105 REM
9108 PRINT "WHAT IS THE BASE PERIOD'S TOTAL SALES";
9111 INPUT B1
9114 PRINT
9117 PRINT "WHAT IS THE NET FIXED ASSETS FOR THE BASE PERIOD";
9120 INPUT B2
9123 PRINT
9126 PRINT "WHAT IS THE REMAINING LONG-TERM DEBT FOR THE BASE PERIOD";
9129 INPUT B4
9132 PRINT
9135 PRINT "WHAT IS THE TOTAL OWNER'S EQUITY FOR THE BASE PERIOD";
9138 INPUT B5
9141 PRINT
9144 PRINT "WHAT ARE THE RETAINED EARNINGS FOR THE BASE PERIOD";
9147 INPUT B6
9150 PRINT
9153 PRINT "WHAT IS THE FEDERAL CORPORATE TAX RATE";
9156 INPUT S2
9159 IF S2<1 THEN 9168
9162 PRINT "ENTER DECIMAL < 1 ";
9165 GOTO 9156
9168 PRINT
9171 PRINT "WHAT IS THE QUARTERLY PROJECTED AMOUNT OF DIVIDENDS";
9174 INPUT S3
9177 PRINT
9180 PRINT "WHAT AMOUNT OF CASH WOULD YOU LIKE TO RETAIN FOR EACH QUARTER";
9183 INPUT R1
9186 PRINT
9189 PRINT "WHAT IS THE NORMAL ACCOUNTS/RECEIVABLE TURNOVER";
9192 INPUT R2
9195 IF R2>1 THEN 9204
9198 PRINT "ENTER VALUE > 1";
9201 GOTO 9192
9204 PRINT
9207 PRINT "WHAT IS THE NORMAL INVENTORY TURNOVER";
9210 INPUT R3
9213 IF R3>1 THEN 9222
9216 PRINT "ENTER VALUE > 1";
9219 GOTO 9210
9222 PRINT
9225 PRINT "WHAT PERCENTAGE OF SALES ARE THE ACCOUNTS/PAYABLE (I.E., A/P TRNOVR)";
9228 INPUT R6
9231 IF R6<1 THEN 9240
9234 PRINT "ENTER A VALUE < 1 ";
9237 GOTO 9228
9240 PRINT
9246 R8=0
9249 IF R8<1 THEN 9258
9252 PRINT "ENTER A DECIMAL < 1";
9255 GOTO 9249
9258 PRINT
9261 PRINT "NOW ENTER FOUR VALUES FOR EACH QUESTION. EACH VALUE APPLIES TO THE RES-"
9264 PRINT"PECTIVE QUARTER:"
9267 REM
9270 REM  L(1,1 THRU 4) = ESTIMATED PERCENTAGE GROWTH IN SALES
9273 REM  L(2,1 THRU 4) = COST OF GOODS SOLD AS AN ESTIMATED % OF SALES
9276 REM  L(3,1 THRU 4) = GENERAL SELLING & ADMINISTRATIVE EXPENSE AS
9279 REM                  AN ESTIMATED % OF SALES
9282 REM  L(4,1 THRU 4) = ESTIMATED AMOUNT OF FIXED ASSET PURCHASES
9285 REM  L(5,1 THRU 4) = ESTIMATED AMOUNT OF FIXED ASSET RETIRED
9288 REM  L(6,1 THRU 4) = PLANNED PAYMENTS PERQUARTER ON DEBT
9291 REM
9294 PRINT "ENTER THE ESTMATED PERCENTAGE GROWTH IN SALES"
9297 INPUT L(1,1),L(1,2),L(1,3),L(1,4)
9300 IF L(1,1)<1 THEN 9309
9303 PRINT "ENTER DECIMALS < 1";
9306 GOTO 9297
9309 PRINT
9312 PRINT "ENTER THE COST OF GOODS SOLD AS AN ESTIMATED PERCENTAGE OF SALES"
9315 INPUT L(2,1),L(2,2),L(2,3),L(2,4)
9318 IF L(2,1)<1 THEN 9327
9321 PRINT "ENTER DECIMALS < 1";
9324 GOTO 9315
9327 PRINT
9330 PRINT "ENTER THE GENERAL SELLING & ADMINISTRATIVE EXPENSE AS A PERCENT OF SALES"
9333 INPUT L(3,1),L(3,2),L(3,3),L(3,4)
9336  IF L(3,1)<1 THEN 9343
9339 PRINT "ENTER DECIMALS < 1";
9342 GOTO 9333
9343 PRINT
9345 PRINT "ENTER THE ESTIMATED AMOUNT OF FIXED ASSET PURCHASES PER QUARTER"
9348 INPUT L(4,1),L(4,2),L(4,3),L(4,4)
9351 PRINT
9354 PRINT "ENTER THE ESTIMATED AMOUNT OF FIXED ASSET RETIREMENTS PER QUARTER"
9357 INPUT L(5,1),L(5,2),L(5,3),L(5,4)
9360 PRINT
9363 PRINT "ENTER THE PLANNED DEBT PAYMENTS PER QUARTER"
9366 INPUT L(6,1),L(6,2),L(6,3),L(6,4)
9369 PRINT
9372 DIM A(4),B(4),C(4),X(4),K(4),D(4),U(4),Z(4),G(4),H(4),F(4)
9375 DIM N(4),O(4),I(4),J(4),P(4),M(4),R(4),S(4),Y(4),W(4)
9378 PRINT
9381 C2=4
9396 PRINT "DO YOU WISH A BALANCE SHEET ONLY (TYPE '1'); AN INCOME STATEMENT"
9399 PRINT "(TYPE '2'); OR BOTH (TYPE '3')";
9402 INPUT K6
9405 PRINT
9444 B7=B4
9459 B8=B5
9465 R8=R8+1
9483 FOR X=1 TO C2
9486 A(X)=S3
9489 A9=B1*L(1,X)
9492 B1=B1+A9
9495 B(X)=B1
9498 C(X)=B(X)*L(2,X)
9501 X(X)=B(X)*L(3,X)
9504 K(X)=B(X)-(C(X)+X(X))
9507 D(X)=K(X)*S2
9510 U(X)=K(X)-D(X)
9513 E(X)=K(X)-D(X)-S3
9516 G(X)=B(X)/R2
9519 H(X)=B(X)/R3
9522 B2=B2+(L(4,X)-L(5,X))
9525 N(X)=B2
9528 O(X)=R1+N(X)+G(X)+H(X)
9531 I(X)=B(X)*R6
9534 J(X)=I(X)+D(X)
9537 B4=B4-L(6,X)
9540 B6=B6+E(X)
9543 S(X)=J(X)+B4+B5+B6
9546 T(X)=O(X)-S(X)
9549 IF T(X)>0 THEN 9558
9552 Z(X)=R1-T(X)
9555 GOTO 9582
9558 D1=R1*(B5+B6)
9561 Z(X)=R1
9564 D2=D1-(B4+T(X))
9567 IF D2<0 THEN 9576
9570 B4=B4+T(X)
9573 GOTO 9582
9576 B5=B5-D2
9579 B4=B4+(T(X)+D2)
9582 P(X)=B4
9585 M(X)=B5
9588 R(X)=B6
9591 F(X)=G(X)+H(X)+Z(X)
9594 S(X)=J(X)+P(X)+M(X)+R(X)
9597 O(X)=N(X)+G(X)+H(X)+Z(X)
9600 NEXT X
9603 Y(1)=P(1)-B7
9606 W(1)=M(1)-R8
9609 FOR X=2 TO C2
9612 Y(X)=P(X)-P(X-1)
9615 W(X)=M(X)-M(X-1)
9618 NEXT X
9621 PRINT
9624 PRINT "***********************************************************************"
9627 PRINT
9630 IF K6=1 THEN 9690
9633 PRINT
9636 PRINT "                                 *** INCOME STATEMENT ***"
9639 PRINT "                                 ------------------------"
9642 PRINT TAB(23);"QTR #1";TAB(35);"QTR #2";TAB(47);"QTR #3";TAB(60);"QTR #4"
9645 PRINT "SALES";TAB(23);B(1);TAB(35);B(2);TAB(47);B(3);TAB(60);B(4)
9648 PRINT "COST OF GOODS SOLD";TAB(23);C(1);TAB(35);C(2);TAB(47);C(3);
9651 PRINT TAB(60);C(4)
9654 PRINT "GS AND A EXPENSES"TAB(23);X(1);TAB(35);X(2);TAB(47);X(3);
9657 PRINT TAB(60);X(4)
9660 PRINT "PROFIT BEFORE TAX";TAB(23);K(1);TAB(35);K(2);TAB(47);K(3);
9663 PRINT TAB(60);K(4)
9666 PRINT
9669 PRINT "FED. INCOME TAX";TAB(23);D(1);TAB(35);D(2);TAB(47);D(3);
9672 PRINT TAB(60);D(4)
9675 PRINT "PROFIT AFTER TAX"TAB(23);U(1);TAB(35);U(2);TAB(47);U(3);
9679 PRINT TAB(60);U(4)
9681 PRINT "ANNUAL DIVIDENDS";TAB(23);A(1);TAB(35);A(2);TAB(47);A(3);
9684 PRINT TAB(60);A(4)
9687 PRINT
9690 PRINT
9691 PRINT "                    ---------------------------"
9693 PRINT
9696 IF K6=2 THEN 9829
9699 PRINT
9702 PRINT "                      *** BALANCE SHEET ***"
9705 PRINT "                      ---------------------"
9708 PRINT TAB(23);"QTR #1";TAB(35);"QTR #2";TAB(47);"QTR #3";TAB(60);"QTR #4"
9711 PRINT "CASH";TAB(23);Z(1);TAB(35);Z(2);TAB(47);Z(3);TAB(60);Z(4)
9714 PRINT"ACCOUNTS RECEIVABLE";TAB(23);G(1);TAB(35);G(2);TAB(47);G(3);
9717 PRINT TAB(60);G(4)
9720 PRINT "INVENTORY";TAB(23);H(1);TAB(35);H(2);TAB(47);H(3);
9723 PRINT TAB(60);H(4)
9726 PRINT "TOTAL CURRENT ASSETS";TAB(23);F(1);TAB(35);F(2);TAB(47);F(3);
9730 PRINT TAB(60);F(4)
9732 PRINT
9735 PRINT "NET FIXED ASSETS";TAB(23);N(1);TAB(35);N(2);TAB(47);N(3);
9738 PRINT TAB(60);N(4)
9741 PRINT
9744 PRINT "TOTAL ASSETS";TAB(23);O(1);TAB(35);O(2);TAB(47);O(3);;
9747 PRINT TAB(60);O(4)
9750 PRINT
9753 PRINT
9756 PRINT "ACCOUNTS PAYABLE";TAB(23);I(1);TAB(35);I(2);TAB(47);I(3);
9759 PRINT TAB(60);I(4)
9762 PRINT "ACCRUED TAXES";TAB(23);D(1);TAB(35);D(2);TAB(47);D(3);
9765 PRINT TAB(60);D(4)
9768 PRINT "TOTAL CURRENT LIAB.";TAB(23);J(1);TAB(35);J(2);TAB(47);J(3);
9771 PRINT TAB(60);J(4)
9774 PRINT
9777 PRINT "DEBT FINANCING";TAB(23);P(1);TAB(35);P(2);TAB(47);P(3);
9780 PRINT TAB(60);P(4)
9783 PRINT "EQUITY";TAB(23);M(1);TAB(35);M(2);TAB(47);M(3);TAB(60);M(4)
9786 PRINT "RETAINED EARNINGS";TAB(23);R(1);TAB(35);R(2);TAB(47);R(3);
9789 PRINT TAB(60);R(4)
9792 PRINT
9795 PRINT "TOTAL LIABILITIES";TAB(23);S(1);TAB(35);S(2);TAB(47);S(3);
9798 PRINT TAB(50);S(4)
9801 PRINT
9802 PRINT "                         ------------------------"
9804 PRINT
9829 PRINT
9831 PRINT "********************************************************************"
9900 DATA 50000.,750000.,35000.,850000.,42000.,.48,8500,30000,2,1.5,5
9901 DATA .12,.12,.15,.16,.56,.6,.6,.12,.12,.12,.12
9902 DATA 2000,3000,10000,1000,0,0,0,8000,500,500,500,500
9999END