5 REM*****BUDGET******BUSINESS PROGRAM
6 REM*****REWRITTEN FOR THE PDP-11 BY LINDA RUFF
20 DIM N(50),B(22,7),J(20),I(29),L(15),A(9,6)
40 PRINT "                    DEPARTMENTAL BUDGET PLAN"
50 MAT A=ZER: MAT B=ZER: PRINT "TODAY'S DATE";: INPUT C$
60 PRINT "LOCATION CODE";:INPUT L$: PRINT "TYPE PERSONNEL COUNT BY MONTH"
70 FOR J=1 TO 6:INPUT A(9,J): NEXT J:PRINT "TYPE";A(9,1);"SALARIES FOR MAY"
80 FOR J=1 TO A(9,1):INPUT N(J):NEXT J:K=1
90 IF K=6 THEN 210
100 IF A(9,K)<>A(9,K+1) THEN 120
110 K=K+1: GOTO 90
120 PRINT "TYPE";A(9,K+1)-A(9,K);"SALARIES FOR MONTH";K+1;"'S HIRES (MINUS FOR LOSSES)"
130 FOR J=1 TO ABS(A(9,K)-A(9,K+1)): ON K+1 GOTO 940,140,150,160,170,180
140 INPUT D(J):GOTO 190
150 INPUT R(J): GOTO 190
160 INPUT F(J): GOTO 190
170 INPUT M(J): GOTO 190
180 INPUT P(J)
190 NEXT J
200 K=K+1: GOTO 90
210 PRINT "WHAT % SALARY INCREASE IN JULY (NORMAL IS 5.0)";:INPUT S1
220 PRINT "WHAT % SALARY INCREASE IN OCTOBER (NORMAL IS 2.0)";: INPUT S2
230 FOR J=1 TO A(9,1): A(1,1)=A(1,1)+N(J): NEXT J
240 A(1,2)=A(1,1): FOR J=1 TO ABS(A(9,1)-A(9,2)):A(1,2)=A(1,2)+D(J):NEXT J
250 A(1,3)=A(1,2)+INT(.01*S1*A(1,1)): FOR J=1 TO ABS(A(9,2)-A(9,3)): A(1,3)=A(1,3)+R(J):NEXT J
260 A(1,4)=A(1,3): FOR J=1 TO ABS(A(9,3)-A(9,4)): A(1,4)=A(1,4)+F(J): NEXT J
270 A(1,5)=A(1,4): FOR J=1 TO ABS(A(9,4)-A(9,5)): A(1,5)=A(1,5)+M(J): NEXT J
280 A(1,6)=A(1,5)+INT(.01*S2*A(1,2)): FOR J=1 TO ABS(A(9,5)-A(9,6)): A(1,6)=A(1,6)+P(J):NEXT J
290 PRINT "WHEN INPUT IS ASKED FOR,TYPE IN THE FOLLOWING, FOR 1 MONTH"
300 PRINT "AT A TIME, SEPARATED BY COMMAS.  TRANSFERS IN,TRANSFERS OUT,"
310 PRINT "PRINTING & REPRODUCTION,OPERATING SUPPLIES, EQUIPMENT COSTS,"
315 PRINT"DEMO & LOAN EXPENSE, TRAVEL EXPENSE, MEALS AND LODGING, OTHER"
320 PRINT"EXPENSE, ADVERTISING & PROMOTION."
330 FOR L=1 TO 6
340 INPUT B(2,L),B(3,L),B(5,L),B(6,L),B(7,L),B(8,L),B(9,L),B(10,L),B(11,L),B(13,L)
350 B(1,L)=A(1,L):B(22,L)=A(9,L): NEXT L
360 D(1)=.082: D(2)=.053:D(3)=.047: D(4)=.034:D(5)=.027: D(6)=.023
370 FOR L=1 TO 6: B(3,L)=-1*B(3,L): B(4,L)=B(1,L)+B(2,L)+B(3,L)
380 B(12,L)=B(4,L)+B(5,L)+B(6,L)+B(7,L)+B(8,L)+B(9,L)+B(10,L)+B(11,L):B(14,L)=B(12,L)+B(13,L)
390 B(15,L)=INT(B(1,L)*D(L))+B(22,L)*23: B(17,L)=80*B(22,L)
400 B(19,L)=INT(.5*(B(2,L)+B(3,L))):B(21,L)=B(14,L)+B(15,L)+B(16,L)+B(17,L)+B(18,L)+B(19,L)+B(20,L)
410 NEXT L
420 PRINT "-----------------------------------------------------------------------": PRINT C$:PRINT L$
430 A$="LOCATION         TARGET": GOSUB 510
440 FOR L=1 TO 22: B(L,7)=B(L,1)+B(L,2)+B(L,3)+B(L,4)+B(L,5)+B(L,6):NEXT L
450 J=0:FOR M1=1 TO 22:READ A$:GOSUB480
454 PRINT TAB(24);
455 PRINT USING " #####",Z(M2); FOR M2=1 TO 7
460 PRINT:PRINT IF M1<>13
461 PRINT IF M1=3 OR M1=4 OR M1=11 OR M1=12 OR M1=14
464 NEXT M1
470 PRINT "-----------------------------------------------------------------------":GOTO 1000
480 J=J+1:I=1:PRINTA$;:FOR M3=1 TO 7:Z(M3)=B(J,I+M3-1):NEXT M3
485 RETURN
510 PRINT A$;TAB(24);:Z$="   MAY   JUN   JUL   AUG   SEP   OCT   TOTAL"
520 PRINT Z$:PRINT
530 RETURN
860 DATA "SALARIES","PLUS TRANSFERS IN","LESS TRANSFERS PUT"
870 DATA"NET SALARIES","PRINTING & REPRODUCTION","OPERATION SUPPLIES"
880 DATA "EQUIPMENT COSTS","DEMO & LOAN COSTS","TRAVEL EXPENSE"
890 DATA "MEALS & LODGING","OTHER EXPENSE","TOTAL OPERATING EXPENSE"
900 DATA "ADVERTISING & PROMOTION","TOTAL CONTROLLABLE EXP"
910 DATA "PAYROLL TAXES","DEPRECIATION","OCCUPANCY COSTS","FREIGHT OUT"
920 DATA"OVERHEAD CHARGES","TRAINING SOLD","TOTAL LOCATION EXPENSE"
930 DATA"PERSONNEL COUNT"
1000 END