9000 REM *****CAPINV*****BUSINESS PROGRAM
9005 REM CAPINV**********VERSION #1 (7/31/69)*****CAPITAL INVESTMENT****:
9010 REM REVISED JUNE, 1972   ANDY ROTH C.C.G.
9015 PRINT "*  CAPITAL INVESTMENT ANALYSIS  *"
9020 PRINT
9025 PRINT "THIS PROGRAM PRINTS THE GROSS CASH FLOW, ANNUAL DEPRECIATION. ANNUAL"
9030 PRINT "TAX, NET CASH FLOW, AND DISCOUNTED CASH FLOW FOR A LONG:TERM CAPITAL"
9035 PRINT "INVESTMENT."
9040 PRINT
9045 PRINT
9050 DIM A(50),B(50),C(50),D(50),E(50),F(50),G(50)
9055 PRINT "WHAT IS THE INITIAL INVESTMENT";
9060 INPUT A1
9062 PRINT
9065 PRINT "HOW MANY CASH FLOWS DO YOU WISH TO ENTER";
9070 INPUT A2
9075 PRINT
9080 PRINT"ENTER ";A2;"GROSS CASH FLOWS";
9085 MAT INPUT A(A2)
9090 PRINT
9095 PRINT "TYPE DEPRECIABLE AMOUNT, LIFE, AND SALVAGE VALUE";
9100 INPUT A3,A4,A5
9105 PRINT
9110 B9=A3-A5
9115 PRINT "DEPRECIATION METHODS:"
9120 PRINT "             1. STRAIGHT LINE"
9125 PRINT "             2. DOUBLE DECLINING TO STRAIGHT LINE"
9130 PRINT "             3. SUM:OF-THE-YEARS- DIGITS"
9135 PRINT "ENTER NUMBER OF DEPRECIATION METHOD";
9140 INPUT A6
9143 PRINT
9145 PRINT"DISCOUNT RATE AND TAX RATE";
9155 INPUT A7,A8
9160 PRINT
9165 PRINT
9170 PRINT "***********************************************************************"
9175 B1=0
9180 B2=0
9185 B3=0
9190 B4=0
9195 B5=0
9200 IF A6>1 THEN 9220
9205 FOR X=1 TO A4
9210 B(X)=(A3-A5)/A4
9215 NEXT X
9220 IF A6 <> 2 THEN 9265
9225 FOR X=1 TO A4
9230 T1=B9/((A4+1)-X)
9235 B(X)=A3*2/A4*(1-2/A4)^(X-1)
9240 IF T1 >= B(X) THEN 9250
9245 GOTO 9255
9250 B(X)=B9/((A4+1)-X)
9255 B9=B9-B(X)
9260 NEXT X
9265 IF Z6<3 THEN 9285
9270 FOR X=1 TO A4
9275 B(X)=(A3-A5)*(A4-X+1)*2/(A4*(A4+1))
9280 NEXT X
9285 IF A4 >= A2 THEN 9305
9290 FOR X=(A4+1) TO A2
9295 B(X)=0
9300 NEXT X
9305 FOR X=1 TO A2
9310 C(X)=A(X)-B(X)
9315 D(X)=C(X)*A8
9320 E(X)=C(X)-D(X)
9325 F(X)=E(X)+B(X)
9340 B1=B1+A(X)
9345 B2=B2+B(X)
9350 B3=B3+D(X)
9355 B4=B4+F(X)
9360 NEXT X
9365 IF A7=0 THEN 9395
9370  FOR X=1 TO A2
9375 G(X)=F(X)/((1+A7)^X)
9380 B5=B5+G(X)
9385 NEXT X
9390 GOTO 9505
9395 FOR R=0 TO .99 STEP .01
9400 B5=0
9405 FOR X=1 TO A2
9410 G(X)=F(X)/((1+R)^X)
9415 B5=B5+G(X)
9420 NEXT X
9425 IF B5 <= A1 THEN 9440
9430 R1=R
9435 NEXT R
9440 FOR R=R1 TO (R1+.01) STEP .0001
9445 B5=0
9450 FOR X=1 TO A2
9455 G(X)=F(X)/((1+R)^X)
9460 B5=B5+G(X)
9465 NEXT X
9470 IF B5 <= A1 THEN 9480
9475 NEXT R
9480 IF R <= 0 THEN 9490
9485 GOTO 9495
9490 PRINT "YOU HAVE A ZERO OR NEGATIVE RATE OF RETURN"
9495 PRINT
9500 PRINT "THE CALCULATED RATE OF RETURN IS";R*100;"PERCENT"
9505 PRINT
9510 PRINT
9515 PRINT "YEAR";TAB(8);"GROSS CASH";TAB(23);"ANNUAL";TAB(35);"ANNUAL";
9520 PRINT TAB(48);"NET CASH";TAB(61);"DISCNTD"
9525 PRINT "    ";TAB(11);"FLOW";TAB(23);"DEPREC";TAB(36);"TAX";
9530 PRINT TAB(50);"FLOW";TAB(60);"CASH FLOW"
9535 PRINT "------------------------------------------------------------------------"
9540 FOR X=1 TO A2
9545 PRINTX ;TAB(9);A(X);TAB(22);B(X);TAB(35);D(X);TAB(48);F(X);
9550 PRINT TAB(60);G(X)
9555 NEXT X
9560 PRINT
9565 PRINT "TOTAL";TAB(8);B1;TAB(21);B2;TAB(34);B3;TAB(47);B4;TAB(59);B5
9570 PRINT
9575 PRINT "DO YOU WISH ANOTHER RUN; 1=YES. 2=NO";
9580 INPUT A9
9585 IF A9=1 THEN 9050
9590 PRINT
9595 PRINT"************************************************************"
9999 END