1 REM***DECSN**TOP MANAGEMENT GAME***
2 REM  ADAPTED TO PDP-11 BY LINDA RUFF
10 LET N=8
20 LET P=11
25 DIM C(8,6)
30 RANDOMIZE
31 PRINT "WHEN A '?' IS TYPED AT THE TERMINAL EACH TEAM (ONE AT A TIME)
32PRINT "MUST ENTER THE FOLLOWING INFORMATION ON ONE LINE, SEPARATED BY COMMAS."
33 PRINT "THE NUMBER OF THE TEAM, THE PRICE AT WHICH THEY WISH TO SELL THEIR"
34 PRINT"PRODUCT, THEIR ESTIMATED COST OF PROMOTION, THEIR COST OF PRODUCTION,"
35PRINT"MONEY DEVOTED TO DEVELOPING THEIR CAPACITY, THEIR RESEARCH,"
36 PRINT"AND TOWARDS INCENTIVE. WHEN EACH TEAM HAS DONE THIS ANOTHER SERIES"
37 PRINT "OF QUESTION MARKS WILL BE PRINTED. EACH TEAM WILL IN ORDER ENTER"
38 PRINT "THE SAME VARIABLES (EXCLUDING TEAM NUMBER) . THE VALUES OF "
39 PRINT "THESE WILL BE IN REFERENCE TO THEIR TRAINING PROGRAM."
40 FOR J=1 TO 8
41 INPUT A(J,1)A(J,2),A(J,3),A(J,4),A(J,5),A(J,6),A(J,7)
42 NEXT J
49 PRINT "THIS DATA REFERS TO THE TRAINING PROGRAM."
50 FOR J=1 TO N
51 INPUT C(J,1),C(J,2),C(J,3),C(J,4),C(J,5),C(J,6)
52 NEXT J
60 PRINT "NO.";TAB(5);"PRICE";TAB(12);"PROMOTION";TAB(24);"PRODUCTION";
70 PRINT TAB(36);"CAPACITY";TAB(48);"RESEARCH";TAB(60);"INCENTIVE"
80 PRINT
90 FOR I=1 TO N
100 PRINT I;TAB(5);A(I,2);TAB(12);A(I,3);TAB(24);A(I,4);TAB(36);
110 PRINT A(I,5);TAB(48);A(I,6);TAB(60);A(I,7)
120 NEXT I
130 LET Y=0
140 LET Z=0
150 FOR I=1 TO N
160 LET Y=Y+A(I,2)
170 LET Z=Z+A(I,3)
180 NEXT I
190 PRINT
220 FOR I=1 TO N
230 LET A(I,3)=A(I,3)+C(I,1)
240 NEXT I
250 LET Y1=Y*(1/N)
260 LET Z1=Z*(1/N)
270 LET F1=75/Y1*(300+Z1)/(1500+Z1)
280 LET F2=1+.2*P-.036*P^2+.0019*P^3
290 LET S=F1*F2*60000.
300 LET T1=0
310 FOR I=1 TO N
320 IF A(I,3) >= 1000 THEN 350
330 LET H(I)=75/A(I,2)*(300+A(I,3))/(1500+A(I,3))
340 GOTO 360
350 LET H(I)=40/A(I,2)
360 LET X=0
370 FOR J=1 TO (N*P)
380 LET X=RND(P)+X+J
390 NEXT J
400 LET H(I)=H(I)-.1*RND(P)
410 LET T1=T1+H(I)
420 NEXT I
430 LET T2=N*S
440 LET S1=T2/T1
450 DIM M(8,5)
460 FOR I=1 TO N
470 LET M(I,1)=I
480 LET M(I,2)=S1*H(I)
490 IF A(I,7) >= 30 THEN 520
500 LET Q(I)=A(I,5)
510 GOTO 530
520 LET Q(I)=1.1*A(I,5)
530 IF Q(A)-A(I,4)<5 THEN 560
540 LET M(I,3)=A(I,4)*10
550 GOTO 570
560 LET M(I,3)=(A(I,4)+5-Q(I))*17+(A(I,4)-5)*10
570 LET R=RND(P)
580 IF R*(A(I,6)+C(I,3))<35 THEN 620
590 LET C(I,2)=.985*C(I,2)
600 LET C(I,3)=0
610 GOTO 630
620 LET C(I,3)=INT(C(I,3)+1.2*A(I,6)+.5)
630 LET M(I,3)=M(I,3)*C(I,2)*(1-C(I,6)*.002)
640 LET C(I,6)=.7*C(I,6)
650 LET M(I,4)=C(I,4)*(.25*C(I,5)+.75*A(I,5))/C(I,5)
660 LET C(I,4)=INT(M(I,4)+.5)
670 LET C(I,5)=A(I,5)
680 LET C(I,1)=INT(.1*A(I,3)+.5)
690 LET M(I,5)=M(I,3)/A(I,4)
700 NEXT I
710 PRINT "TEAM NO.","SALES","PROD COST","ADMIN COST","UNIT COST"
720 PRINT
730 FOR I=1 TO N
740 PRINT M(I,1),M(I,2),M(I,3),M(I,4),M(I,5)
750 NEXT I
760 PRINT
770 PRINT "TOTAL POTENTIAL SALES,  ";T2;"UNITS"
780 PRINT "TOTAL PROMOTION,  $";Z
790 PRINT
960 FOR I=1 TO N
970 PRINT 360+I;"DATA";C(I,1);",";C(I,2);",";C(I,3);",";C(I,4);
980 PRINT ",";C(I,5);",";C(I,6)
990 NEXT I
1000 END