9000 REM **** DEPCOM **** BUSINESS PROGRAM REVISED APRIL, 1972 ED BAKER
9001 REM DEPCOM**********VERSION #1 (7/31/69)****DEPRECIATION COMPARISON
9004 PRINT '** DEPRECIATION METHOD COMPARISON **'
9006 PRINT
9008 PRINT 'THIS PROGRAM COMPUTES AND PRINTS DEPRECIATION BY MONTHS BY'
9010 PRINT 'FOUR METHODS: STRAIGHT LINE, DOUBLE DECLINING BALANCE, '
9012 PRINT 'SUM-OF-THE-YEARS-DIGITS, AND 150 PERCENT DECLINING BALANCE.'
9014 PRINT
9016 INPUT'DO YOU ONLY WANT A YEARLY SUMMARY';Z$
9020 PRINT
9022 PRINT
9024 INPUT'WHAT IS THE AMOUNT OF YOUR INVESTMENT';I1
9026 PRINT
9030 INPUT'WHAT IS THE SALVAGE VALUE';S1
9034 PRINT
9036 INPUT'WHAT IS THE DEPRECIABLE LIFE (IN YEARS)';L1
9040 IF L1>=2THEN9046
9042  PRINT 'LIFE TOO SHORT TO PROVIDE MEANINGFUL RESULTS.'
9043 INPUT'DO YOU WISH TO REENTER';J$:IFJ$='YES'THEN9036ELSE9999
9046 IFL1<=75 THEN 9052
9048 PRINT 'LIFE TOO LONG.  PLEASE TRY A VALUE LESS THAN 76.':GOTO9036
9052 PRINT
9054 PRINT 'IN WHICH MONTH, AND WHICH YEAR IS YOUR INVESTMENT MADE'
9056 PRINT 'PLEASE ENTER AS TWO NUMBERS(MM,19YY)';
9058 INPUT A1,Z1
9060 PRINT
9062 PRINT 'WHAT IS THE DISCOUNT RATE (IN DECIMAL NOTATION) FOR COMPUTING'
9064 PRINT 'Tq PRESENT VALUE OF THE ANNUAL DEPRECIATION';
9066 INPUTR
9068 PRINT
9070PRINT'YOU HAVE THE OPTION TO SWITCH OVER FROM THE DOUBLE DECLINING'
9072PRINT'BALANCE METHOD TO THE STRAIGHTLINE METHOD AT APPROPRIATE TIMES.
9074PRINT'TO PREVENT ANY SWITCHOVER PLEASE TYPE 0.'
9076PRINT'TO SPECIFY A SPECIFIC YEAR OF SWITCHOVER, PLEASE TYPE THE YEAR.
9078PRINT'TO OBTAIN AND AUTOMATIC SWITCHOVER WHEN THE ANNUAL STRAIGHTLINE
9080PRINT'DEPRECIATION BECOMES GREATER THAN THE DOUBLE DECLINING BALANCE
9082PRINT'VALUE, PLEASE TYPE A 1.';
9084INPUTY
9086 PRINT
9088 PRINT'*************************************************************
9090 PRINT
9092 PRINT'    DATE     STRAIGHTLINE DBL DECLINING  SUM-O-THE';
9094 PRINT '   150% DECLINING'
9096 PRINT'  YR    MO                BALANCE     YEARS-DIGITS';
9098 PRINT'    BALANCE'
9100K=0
9102P=0
9104S=0
9106 Q1,Q2,Q3,Q4=0
9108 V1,V2,V3,V4=0
9110 DIM W(12), X(12), Y(12), Z(12)
9112 DIM A(75), B(75), C(75), D(75)
9114 DIM H(75), I(75), J(75), K(75)
9116 REM STRAIGHTLINE METHOD
9118 N=S1
9120 FOR I=1TOL1
9122 A(I)=(I1-S1)/L1
9124 H(I)=A(I)/12
9126 NEXT I
9128 REM DOUBLE DECLINING BALANCE METHOD
9130 N=S1
9132 FORI=1 TO L1
9134 B(I)=2*((I1-N)/L1)
9136 I(I)=B(I)/12
9138 M=N
9140 N=N+B(I)
9142 GOTO 9148
9144 NEXTI
9146 GOTO 9194
9148 IF Y<1 THEN 9144
9150 IF Y>1 THEN 9174
9152 IF I=1 THEN 9144
9154 IF P=1 THEN 9168
9156 IF B(I)>A(I)THEN 9144
9158 G=L1+1-I
9160 P=1
9162 B(I)=(I1-M)/G
9164 I(I)=B(I)/12
9166 GOTO 9144
9168 B(I)=B(I-1)
9170 I(I)=B(I)/12
9172 GOTO 9144
9174 G=Y+1-Z1
9176 IF I<G THEN 9144
9178 IF P=1 THEN 9188
9180 P=1
9182 B(I)=((I1-M)/(L1+1-G))
9184 I(I)=B(I)/12
9186 GOTO 9144
9188 B(I)=B(I-1)
9190 I(I)=B(I)/12
9192 GOTO 9144
9194 REM SUM OFTHE YEARS DIGITS METHOD
9196 N=S1
9198 FOR I=1 TO L1
9200 C(I)=(I1-N)*(L1+1-I)*(2/(L1*(L1+1)))
9202 J(I)=C(I)/12
9204 NEXT I
9206 REM 150% DECLINING METHOD
9208 N=S1
9210 FOR I=1 TO L1
9212 D(I)=1.5*((I1-N)/L1)
9214 K(I)=D(I)/12
9216 N=N+D(I)
9218 NEXT I
9220 I=0
9222 K=K+1
9224 X=K+(Z1-1)
9226 IF K<=1+L1 THEN 9254
9228 FOR I=1 TO L1
9230 V1=V1+A(I)/((1+R)^I)
9232 V2=V2+B(I)/((1+R)^I)
9234 V3=V3+C(I)/((1+R)^I)
9236 V4=V4+D(I)/((1+R)^I)
9238 NEXT I
9240 PRINT
9242 PRINT 'THE PRESENT VALUE OF THE DEPREIATION AT THE BEGINNING OF 'Z1
9244 PRINT 'AT'R'IS AS FOLLOWS:'
9246 PRINT ' ',V1,V2,V3,V4
9248 PRINT
9250PRINT'*********************************************************************'
9252 GOTO 9368
9254 I=I+1
9256 IFI>12THEN9302
9258 IFI<=A1 THEN 9278
9260 S=1
9262 IFK<L1+1 THEN 9268
9264 W(I),X(I),Y(I),Z(I)=0
9266 GOTO 9294
9268 W(I)=H(K)
9270 X(I)=I(K)
9272 Y(I)=J(K)
9274 Z(I)=K(K)
9276 GOTO 9294
9278 IFS=0THEN9290
9280 W(I)=H(K-1)
9282 X(I)=I(K-1)
9284 Y(I)=J(K-1)
9286 Z(I)=K(K-1)
9288 GOTO 9294
9290 W(I),X(I),Y(I),Z(I)=0
9294 REM  PRINT OUT ROUTINE
9296 IF Z$='YES' THEN 9254
9298 PRINT X' 'I,W(I),X(I),Y(I),Z(I)
9300 GOTO 9254
9302 S=1
9304 T1,T2,T3,T4=0
9306 FOR J=1 TO 12
9308 T1=T1+W(J)
9310 T2=T2+X(J)
9312 T3=T3+Y(J)
9314 T4=T4+Z(J)
9316 NEXT J
9318 Q1=Q1+T1
9320 Q2=Q2+T2
9322 Q3=Q3+T3
9324 Q4=Q4+T4
9326 PRINT
9328 PRINT 'TOTAL'X,T1,T2,T3,T4
9330 PRINT
9332 PRINT 'CUM DEPR',Q1,Q2,Q3,Q4
9334 PRINT
9336 B1=(I1-S1)-Q1
9338 IF B1>1 THEN 9342
9340 B1=0
9342 B2=(I1-S1)-Q2
9344 IF B2>1 THEN 9348
9346 B2=0
9348 B3=(I1-S1)-Q3
9350 IF B3>1 THEN 9354
9352 B3=0
9354 B4=(I1-S1)-Q4
9356 IF B4>1 THEN 9360
9358 B4=0
9360 PRINT 'UNDEPR BAL',B1,B2,B3,B4
9362 PRINT
9364 PRINT '----------'
9366 GOTO 9220
9368 END