9000 REM ***** EQUITY ***** BUSINESS PROGRAM
9005 REM EQUITY *********** VERSION #1 (7/31/69) ***** COST OF EQUITY CAPITAL *****
9010 REM   REVISED JUNE,1972     ANDY ROTH  C.C.G.
9015 PRINT "*  COST OF EQUITY CAPITAL  *"
9020 PRINT
9025 PRINT
9030 PRINT "THIS PROGRAM WILL COMPUTE THE COST OF EQUITY CAPITAL BY COMPUTING DIVI-"
9035 PRINT "DENDS AND THE SHARE PRICE FOR FUTURE PERIODS, (BASED ON THE GORDON"
9040 PRINT "MODEL), AND THEN FIND THE DISCOUNT RATE BY EQUATING THE PRESENT VALUE"
9045 PRINT "OF THE STREAM TO THE CURRENT SHARE PRICE."
9050 PRINT
9055 REM
9060 REM    THE VARIABLES ARE DEFINED AS FOLLOWS:
9065 REM  D(I) = DIVIDEND IN PERIOD I
9070 REM   N   = NUMBER OF GROWTH SEGMENTS
9075 REM  G(I) = GROWTH RATE IN DPS PERSEGMENT I
9080 REM  B(I) = BEGINNING PERIOD OF SEGMENT I
9085 REM  L(I) = FINAL PERIOD OF SEGMENT I
9090 REM   Q   = INDICATOR FOR RERUN OPTIONS
9095 REM   R   = COST OF CAPITAL
9100 REM
9105 DIM D(100)
9110 DIM L(20),B(20),G(20)
9115 Q,S1=0
9120 IF Q=1 THEN 9145
9125 PRINT
9130 PRINT "PLEASE ENTER THE CURRENT PRICE/SHARE, AND DIIDEND/SHARE";
9135 INPUT P,D(1)
9140IF Q=2 THEN 9200
9145 PRINT
9150 PRINT "HOW MANY GROWTH SEGMENTS ARE THERE";
9155 INPUT N
9160 PRINT
9165 PRINT "FOR EACH GROWTH SEGMENT, ENTER THE GROWTH RATE IN DECIMAL, & THE LAST"
9170 PRINT "EFFECTIVE PERIOD FOR EACH SEGMENT."
9175 FOR I=1 TO N
9180 PRINT "SEGMENT";I;
9185 INPUT G(I),L(I)
9190 NEXT I
9195 PRINT
9200 R=0
9205 B(1)=1
9210 REM IF N=1, THEN THE COST CAN BE FOUND ANALYTICALLY
9215 IF N=1 THEN 9365
9220 FOR I=1 TO N-1
9225 FOR J=B(I) TO L(I)
9230 D(J+1)=D(J)*(1+G(I))
9235 NEXT J
9240 B(I+1)=L(I)+1
9245 R=R+G(I)
9250 NEXT I
9255 GOSUB 9375
9260 PRINT
9265 IF S1=1 THEN 9285
9270 PRINT "*********************************************************************"
9275 S1=1
9280 GOTO 9290
9285 PRINT "                                          ------------------"
9290 PRINT
9295 PRINT "A SHARE PRICE OF $";P;",DIVIDEND OF $";D(1);", AND INITIAL GROWTH
9300 PRINT "RATE OF";G(1)*199;"%, YIELD A COST OF EQUITY CAPITAL OF";R;"PERCENT
9305 PRINT
9310 PRINT "                                         --------------------"
9315 PRINT
9320 PRINT "DO YOU WISH TO RUN SOME DIFFERENT DATA?"
9325 PRINT "ENTER '0' FOR ALL NEW INFORMATION."
9330 PRINT "ENTER '1' FOR SAME SHARE PRICE & DIVIDEND, NEW GROWTH RATES OF PERI
9335 PRINT "ENTER '2' FOR SAME GROWTH RATES & PERIODS, NEW SHARE PRICE OR DIVID
9340 PRINT "ENTER '3' TO TERMINATE.  ";
9345 INPUT Q
9350 PRINT
9355 IF Q=3 THEN 9515
9360 GOTO 9120
9365 R=100*(D(1)/P+G(1))
9370 GOTO 9260
9375 R=(R+G(N))/N+D(1)/P
9380 M=0
9385 R=R-.55
9390 D1=1
9395 FOR I=1 TO 13
9400 R=R+D1
9405 M=M+1
9410 D1=.5*D1
9415 R=R-D1
9420 F=1
9425 IF M>100 THEN 9500
9430 IF R=-1 THEN 9480
9435 Z=-P
9440 FOR J=1 TO L(N-1)
9445 F=F/(1+R)
9450 Z=Z+D(J)*F
9455 NEXT J
9460 IF R<G(N) THEN 9400
9465 Z=Z+D(L(N-1))*F/(R-G(N))
9470 IF Z<0 THEN 9415
9475 NEXT I
9480 R=100*R
9485 REM NEXT LINE ROUNDS R OFF
9490 R=(INT(100*R+.5))/100
9495 RETURN
9500 PRINT
9505 PRINT "TOO MANY ITERATIONS. LAST COST WAS";R*100;"PERCENT WITH VALUE $";Z
9510 GOTO 9305
9515 PRINT
9520 PRINT"*******************************************************"
9999 END