8900 RANDOMIZE!!!!!!!!!!!!!!!!!
9000 REM ***** GNPSUM ***** BUSINESS PROGRAM
9005 REM GNPSUM *********** VERSION #1 (7/31/69) ***** GNP SUMMARY *****
9010 REM REVISED JUNE 1972,  ANDY ROTH C.C.G.
9015 REM THIS PROGRAM PRODUCES FIGURES FOR GNP, CONSUMPTION, INVESTMENT
9020 REM AND GOVERNMENT SPENDING FOR A SERIES OF YEARS FROM A MODEL
9022 REM IN WHICH CONSUMPTION IS FUNCTION OF INCOME IN THE PREVIOUS
9023 REM PERIOD AND INVESTMENT DEPENDS IN PART ON CHANGES IN CONSUMPTION.
9025 REM
9030 REM THE FOLLOWING COEFFICIENTS ARE TO BE INPUT BY THE USER:
9032 REM (NOTE: ALL DOLLAR VALUES SHOULD  BE ENTERED IN EXPONENTIAL
9033 REM NOTATION.  EXAMPLE: $ 6 MILLION = 6E+6).
9035 REM
9040 REM THE FIRST FOUR VALUES REFER TO A BASE PERIOD:
9045 REM     A = THE FRACION CONSUMPTION WAS OF PERSONAL INCOME
9050 REM     B = THE ACTUAL VALUE OF INVESTMENT EXPENDITURES
9055 REM     E = THE VALUE OF GOVERNMENT SPENDING IN THIS BASE PERIOD
9060 REM     Y(1) = THE TOTAL GNP FOR THIS BASE PERIOD
9065 REM THE NEXT FIVE VALUES ARE GENERAL INFORMATION:
9070 REM     N = THE NUMBER OF PERIODS THE USER WISHES TO ANALYZE
9075 REM     G = THE FRACTION DISPOSABLE INCOME IS OF TOTAL GNP
9080 REM     C = THE ADDITIONAL INVESTMENT ADDED EACH PERIOD
9085 REM     F = THE ADDITIONAL GOVERNMENT SPENDING EACH PERIOD
9090 REM     D = THE FRACTION OF THE CONSUMPTION INCREMENT THAT IS TO
9095 REM         BE ADDED TO INVESTMENT EACH PERIOD
9100 REM     N$= 'YES' IMPLIES H=1, AND THE BUSINESS INVESTMENT DOES
9105 REM         HAVE A RANDOM COMPONENT.
9110 REM     'NO' IMPLIES H=0, AND THE BUSINESS INVESTMENT DOES NOT
9111 REM         HAVE A RANDOM COMPONENT.
9115 REM         THE RAMDOM COMPONENT HAS A RECTANGULAR DISTRIBUTION, AND
9120 REM         RANGES FROM +10% TO -10% OF THE VALUE OF B+(C*T)
9121 REM
9122 REM
9125 PRINT "*  GNP SUMMARY  *"
9130 PRINT
9135 PRINT "THIS PROGRAM PRINTS A SUMMARY OF FIGURES FOR GNP, CONSUMPTION, INVEST-"
9140 PRINT "MENT, AND GOVERNMENT SPENDING FOR A SERIES OF CONSECUTIVE YEARS."
9145 PRINT
9150 PRINT "THE FOLLOWING FOUR QUESTIONS REFER TO A BASE PERIOD:"
9155 PRINT
9160 PRINT "FOR THE BASE PERIOD, WHAT FRACTION OF PERSONAL INCOME WAS CONSUMPTION"
9165 INPUT A
9170 PRINT
9175 PRINT "WHAT WAS THE TOTAL INVESTMENT DURING THIS PERIOD?  (IN DOLLARS)";
9180 INPUT B
9185 PRINT
9190 PRINT "WHAT WAS THE GOVERNMENT SPENDING FOR THIS PERIOD";
9195 INPUT E
9200 PRINT
9205 PRINT "AND WHAT WAS THE TOTAL GNP FOR THIS BASE PERIOD";
9210 INPUT Y(1)
9215 PRINT
9220 PRINT "---"
9225 PRINT
9230 PRINT "HOW MANY PERIODS DO YOU WISH TO ANALYZE";
9235 INPUT N
9240 PRINT
9245 PRINT "FOR THIS MODEL, WHAT FRACTION OF GNP SHOULD BE USED AS DISPOSABLE INCOME"
9250 INPUT G
9255 PRINT
9260 PRINT "HOW MUCH NEW INVESTMENT SHOULD BE ADDED EACH PERIOD";
9265 INPUT C
9270 PRINT
9275 PRINT "HOW MUCH NEW GOVERNMENT SPENDING SHOULD BE ADDED EACH PERIOD";
9280 INPUT F
9285 PRINT
9290 PRINT "WHAT FRACTION OF THE CHANGE IN CONSUMPTION FROM PERIOD TO PERIOD SHOULD
9295 PRINT "BE RE-INVESTED";
9300 INPUT D
9305 PRINT
9310 PRINT "DOES THE NORMAL BUSINESS INVESTMENT HAVE A RANDOM COMPONENT";
9315 INPUT N$
9320 IF N$="YES" THEN 9335
9325 LET H=0
9330 GOTO 9340
9335 LET H=1
9340 DIM N$(3)
9345 DIM V(30),G(30),C(30),P(30),Y(30)
9350 Z=0
9351 PRINT
9355 PRINT "**********************************************************************"
9360 PRINT
9365 Z=Z+1
9370 PRINT "YEAR","  GNP  ","CONSUMPTION","INVESTMENT","GOV'T. EXP."
9375 PRINT "----","-------","------------","----------","-----------"
9380 PRINT
9385 V(1)=B
9390 G(1)=E
9395 C(1)=Y(1)-V(1)-G(1)
9400 P(1)=G*Y(1)
9405 PRINT "0",Y(1),C(1),V(1),G(1)
9410 C(2)=A*P(1)
9415 V(2)=B+C
9420 G(2)=E+F
9425 Y(2)=C(2)+V(2)+G(2)
9430 P(2)=G*Y(2)
9435 PRINT "1",Y(2),C(2),V(2),G(2)
9440 X=0
9445 FOR I=3 TO N+1
9450 IF H=0 THEN 9465
9455 X=RND(X)-.5
9460 X=X*(B+C*I)*.2
9465 C(I)=A*P(I-1)
9470 V(I)=B+C*I+D*(C(I-1)-C(I-2))+X
9475 G(I)=E+F*I
9480 Y(I)=C(I)+V(I)+G(I)
9485 P(I)=G*Y(I)
9490 PRINT I-1,Y(I),C(I),V(I),G(I)
9495 NEXT I
9500 PRINT
9505 PRINT
9510 PRINT "<**********************************************************************"
9999 END