9000 REM ***** INACNT ***** BUSINESS PROGRAM
9005 REM INACNT *********** VERSION #1 (7/31/69) ***** INCOME ACCOUNTS *****
9010 REM
9015 REM THIS PROGRAM PRODUCES A SIIPLE SET OF INCOME AND PRODUCT
9020 REM ACCOUNTS.
9025 REM
9030 REM THE FOLLOWING COEFFICIENTS ARE TO BE SUPPLIED BY THE USER:
9035 REM     A= THE FRACTION OF GNP SAVED BY BUSINESS
9040 REM     B= THE FRACTION OF GNP PAID IN TAX BY BUSINESS
9045 REM     C= THE FRACTION OF PERSONAL INCOME PAID IN
9050 REM        PERSONAL TAXES
9055 REM     D= THE FRACTION OF PERSONAL INCOME AFTER TAXES
9060 REM        SPENT ON CONSUMPTION.
9065 REM     I4= DOLLOARS OF GNP EVENTUALLY INVESTED
9070 REM     G3= DOLLARS OF GNP SPENT BY GOVERNMENT
9075 REM
9080 PRINT "*  NATIONAL INCOME & PRODUCT ACCOUNT  *"
9085 PRINT
9090 PRINT "THIS PROGRAM PRODUCES A SIMPLE SET OF INCOME AND PRODUCT ACCOUNTS."
9095 PRINT
9100 I=0
9105 PRINT "PLEASE ANSWER THE FOLLOWING QUESTIONS."
9110 DIM N$(3),Q$(29)
9115 PRINT
9120 PRINT "1. WHAT FRACTION OF GNP IS SAVED BY BUSINESS";
9125 INPUT A
9130 PRINT
9135 PRINT "2. WHAT FRACTION OF GNP IS PAID IN TAX BY BUSINESS";
9140 INPUT B
9145 PRINT
9150 PRINT "3. WHAT FRACTION OF PERSONAL INCOME IS PAID AS PERSONAL INCOME TAX";
9155 INPUT C
9160 PRINT
9165 PRINT "4. WHAT FRACTION OF THE DISPOSABLE PERSONAL INCOME (I.E. AFTER:TAXES)"
9170 PRINT "IS SPENT ON CONSUMPTION";
9175 INPUT D
9180 PRINT
9185 PRINT "HOW MUCH OF THE GNP IS INVESTED? (IN DOLLARS: EX.: 50 BILLION=5E+10)."
9190 INPUT I4
9195 PRINT
9200 PRINT "HOW MUCH OF GNP IS SPENT BY THE GOVERNMENT? (IN DOLLARS AS ABOVE.)"
9205 INPUT G3
9210 PRINT
9215 PRINT "(DO YOU WISH A SENSITIVITY ANALYSIS ON ANY OF THE FIRST 4 INPUTS?)"
9220 INPUT N$
9225 IF LEFT(N$,2)="NO" THEN 9255
9230 PRINT "WHICH INPUT? (1-4)";
9235 INPUT Z
9240 PRINT "ENTER THE LOW VALUE, HIGH VALUE, STEP";
9245 INPUT Z1,Z2,Z3
9250 PRINT
9255 M1=(1/(1-D*(1-A-B)*(1-C)))
9260 M2=(M1*(D*(1-A-B)*(1-C)))
9265 M3=M1*(B+C*(1-A-B))
9270 PRINT "********************************************************************"
9275 PRINT
9280 PRINT "     BUSINESS SAVINGS ARE ";A*100;"PERCENT OF GNP"
9285 PRINT "     BUSINESS TAXES ARE  ";B*100;"PERCENT OF GNP"
9290 PRINT "     PERSONAL INCOME TAX IS";C*100;"PERCENT OF PERSONAL INCOME"
9295 PRINT "     PERSONAL CONSUMPTION IS";D*100;"PERCENT OF DISPOSABLE PERSONAL INCOME"
9300 PRINT
9305 PRINT "     THE GNP MULTIPLIER IS ";M1
9310 PRINT "     THE CONSUMPTION MULTIPLIER IS";M2
9315 PRINT "     THE TAX MULTIPLIER IS ";M3
9320 PRINT
9325 PRINT "----------------------------------------------------------------"
9326 IF LEFT(N$,2)="NO" THEN 9445
9330 PRINT
9335 IF Z>1 THEN 9365
9340 FOR A=Z1 TO Z2 STEP Z3
9345 I=I+1
9350 P=A
9355 Q$="BUSINESS SAVING/GNP"
9360 GOTO 9445
9365 IF Z>2 THEN 9395
9370 FOR B=Z1 TO Z2 STEP Z3
9375 I=I+1
9380 P=B
9385 Q$="BUSINESS TAX/GNP"
9390 GOTO 9445
9395 IF Z>3 THEN 9425
9400 FOR C=Z1 TO Z2 STEP Z3
9405 I=I+1
9410 P=C
9415 Q$="PERSONAL TAX/PERSONAL INCOME"
9420 GOTO 9445
9425 FOR D=Z1 TO Z2 STEP Z3
9430 I=I+1
9435 P=D
9440 Q$="CONSUMPTION/DISPOSABLE INCOME"
9445 N=0
9450 Y=M1*(I4+G3)
9455 S1=A*Y
9460 T1=B*Y
9465 Y1=Y-S1-T1
9470 T2=C*Y1
9475 C2=D*(Y1-T2)
9480 S2=Y1-T2-C2
9485 S3=T1+T2-G3
9490 PRINT
9495 IF LEFT(N$,2)="NO" THEN 9510
9500 PRINT " ** RUN #";I;":";Q$;"=";P;"**"
9505 PRINT
9510 PRINT "                   PRODUCTION SECTOR (ACT.#1)"
9515 PRINT "                   --------------------------"
9520 PRINT "PERSONAL INCOME.....";Y1;"CONSUMPTION........";C2
9525 PRINT "BUSINESS TAXES......";T1;"INVESTMENT.........";I4
9530 PRINT "BUSINESS SAVING.....";S1;"GOV'T SPENDING.....";G3
9535 PRINT "                    ";"------------";"                      ";"-------------"
9540 PRINT "GROSS NAT. PRODUCT..";Y;"GROSS NAT. PRODUCT..";Y
9545 PRINT
9550 PRINT "                   PERSONAL SECTOR  (ACT. #2)"
9555 PRINT "                   --------------------------"
9560 PRINT "PERSONAL TAXES......";T2;"PERSONAL INCOME....";Y1
9565 PRINT "CONSUMPTION.........";C2
9570 PRINT "PERSONAL SAVING.....";S2
9575 PRINT "                    ";"-------------";"                     ";"-------------"
9580 PRINT "PERSONAL INCOME....."Y1;"PERSONAL INCOME.....";Y1
9585 PRINT
9590 PRINT "                   GOVERNMENT SECTOR (ACT. #3)"
9595 PRINT "                    ----------------------------"
9600 PRINT "GOVERNMENT SPENDING.";G3;"BUSINESS TAXES......";T1
9605 PRINT "GOVERNMENT SAVING...";S3;"PERSONAL TAXES......";T2
9610 PRINT "                    ";"----------";"                        ";"-------------"
9615 PRINT "GOVERNMENT INCOME...";G3+S3;"GOVERNMENT INCOME...";T1+T2
9620 PRINT
9625 PRINT "                   SAVING & INVESTMENT(ACT. #4)"
9630 PRINT "                   <----------------------------"
9635 PRINT "BUSINESS SAVING.....";S1;"INVESTMENT..........";I4
9640 PRINT "PERSONAL SAVING.....";S2
9642 PRINT "GOVERNMENT SAVING...";S3
9645 PRINT "                    ";"-------------";"                     ";"-------------"
9655 PRINT "SAVING..............";I4;"INVESTMENT         ";I4
9660 PRINT
9665 IF LEFT(N$,2)="NO" THEN 9745
9670 IF Z<4 THEN 9690
9675 PRINT "         -------------------------------------------------"
9680 NEXT D
9685 GOTO 9745
9690 IF Z<3 THEN 9710
9695 PRINT "         -------------------------------------------------"
9700 NEXT C
9705 GOTO 9745
9710 IF Z<2 THEN 9730
9715 PRINT "         -------------------------------------------------"
9720 NEXT B
9725 GOTO 9745
9730 PRINT "         -------------------------------------------------"
9735 NEXT A
9740 GOTO 9745
9745 PRINT "*********************************************************************"
9999 END