9000REM *****LENDER*****BUSINESS PROGRAM
9010REM LENDER**********VERSION #1 (7/31/69)*****LOAN ANALYSIS***
9020 REM REVISED MAR 1972  ANDY ROTH  C.C.G.
9025 ON ERROR GO TO 9900
9030PRINT "*  SIMPLE LOAN ANALYSIS  *"
9040PRINT
9050PRINT "THIS PROGRAM CALCULATES THE MONTHLY INTEREST CHARGES AND OUTSTANDING"
9060 PRINT "BALANCE OF A LOAN THAT MUST BE PAID OFF IN ONE YEAR OR LESS."
9070PRINT
9080PRINT
9090 INPUT "WHAT IS THE AMOUNT OF THE LOAN";B
9110PRINT
9120 INPUT"WHAT IS THE MONTHLY PAYMENT";M
9140PRINT
9150 INPUT"WHAT IS THE INTEREST RATE IN PERCENT";R
9170IF R>1 THEN 9200
9180PRINT "ENTER ABOVE INTEREST AS A PERCENT > 1"
9190 GO TO 9150
9200PRINT
9220Z=(B*R)/1200
9230IF ((Z+B)/12) >=M THEN 9250
9240GOTO 9300
9250PRINT
9260PRINT "LOAN CANNOT BE PAID OFF IN LESS THAN 1 YEAR."
9270PRINT "INCREASE YOUR MONTHLY PAYMENT."
9280PRINT
9290GOTO 9610
9300PRINT "**************************************************"
9310PRINT
9320PRINT TAB(9);"PAYMT";TAB(19);"APPLIED TO";TAB(34);"BALANCE"
9330PRINT "MTH.";TAB(10);"INT.";TAB(22);"LOAN";TAB(35);"DUE"
9340PRINT "----";TAB(9);"-----";TAB(21);"------";TAB(34);"-------"
9350T=0
9360X=0
9370FOR N=1 TO 37
9380I=B*R/1200
9390I=INT(100*I+.5)/100
9400B=B+I-M
9410T=T+I
9420 X=X+1
9430 PRINTUSING' ##    ###.##       ###.##       ######.##',X,I,M-I,B
9440IF B <= M THEN 9460
9450NEXT N
9460N=N+1
9470 F=B
9480I=B*R/1200
9490I=INT(100*I+.5)/100
9500T=T+I
9510 X=X+1
9520 PRINTUSING' ##    ###.##       ###.##            #.#',X,I,F,0
9530 PRINT
9540 PRINT'----------------------------------------------------'
9550 PRINT
9560 PRINT'MONTHS TO PAYOFF LOAN:';N
9570 PRINT'TOTAL INTEREST CHARGES:';T
9580 PRINT
9590 PRINT'----------------------------------------------------'
9600 PRINT
9610 INPUT "DO YOU HAVE ANOTHER CASE";N$
9640 IFN$='NO'THEN9660ELSEIFN$<>'YES'THENPRINT:PRINT'PLEASE ANSWER ';
	'YES OF NO':GOTO9600
9650 GO TO 9090
9660 PRINT
9670 PRINT "***************************************************"
9899 GO TO 9999
9900 IF ERR=52 THEN RESUME
9910 PRINT" THERE IS A MISTAKE SOMEWHERE, PLEASE REENTER":RESUME9090
9999 END