9000 REM ****MKBUY*****BUSINESS PROGRAM**REVISED APRIL, BY ED BAKER***
9002 REM MKBUY*********VERSION #1  (7/31/69)*****MAKE-BUY ANALYSIS
9004 PRINT '   *  MAKE-BUY ANALYSIS  *'
9006 PRINT
9008 REM INPUT THE NAME OF THE COMPONENT UNDER CONSIDERATION
9010 REM (FIRST QUESTION) IN THE SINGULAR, NOT THE PLURAL.
9012 REM THIS PROGRAM DOES TAKE THE INVESTMENT TAX CREDIT INTO ACCOUNT.
9014 REM    INITIALIZATION
9016 DIM A(25),B(25),C(25),D(25)
9034 C2,C8,A1,Y1,A(1),B(1),C(1),D(1)=0
9050 PRINT
9052 PRINT
9054 PRINT ' THIS PROGRAM CALCULATES THE PRESENT VALUE OF THE COST'
9056 PRINT 'SAVING INCURRED BY MAKING A PRODUCT AS OPPOSED TO BUYING'
9058 PRINT 'IT.'
9060 PRINT
9062 PRINT"FIRST WE WOULD LIKE TO ASK YOU A FEW QUESTIONS.."
9064 PRINT:PRINT
9068 PRINT 'WHAT IS THE NAME OF YOUR COMPANY';
9070 INPUT D$
9072 PRINT
9074 PRINT 'WHAT IS THE NAME OF THE COMPONENT YOU ARE CONSIDERING'
9076 PRINT 'MAKING OR BUYING';
9078 INPUT I$
9080 PRINT
9082 PRINT '***** ENTER ALL COSTS IN DOLLARS *****'
9084 PRINT
9086 PRINT ' 1) WHAT IS THE COST TO BUY A ';I$;' FOR YOUR PLANT';
9090 INPUT I1
9092 PRINT
9094 PRINT ' 2) WHAT IS THE COST TO MANUFACTURE A ';I$;' IN YOUR PLANT ';
9096 PRINT 'INCLUDING DIRECT MATERIALS AND LABOR BUT NOT OVERHEAD';
9098 INPUT I2
9100 PRINT
9102PRINT" 3) WHAT IS THE INITIAL INVESTMENT (COST OF THE EXTRA"
9104PRINT"MACHINERY THAT WOULD BE NEEDED TO MANUFACTURE "I$;"S";
9106 INPUT I3
9108 PRINT
9110 PRINT ' 4) WHAT IS THE LIFE OF THE INVESTMENT IN YEARS';
9112 INPUT I4
9114 GOSUB 9438
9116 PRINT
9118 PRINT ' 5) WHAT IS THE SALVAGE VALUE OF THIS INVESTMENT';
9120 INPUT I5
9122 C(I4+1)=-I5
9124 PRINT:PRINT'NOTE: SUM-OF-THE-YEARS-DIGITS METHOD WILL BE USED TO '
9126 PRINT 'DEPRECIATE THE INVESTMENT.'
9128 S4=0
9130 FOR S5=1 TO I4
9132 S4=S4+S5
9134 NEXT S5
9136 PRINT
9138 PRINT ' 6) WHAT ARE THE ANNUAL FIXED COSTS (SUCH AS SUPERVISION AND'
9140 PRINT 'MAINTENANCE) INVOLVED IN YOUR MAKING ';I$;'S';
9142 INPUT I7
9144 PRINT
9146 PRINT ' 7) WHAT IS YOUR CORPORATE TAX RATE IN PERCENT';
9148 INPUT I8
9150 S1=I8
9152 GOSUB 9190
9154 IF S2=1 THEN 9146
9156 I8=I8/100
9158 PRINT
9160 PRINT ' 8) WHAT IS THE LOCAL TAX RATE ON THE EXTRA INVESTMENT IN DOLLARS'
9162 PRINT 'PER THOUSAND';
9164 INPUT I9
9166 I9=I9/1000
9168 PRINT
9170 PRINT ' 9) WHAT IS YOUR COST OF CAPITAL IN PERCENT';
9172 INPUT J1
9174 S1=J1
9176 GOSUB 9190
9178 IF S2=1 THEN 9170
9180 J1=J1/100
9182 PRINT
9184 PRINT ' 10) WHAT IS YOUR ESTIMATE OF THE YEARLY DEMAND FOR ';I$;'S';
9186 INPUT J2
9188 GOTO 9206
9190 REM PERCENTAGE CHECK SUBROUTINE
9192 IF S1>1 THEN 9202
9194 IF S1=0  THEN 9202
9196 PRINT 'PLEASE GIVE YOUR ANSWER IN PERCENT.'
9198 S2=1
9200 GOTO 9204 
9202 S2=2
9204 RETURN
9206 D(1),C7=D1
9208 D(I4+1)=-15*(1-I8)
9210 FOR A=2 TO I4
9212 C(A),D(A)=0
9214 NEXT A
9216 REM  EXECUTIVE ROUTINE
9218 FOR A=2 TO I4+1
9220 C6=(1+J1)+(A)
9222 A(A)=I1*J2
9224 B(A)=A(A)*(1-I8)
9226 C5=B(A)/C6
9228 C8=C8+C5
9230 GOSUB 9458
9232 C3=(I3-C2)*I9
9234 C4=(I2*J2)+I7+C3
9236 C(A)=C4+C1+C(A)
9238 D(A)=(C4*(1-I8))-(C1*I8)+D(A)
9240 C5=D(A)/C6
9242 C7=C7+C5
9244 NEXT A
9246 REM PRINTOUT ROUTINE
9248 PRINT
9250 PRINT '**********************************************************'
9252 PRINT
9254 PRINT 'THE PRESENT VALUE OF THE COST TO MAKE IS ';C7
9256 PRINT 'THE PRESENT VALUE OF THE COST TO BUY IS ';C8
9258 PRINT
9260 C9=ABS(C8-C7)
9262 ONSGN(C8-C7)+2GOTO9264,9278,9268
9264 C$='BUY'
9266 GOTO 9270
9268 C$='MAKE'
9270 PRINT D$;' SHOULD ';C$;' ';I$;
9272 PRINT 'S AT A SAVINGS OF ';C9;' DOLARS.'
9274 PRINT
9276 IF A1=1 THEN 9360
9278 PRINT
9280 PRINT ' **** THE FLOWS ****'
9282 PRINT
9284 PRINT TAB(10%);'IF BUY**********';TAB(38%);'IF MAKE*********';
9288 PRINT TAB(62%);'***NET***'
9290 PRINT 'YEAR';
9292 PRINT TAB(8%);'EXPENSE';TAB(20%);'CASH FLOW';TAB(36%);'EXPENSE';
9294 PRINT TAB(48%);'CASH FLOW';TAB(62%);'CASH FLOW'
9302 FOR A=1 TO I4+1
9304 PRINTA;
9306 PRINT TAB(7%);A(A);TAB(19%);B(A);TAB(33%);C(A);TAB(47%);
9320 PRINT D(A);
9322 S7=B(A)-D(A)
9324 PRINT TAB(61%);
9326 PRINT S7
9328 NEXT A
9330 REM  SENSITIVITY CHECK
9332 PRINT
9334 PRINT '--------------------------------------------------------------'
9336 PRINT
9338 PRINT 'WOULD YOU LIKE TO SEE THE EFFECT OF CHANGING A VARIABLE';
9342 INPUT A$
9344 IF A$='NO'ORA$='0'ORA$=''THEN9470
9346 A1=1
9348 PRINT 'WHAT IS THE NUMBER OF THE QRESTION OF WHICH YOU WOULD LIKE'
9350 PRINT 'TO CHANGE YOUR ANSWER';
9352 INPUT A2
9354 PRINT 'WHAT IS THE NEW VALUE';
9356 INPUT A3
9358 GOTO 9380
9360 PRINT '--------------------------------------------------------------'
9362 PRINT
9364 PRINT 'MORE CHANGES';
9366 INPUT A$
9368 IF A$='NO'ORA$='0'ORA$=''THEN9470
9370 PRINT 'SAME QUESTION'
9372 INPUT J$
9374 IF J$='NO'ORJ$='0'ORJ$=''THEN9348
9376 PRINT 'NEW VALUE';
9378 INPUT A3
9380 ON A2 GOTO 9382,9386,9390,9394,9408,9414,9418,9422,9426,9430
9382 I1=A3:GOTO9432
9386 I2=A3:GOTO 9432
9390 I3=A3:GOTO 9432
9394 I4=A3
9396 GOSUB 9438
9398 C(1)=I3
9400 S4=0
9402 FOR S5=1 TO I4
9404 S4=S4+S5
9406 NEXT S5
9408 I5=A3
9410 C(I4+1)=-15
9412 GOTO 9432
9414 I7=A3:GOTO9432
9418 I8=A3/100:GOTO 9432
9422 J1=A3/1000:GOTO9432
9426 J1=A3/100:GOTO9432
9430 J2=A3
9432 C2,C8=0
9434 GOTO 9206
9436 GOTO9999
9438 REM  INVESTMENT TAX CREDIT
9440 IF I4>=4 THEN 9446
9442 S3=0:GOTO 9454
9446 IF I4>=8 THEN 9452
9448 S3=(2/3)*.07*I3:GOTO 9454
9452 S3=.07*I3
9454 D1=I3-S3
9456 RETURN
9458 REM  DEPRECIATION SUBROUTINE
9460 S6=I3-I5
9462 C1=S6*((I4+2-A)/S4)
9464 C2=C2+C1
9466 RETURN
9470 PRINT '*************************************************************'
9496 GOSUB 9438
9498 C(1)=I3
9999 END