9000 REM ***** STKSMO ***** BUSINESS PROGRAM
9005 REM STKSMO************VERSION #1(7/31/69)**EXP SMOOTHING AS STOCK GUIDE
9010 REM
9015 PRINT "*  EXPONENTIAL SMOOTHING AS A STOCK GUIDE  *"
9020 PRINT
9025 DIM P(100),X(100),Y(100),N(100),G(100),Q(100)
9030 P9,X9,Y9,N9,G9,Q9=100
9035 Q=0
9040 IF Q=1 THEN 9090
9045 IF Q=2 THEN 9279
9050 PRINT " THIS PROGRAM USES EXPONENTIAL SMOOTHING OF PAST PRICE DATA TO PROVIDE"
9055 PRINT "A GUIDE FOR THE TIMING OF BUY AND SELL ORDERS."
9060 PRINT
9065 PRINT " TO ENTER THE DATA FOR THE STOCK YOU ARE CONSIDERING, TYPE THE DATA"
9070 PRINT " BEGINNING IN LINE 9900.  NO MORE THAN 100 PERIODS MAY BE CONSIDERED."
9075 PRINT "         THEN TYPE: '9035  LETQ=1'"
9080 PRINT "                    'RUN'"
9085 GOTO 9999
9090 PRINT "  FOR HOW MANY PERIODS DID YOU ENTER DATA";
9095 INPUT M
9100 PRINT
9105 PRINT "ENTER A SMOOTHING COEFFICIENT BETWEEN 0.1 AND 0.9";
9110 INPUT A
9115 FOR T=1 TO M
9120 READ P(T)
9125 NEXT T
9130 G(G9)=P(2)-P(1)
9135 N(N9)=P(1)-G(G9)
9140 X(X9)=N(N9)-((1-A)/A)*G(G9)
9145 Y(Y9)=N(N9)-(2*(1-A)/A)*G(G9)
9150 GOSUB 9380
9165 PRINT
9170 PRINT "DO YOU WISH TO USE THIS PROGRAM AS A COTINUING AID FOR THE TIMING OF"
9185 PRINT "BUY AND SELL DECISIONS ON THIS SAME STOCK AT SOME FUTURE TIME";
9195 INPUT N$
9196 PRINT
9197 PRINT
9200 IF LEFT(N$,2)="NO" THEN 9272
9205 PRINT
9240 PRINT "WHAT IS THE NAME OF THIS STOCK";
9245 INPUT A$
9250 PRINT "WHAT TIME PERIOD HAVE YOU USED THUS FAR??(EX:MAY1,1969 TO MAT 1.1970)"
9255 INPUT B$
9260 PRINT "THEN ENTER THE FOLLOWING LINES BEFORE SIGNING OFF:"
9262 PRINT "     '9035  LET Q=2'"
9263 PRINT "     '9280  LET X(X9) =";Y(M);"'"
9264 PRINT "     '9287  LET Y(Y9) =";Y(M);"'"
9265 PRINT "     '9288  LET A =";A;"'"
9266 PRINT "     '9280  LET A$ ='";A$;"' '"
9267 PRINT "     '9281  LET B$ ='";B$;"' '"
9268 PRINT "     'KILL-STKSMO'"
9269 PRINT "     'SAVE'"
9270 GOTO 9999
9272 PRINT "THEN ENTER '9035 LET Q=0', 'KILL-STKSMO', AND 'SAVE' BEFORE SIGNING OFF."
9275 GOTO 9999
9279 PRINT "THIS PROGRAM IS BEING USED TO PROVIDE A GUIDE TO THE TIMING OF BUY"
9285 PRINT "AND SELL ORDERS ON ";A$;"."
9290 PRINT
9295 PRINT "IT IS BASED UPON DATA FROM THE PERIOD:";B$;"."
9300 PRINT
9305 PRINT "FOR HOW MANY ADDITIONAL PERIODS FOLLOWING THE LAST MARKET DATA"
9310 PRINT "SHPWN DO YOU WISH TO ENTER DATA";
9315 INPUT M
9320 FOR T=1 TO M
9325 PRINT "WHAT IS THE PRICE FOR PERIOD";T;
9330 INPUT P(T)
9335 NEXT T
9340 PRINT
9345 PRINT "WHAT PERCENTAGE DIFFERENCE (EXPRESSED AS A DECIMAL) BETWEEN THE PRE-"
9350 PRINT "DICTED AND ACTUAL PRICE WOULD YOU LIKE TO USE AS A SCREENING RATE"
9355 PRINT "FOR THE BUY AND SELL ORDERS";
9360 INPUT C
9365 GOSUB 9380
9370 GOSUB 9495
9375 GOTO 9170
9377 PRINT
9380 PRINT "*********************************************************************"
9390 PRINT "PERIOD         ACTUAL         EXTIMATED",
9395 PRINT "ESTIMATED  PREDICTED" 
9400 PRINT "               PRICE          PRICE",
9405 PRINT " GROWTH        PRICE FOR"  
9410 PRINT " "," "," "," ","NEXT PERIOD"
9415 PRINT
9420 FOR T=1 TO M
9425 IF T>1 THEN 9440
9430 X(1)=A*P(1)+(1-A)*X(X9)
9435 Y(1)=A*X(1)+(1-A)*Y(Y9)
9436 GOTO 9450
9440 X(T)=A*P(T)+(1-A)*X(T-1)
9445 Y(T)=A*X(T)+(1-A)*Y(T-1)
9450 N(T)=2*X(T)-Y(T)
9455 G(T)=(A/(1-A))*(X(T)-Y(T))
9460 Q(T+1)=N(T)+G(T)
9465 PRINT T,P(T),N(T),G(T),Q(T+1)
9470 NEXT T
9475 PRINT
9480 PRINT "***********************************************************************"
9485 PRINT
9490 RETURN
9495 FOR T=1 TO M
9500 H=Q(T+1)/P(T)-1
9505 IF H>C THEN 9555
9510 IF H<-C THEN 9535
9515 PRINT "IN PERIOD";T;"THE PREDICTED PRICE VARIES FROM THE ACTUAL PRICE BY"
9520 PRINT "LESS THAN";C*100;"PERCENT, AND NO BUY OR SELL ORDER IS INDICATED."
9530 GOTO 9570
9535 PRINT "IN PERIOD";T;"THE PREDICTED PRICE IS BELOW THE ACTUAL PRICE BY MORE"
9540 PRINT "THAN";C*100;"PERCENT, AND A SELL ORDER IS INDICATED."
9550 GOTO 9570
9560 PRINT "THAN";C*100;"PERCENT, AND A BUY ORDER IS INDICATED."
9570 PRINT
9575 PRINT
9580 NEXT T
9585 PRINT "-----------------------------------------------------------------------"
9590 RETURN
9595 PRINT "-----------------------------------------------------------------------"
9900 DATA 10,12,14,13,14,15,16,18
9999 END