9000 REM ***** TRUINT ***** BUSINESS PROGRAM
9001 REM TRUINT *********** VERSION #1 (7/31/69) ***** TRUE INTEREST RATES
9002 REM REVISED JUNE,1972   ANDY ROTH C.C.G.
9003 PRINT "*  TRUE ANNUAL INTEREST RATE  *"
9004 PRINT
9010 PRINT "THIS PROGRAM CALCULATES THE TRUE ANNUAL INTEREST RATE CHARGED ON AN"
9020 PRINT "INSTALLMENT LOAN."
9030 PRINT
9040 PRINT
9050 PRINT "IF YOU NEED INSTRUCTIONS TYPE 1, OTHERWISE TYPE 0:  ";
9060 INPUT X
9070 IF X=0 THEN 9120
9080 PRINT "TO USE THIS PROGRAM IT IS NECESSARY FOR YOU TO SUPPPLY THE VALUES FOR"
9090 PRINT "FOUR VAIABLES:  A = AMOUNT OF LOAN (IN $), P = AMOUNT OF EACH"
9100 PRINT "PAYMENT ($), N = THE TOTAL NUMBER OF PAYMENTS DUE, AND K = THE NUMBER"
9110 PRINT "OF PAYMENTS DUE IN ONE YEAR."
9115 PRINT
9120 PRINT"WHAT ARE A,P,N,K";
9130 INPUT A,P,N,K
9140 PRINT
9150 IF N=1 THEN 9550
9160 IF P*N >= A THEN 9220
9170 PRINT
9180 PRINT "THATS NOT REASONABLE; THE PAYMENTS ADD UP TO LESS THAT THE AMOUNT"
9190 PRINT "OWED. TRY AGAIN."
9200 PRINT
9210 GOTO 9120
9220 LET R=0
9230 LET D=100
9240 GOSUB 9330
9250 IF P=P1 THEN 9430
9260 IF P>P1 THEN 9290
9270 LET R=R-D
9280 GOTO 9300
9290 LET R=R+D
9300 LET D=D/2
9310 IF D<.0001 THEN 9430
9320 GOTO 9240
9330 R1=R/(100*K)
9340 LET Q=1+R1
9350 IF N*LOG(Q)/LOG(10) <= 75 THEN 9380
9360 LET P1=A*R1
9370 RETURN
9380 IF Q>1 THEN 9410
9390 LET P1=A/N
9400 RETURN
9410 LET P1=A*Q^N*R1/(Q^N-1)
9420 RETURN
9430 LET R=.01*INT(.5+100*R)
9440 IF R<199.5 THEN 9500
9450 PRINT
9460 PRINT "ARE YOU SURE THE DATA IS CORRECT?  THE INTEREST RATE WOULD BE OVER"
9470 PRINT "200 PERCENT.  TRY AGAIN."
9480 PRINT
9490 GOTO 9120
9500 PRINT "THE TRUE ANNUAL INTEREST RATE = ";R
9510 PRINT
9520 PRINT
9530 PRINT "ANOTHER CASE??  TYPE 'N' TO QUIT, 'Y' TO TRY AGAIN";
9532 INPUT Q$
9534 IF Q$="N" THEN 9999
9540 GOTO 9120
9550 LET R=(P/A-1)*K
9560 LET R=100*R
9570 GOTO 9430
9999 END