5 REM *** WRITTEN BY TOM KARZES, CURTIS JR HS, SUDBURY, MA
6 REM *** MODIFIED BY DAVE AHL, DIGITAL
10 &"YOU ARE IN A LARGE, NEW GOVERNMENT BUILDING WITH 1,000,000"
20 &"ROOMS IN IT.  THE BUILDING IS 100 ROOMS LONG (0-99), 100"
30 &"ROOMS WIDE (0-99), AND 100 FLOORS HIGH (0-99).":&
40 &"A MAD BOMBER HAS HIDDEN A BOMB IN ONE OF THE ROOMS AND"
50 &"HAS JUST PHONED A THREAT THAT THE BOMB IS SET TO GO"
60 &"OFF IN 200 SECONDS.  FORTUNATELY, YOU HAPPEN TO HAVE A BOMB-"
70 &"TRACKER THAT SENDS OUT SIGNALS THAT GET STRONGER AS YOU"
80 &"GET CLOSER TO THE BOMB.  YOU ARE STARTING IN ROOM 0,0,0"
90 &"AND IT TAKES 10 SECONDS TO MOVE TO ANY OTHER ROOM.":&
100 RANDOMIZE:A=INT(100*RND):B=INT(100*RND):C=INT(100*RND)
110 IF A=0 AND B=0 AND C=0 THEN 100
120 P1=A/100+B+C*100:D,E,F,G,P=0
125 &"SIGNAL","CURRENT ROOM","SEC. INTO","COORDINATES FOR"
130 &"STRENGTH","L , W , H","MISSION","SEARCH (L,W,H)"
132 B$=" ####.##      ##  ##  ##     ###           "
135 PRINT USING B$,10000-ABS(P1-P),D,E,F,G;
140 INPUT D,E,F:G=G+10:P=D/100+E+F*100:IF P=P1 THEN 170
145 IF G=200 THEN 150 ELSE GOTO 180
150 &"BOOOOOOOMMM!!!":&"YOU BLEW IT.  THE BUILDING BLEW UP."
155 &:INPUT "WANT TO PLAY AGAIN (YES OR NO)";A$
160 IF A$="NO" THEN 999 ELSE &:&:GOTO 100
170 &"BOMB DEACTIVATED AT"G"SECONDS!!!":&:GOTO 155
180 IF D>99 OR D<0 OR E>99 OR E<0 THEN 200
190 IF F>99 THEN 220 ELSE IF F<0 THEN 230 ELSE GOTO 135
200 &"YOU WALKED OUT A WINDOW ON THE";:IF F<4 THEN 240
201 & F"TH FLOOR!!!"
202 &"YOU WERE KILLED AND"200-G"SECONDS LATER THE BUILDING"
203 &"BLEW UP!!!":&:GOTO 155
220 &"YOU ARE NOW"F*9"FEET IN THE AIR!!!":GOTO 202
230 &"YOU ARE NOW -"F*9"FEET UNDERGROUND!!!":GOTO 202
240 ON F GOTO 250,260,270
250 &" 1ST FLOOR!!!":GOTO 202
260 &" 2ND FLOOR!!!":GOTO 202
270 &" 3RD FLOOR!!!":GOTO 202
999 END