5 REM *** WRITTEN BY CHRIS REID, LEXINGTON HS, '73
6 REM *** CONVERTED TO BASIC-PLUS BY DAVE AHL, DIGITAL 11/45 GROUP
10 DIM S(5),A(5),L(5),D(5),P(5)
15 &:&:&"I AM THINKING OF A WORD -- YOU GUESS IT.  I WILL GIVE"
16 &"YOU CLUES TO HELP YOU.  GOOD LUCK !!":&:&
20 RANDOMIZE
30 &:&:&"STARTING A NEW GAME....":RESTORE
40 READ N:C=INT(N*RND+1)
60 READ S$ FOR I=1 TO C
90 G=0
100 CHANGE S$ TO S
110 A(I)=45 FOR I=1 TO 5
120 P(J)=0 FOR J=1 TO 5
150 INPUT "GUESS A 5-LETTER WORD";L$
170 G=G+1
174 IF L$=S$ THEN 500
180 CHANGE L$ TO L
190 IF L(1)=63 THEN 300
200 IF L(0)<>5 THEN 400
205 M=0:Q=1
210 FOR I=1 TO 5:FOR J=1 TO 5
230 IF S(I)<>L(J) THEN 260
231 P(Q)=L(J):Q=Q+1
233 IF I<>J THEN 250
240 A(J)=L(J)
250 M=M+1
260 NEXT J:NEXT I
270 A(0)=5:P(0)=M
275 CHANGE A TO A$:CHANGE P TO P$
280 &"THERE WERE"M"MATCHES AND THE COMMON LETTERS WERE....";P$
285 &"FROM THE EXACT LETTER MATCHES, YOU KNOW.............";A$
286 IF A$=S$ THEN 500
287 IF M>1 THEN 290
288 &:&"IF YOU GIVE UP, TYPE ? FOR YOUR NEXT GUESS"
289 &
290 &:GOTO 150
300 CHANGE S TO S$
310 &"THE SECRET WORD IS "S$:&:GOTO 30
400 &:&"PLEASE GUESS A 5 LETTER WORD.  AGAIN....":G=G-1:GOTO 150
500 &"YOU HAVE GUESSED THE WORD!!  IT TOOK"G"GUESSES.":&
505 & CHR$(7); FOR N=1 TO 10
510 INPUT "WANT TO PLAY AGAIN (Y OR N)";Q$:IF Q$="Y" THEN 30
520 &"OKAY.  HOPE YOU HAD FUN !!":GOTO 999
530 DATA 12,"DINKY","SMOKE","WATER","GRASS","TRAIN","MIGHT","FIRST"
540 DATA "CANDY","CHAMP","WOULD","CLUMP","DOPEY"
999 END