10 &"GAME OF YAHTZEE":&
27 DIMA(5),B(5),H(7),S(13):RANDOM:I3=10:S(G)=GFORG=1TO13
37 INPUT"INSTRUCTIONS";Q$:IFASCII(Q$)=78THEN77
47 &"THIS IS THE GAME OF YAHTZEE"
57 &"THE OBJECT OF THE GAME IS TO BEAT THE TOP SCORE"
        :&"YOU HAVE 5 DICE TO ROLL 3 TIMES KEEPING THE ONES YOU WANT"
67 &"40 BONUS PTS. IF TOTAL OF FIRST HALF IS > OR = 63"
        :&"2ND OR 3RD YAHTZEES SCORE 100 PTS."
77 G$="ONESTWOSTHREESFOURSFIVESSIXES"
87 B$="3 OF KIND4 OF KINDCHANCE   FULL HOUSESM. STR.  LR. STR.  YAHTZEE 
97 INPUT"LIST OF COMBINATIONS";X$:IFASCII(X$)=78THEN127
107 &"1ST HALF":FORI=1TO6:&I"  "MID(G$,I*6-5,6):NEXTI:&"2ND HALF":
        FORI=7TO9:&I"  "MID(B$,I*10-69,10)"  TOTAL":NEXTI
117 FORI=10TO13:I3=I3+10:&I"  "MID(B$,I*10-69,10)"  "I3:NEXTI
        :&" 14 PLACES ZEROS"
127U2=0:FORC=1TO13:GOSUB477:&:&"ROLL *"C"*"
137 FORT=1TO5:A(T)=INT(RND(0)*6+1):&T"---"A(T):NEXTT:D=1:FORF=1TO2
147INPUT"NO. TO ROLL AGAIN";D:IFD<0ORD>5THEN147ELSEIFD=0THEN187
157MATB=ZER:&"NUMBERS";:MATINPUTB
167 GOTO157IFB(T)<1ORB(T)>5FORT=1TOD:A(B(T))=INT(RND(0)*6+1)FORT=1TOD
177 &"DICE":FORT=1TO5:&T"---"A(T):NEXTT:NEXTF
187 INPUT"COMBINATION";G:IFG=14THEN287
197 IFG<1ORG>13THEN187ELSEIFS(G)=0THEN187ELSEIFG<7THEN297
207 ONG-6GOSUB307,307,327,337,377,377,437
217 T,K,B2=0:NEXTC:IFU>=63THENU=U+40
227 U2=U1+U:&"1ST HALF ="U:&"2ND HALF ="U1:&"TOTAL ="U2
237OPEN"T1.BAM"AS FILE 1:INPUT#1,Z:IFZ=U2THEN257ELSEIFZ>U2THEN267
247 &"OUR TOP SCORE IS"Z:GOTO277
257 &"YOU HAVE TIED THE TOP SCORE":GOTO277
267 &"YOU BEAT THE TOP SCORE BY"U2-Z"PTS.":Z=U2:&#1,Z
277 CLOSE 1:INPUT"ANOTHER GAME";S$:IFASCII(S$)=89THEN127ELSE527
287 INPUT"#";G:IFS(G)=0ORG<1ORG>13THEN287ELSE467
297 U=U+GIFA(T)=GFORT=1TO5:GOTO457
307 FORE=1TO6:K=K+1IFA(T)=EFORT=1TO5:IFK>=G-4THEN327
317 K=0:NEXTE:GOTO187
327 U1=U1+A(T)FORT=1TO5:GOTO467
337 M=A(1):GOTO347IFA(T)<>MFORT=1TO5
347 M1=A(T):FORT=1TO5:IFA(T)=MTHENN=N+1ELSEIFA(T)=M1THENN1=N1+1
357 NEXTT:IFN=3ANDN1=2ORN=2ANDN1=3THEN367ELSE187
367 U1=U1+20:GOTO467
377 FORP=2TO7:GOTO407IFH(P-1)+1=A(T)FORT=1TO5:B2=0
387 IFP=2THENH(P)=1
397 NEXTP:GOTO187
407 H(P)=A(T):B2=B2+1:IFB2=G-7THEN417ELSE397
417 IFG-7=4THENU1=U1+30ELSEU1=U1+40
427 GOTO467
437 X=A(1):GOTO187IFA(T)<>XFORT=1TO5:IFX1=1THENU1=U1+100ELSEU1=U1+50
447 X1=1:RETURN
457 S(G)=0:GOTO217
467 S(G)=0:RETURN
477 IFC<5THEN517ELSEINPUT"UNFILLED COMBINATIONS";P$
487 IFASCII(P$)=78THEN517
497 FORR=1TO6:IFS(R)=0THEN507ELSE&R"  "MID(G$,R*6-5,6)
507 NEXTR:FORR=7TO13:IFS(R)=0ORR=13ANDX1=1THEN517
        ELSE&R"  "MID(B$,R*10-69,10)
517 NEXTR:RETURN
527 END