D8|2R lLdNr`~p@p~
BD||R<ll100 REM GERMAN WRITTEN BY FRED WHITE   MANKOTA STATE COLLEGE
105 REM CONVERTED TO BASIC+ 02/73 MARK LINTON  PROJECT DELTA
110 RANDOMIZE:DIM Q(78),M$(100%),N$(100%),O$(100%)
130 GO TO 140
131 PRINT "INSTRUCTIONS FOR $GERMAN.BAS"
132 PRINT "    WHEN ASKED FOR 'NUMBER OF PROBLEMS?' RESPOND WITH"
133 PRINT "THE NUMBER OF PROBLEMS YOU WISH TO ANSWER."
134 PRINT "THEN FOR THAT NO. OF PROBLEMS THE COMPUTER WILL PRINT"
135 PRINT "OUT A GERMAN SENTENCE WITH '...' IN PLACE OF AN "
136 PRINT "ADJECTIVE ENDING.  YOU WILL THEN GET A '?' WHICH YOU"
137 PRINT "SHOULD RESPOND TO WITH THE CORRECT ADJECTIVE ENDING"
138 PRINT "TO FIT IN THE SENTENCE. IF YOU ARE RIGHT YOU WILL PROCEED"
139 PRINT "TO THE NEXT SENTENCE, IF NOT THEN YOU WILL BE TOLD":
	PRINT "THE CORRECT ANSWER AND WHY.  AFTER YOUR PROBLEMS":
	PRINT "IF YOU MISS ANY YOU WILL HAVE TO REPEAT THE ONES":
	PRINT "YOU MISSED.":PRINT:PRINT "GOOD LUCK!":GO TO 150
140 INPUT "INSTRUCTIONS";Q$:PRINT:IF Q$="YES" OR Q$="JA" THEN 131
150 INPUT "NUMBER OF PROBLEMS";N7:IF N7=0 THEN 999
160 PRINT:OPEN "$GERMAN.DAT" FOR INPUT AS FILE 1%:
	DIM #1%,A$(70%)=64%,B$(70%),C$(70%),G$(70%),D$(70%)
180 FOR Q0%=1% TO N7:PRINT:Q%=INT(68%*RND+1%):PRINT A$(Q%):INPUT I$
185 A$=A$(Q%):B$=B$(Q%):C$=C$(Q%):D$=D$(Q%):G$=G$(Q%)
190 IF I$=B$(Q%) THEN 230
200 IF I$="EM" OR I$="E" OR I$="ES" OR I$="ER" OR I$="EN" OR
	I$="DUNKLEN" OR I$="DUNDELEN" OR I$="DUNKELN" OR I$="MU:DE"
	THEN 250 ELSE IF I$="MUDE" THEN 240
210 PRINT:PRINT "WHAT KIND OF AN ANSWER IS THAT?"
220 GO TO 140
230 T=T+1:NEXT Q0%
235 GO TO 270
240 PRINT "YES. BUT DO NOT FORGET THE UMLAUT.  IT SHOULD BE MU:DE."
250 GO SUB 340
260 W=W+1:M$(W)=A$:GO TO 230
270 PRINT:PRINT "YOU GOT";T-W;"CORRECT OUT OF";T;"PROBLEMS."
280 PRINT USING "YOUR SCORE IS ###% CORRECT",(T-W)/T*100:IF W=0 THEN 999
290 PRINT:PRINT:PRINT "REMEDIAL EXERCISES":
		PRINT "-------- ---------"
300 FOR D9%=1% TO W:FOR B9%=1% TO 68%:IF A$(B9%)<>M$(D9%)
	THEN 320
305 C$=C$(B9%):D$=D$(B9%):G$=G$(B9%)
310 A$=A$(B9%):PRINT:PRINT A$:B$=B$(B9%):INPUT I$:IF I$<>B$ THEN 330
320 NEXT B9%:NEXT D9%:IF W1>0 THEN PRINT "IF YOUR A GERMAN STUDENT, YOU'RE"+
	" IN TROUBLE!!!!":GO TO 999
325 PRINT "YOU'LL PASS YET. ":GO TO 999
330 W1=1:GO SUB 340:GO TO 320
340 PRINT:PRINT
350 PRINT "WRONG. THE CORRECT ANSWER IS '";B$;"'."
400 O9%=INSTR(1%,A$,"."):O8%=INSTR(O9%,A$," "):O7%=INSTR(O8%+1%,A$," ")
410 IF O7%=0% THEN O7%=LEN(A$)
430 S$=MID(A$,O8%+1%,O7%-O8%-1%):PRINT S$;" IS ";C$;" ";G$;"."
440 PRINT "IT IS THE ";D$;" DECLENSION.":PRINT:RETURN
999 CLOSE 1%:END
KEY