1 REM--REWRITTEN BY H. L. LING--JACKSON--10/21/71
2 REM--SUPPLIED BY MANKOTA STATE COLLEGE
10 D1=2000
12 C1=100
13 W1=1
14 W2=.1
15 RANDOMIZE
16 FOR I=1 TO 20
17 T1=INT(60*RND+1)+1930
18 NEXT I
20 PRINT "************************************************************************"
21 PRINT "THIS PROGRAM ILLUSTRATES THE COBWEB MODEL FOR SUPPLY"
22 PRINT "AND DEMAND.  IN THIS MODEL QUANTITY DEMANDED DEPENDS"
23 PRINT "ON CURRENT PRICES, QUANTITY SUPPLIED DEPENDS ON LAST"
24 PRINT "SEASONS PRICES AND THE MARKET IS CLEARED EXCEPT FOR"
25 PRINT "RANDOM ERROR.  THE AMERICAN ONION MARKET IS A TYPICAL"
26 PRINT "EXAMPLE OF SUCH A MARKET.  YOU ARE ASKED TO ASSUME THE"
27 PRINT "ROLE OF AN ONION FARMER WHO HAS RESOURCES TO PRODUCE A"
28 PRINT "MAXIMUM OF FIFTY THOUSAND SACKS OF ONIONS PER YEAR"
29 PRINT "ALL OF THE ONIONS YOU HARVEST ARE SOLD, AND YOU WILL BE"
30 PRINT "WORKING TO FIND THE PRODUCTION LEVEL WHICH MAXIMIZES"
31 PRINT "YOUR  OWN PROFITS.  ASSUMING YOU ARE A TYPICAL ONION"
32 PRINT "FARMER, THIS LEVEL WILL CORRESPOND TO THE  POINT AT"
33 PRINT "WHICH THE SUPPLY AND DEMAND CURVES FOR THE WHOLE MARKET"
34 PRINT "INTERSECT. HOW MANY SACKS WILL YOU TRY TO PRODUCE IN"
35 PRINT "THE FIRST YEAR. (USE A MINUS  NUMBER TO EXIT)."
40 INPUT S1
50 IF S1<=0 THEN 9999
60 IF S1 <=50000 THEN 100
70 PRINT "YOU DO NOT HAVE THE RESOURCES TO PRODUCE";S1;"SACKS"
80 PRINT "OF ONIONS.  TRY PRODUCING A SMALLER QUANTITY."
90 GOTO 40
100 L1=10^.681*D1^1.31
110 L3=10^(.134+.0123*(T1-1924))*C1^(-.512)*W1^(-1.2)
120 U1=10^.13*W2^2.4*(S1*.001)^2.56
130 Q1=INT(S1-U1+.50001)
140 P1=L1*(Q1*.001)^(-2.27)*.01
150 P1=INT(P1*100)/100
155 Q2=EXP(LOG(1/L3/L1^.324)/(-1.7355))
160 L2=-1.27*L1*Q2^.33/(-1.6)
170 Q2=INT(Q2*1000+.50001)
180 C2=L2*(Q1*.001)^(-2.6)*.01
190 P2=INT(Q1*(P1-C2)*100)/100
200 T2=Q1*P1
210 IF P2>=0 THEN 260
220 PRINT "UNFORTUNATELY, EVEN THOUGH YOU SOLD";Q1;"SACKS OF"
230 PRINT "ONIONS, YOUR FIXED COSTS WERE HIGH ENOUGH TO CAUSE YOU"
240 PRINT "TO SUFFER A LOSS.  TRY AGAIN, BUT TRY TO PRODUCE MORE!"
250 GOTO 40
260 PRINT "YOU SOLD ";Q1;" SACKS AT $";P1;" PER SACK."
270 PRINT "TOTAL REVENUE = $";T2;"         PROFITS = $";P2
280 IF ABS(Q1-Q2)>=50 THEN 540
290 PRINT "CONGRATUALTIONS!  YOU HAVE COME CLOSE TO THE MAXIMUM PROFIT."
300 PRINT "MAXIMIZING QUANTITY = ";Q2;"   SACKS OF ONIONS."
310 PRINT "***********************************************************************"
320 I1=I1+1
330 ON I1 GOTO 340,430,470,510,560
340 PRINT "UNFORTUNATELY, THE ONION MARKET IS NOT REALLY SO SIMPLE."
350 PRINT "IT IS AFFECTED BY MANY ENVIRONMENTAL AND ECONOMIC"
360 PRINT "CONDITIONS.  FOR AN EXAMPLE, WE WILL LET NATIONAL"
370 PRINT "DISPOSABLE INCOME INCREASE, WHICH WILL CAUSE A SHIFT IN"
380 PRINT "THE ONION MARKETS SUPPLY CURVE.  DECIDE WHAT EFFECT"
390 PRINT "THIS WILL HAVE ON THE LEVEL OF PRODUCTION NECESSARY"
400 PRINT "TO MAXIMIZE YOUR OWN PROFITS, AND CONTINUE.  "
410 D1=D1*1.2
420 GOTO 540
430 PRINT "A WAGE INCREASE IS NECESSARY FOR YOUR WORKERS DURING"
440 PRINT "THE NEXT SEASON, AND THIS WILL SHIFT YOUR SUPPLY CURVE."
450 W1=W1*1.2
460 GOTO 540
470 PRINT "THE PRICE OF ONION SEEDS HAS GONE DOWN ENABLING"
480 PRINT "YOU TO PRODUCE ATA A LOWER COST."
490 C1=C1*.85
500 GOTO 540
510 PRINT "POOR WEATHER IS PREDICTED FOR THE COMING SEASONS AND"
520 PRINT "THIS WILL REDUCE YOUR HARVEST SIGNIFICANTLY."
530 W2=W2*15
540 PRINT "HOW MANY SACKS WILL YOU TRY TO PRODUCE NEXT YEAR"
550 GOTO 40
560 PRINT "YOU HAVE RECEIVED RECOGNITION AS AN OUTSTANDING ONION"
570 PRINT "FARMER.  THIS IS THE END OF THE PROGRAM."
9999 END
KEY