100 REM
110 REM	PROGRAM WRITTEN BY P. M. DONINI
120 REM	GOODYEAR ATOMIC CORP.
130 REM	PIKETON, OHIO
140 REM
150 REM	SUBMITTED TO DECUS	30-JUL-73
160 REM
170 DIM A(3),B(3),N(3)
180 RANDOMIZE
190 PRINT "THIS IS A COMPUTERIZED CHUCK-A-LUCK GAME UP TO"
200 PRINT "THREE PEOPLE CAN PLAY AT A TIME."
210 PRINT "WOULD YOU LIKE THE RULES OF THIS GAME: YES OR NO";
220 INPUT R$
230 IF R$ = "YES" THEN 250
240 GOTO 390
250 PRINT: PRINT " ... RULES"
260 PRINT "A BET IS MADE ON A NUMBER AND 3 DICE ARE TOSSED"
270 PRINT "IF YOUR NO. APPEARS ONCE YOU RECEIVE YOUR BET."
280 PRINT "IF YOUR NO. APPEARS TWICE YOU DOUBLE YOUR BET."
290 PRINT "IF YOUR NO. APPEARS THREE TIMES YOU TRIPLE YOUR BET."
300 PRINT "IF YOUR NO. DOES NOT APPEAR YOU LOSE YOUR BET."
310 PRINT "YOU WILL BE GIVEN $50 TO START WITH. YOU CAN BET"
320 PRINT "ANY DOLLAR AMOUNT AS LONG AS YOU HAVE THAT AMOUNT"
330 PRINT "IN YOUR BANKROLL."
340 PRINT "IF YOU WISH TO QUIT MAKE A BET OF 0 AND THE ROUND"
350 PRINT "WILL END........"
360 PRINT "UP TO 3 PEOPLE CAN PLAY AT ONE TIME."
370 PRINT : PRINT
380 PRINT "READY TO START ... ","CHUCK-A-LUCK"
390 PRINT ,,"------------"
400 PRINT
410 INPUT "NUMBER OF PLAYERS";X
420 IF X>3 THEN 360
430 A(1)=50 : A(2)=50 : A(3)=50
440 FOR I1 = 1 TO X
450 INPUT "AMOUNT OF BET, YOUR NUMBER";B(I1),N(I1)
460 IF N(I1)>6 OR N(I1)<1 THEN 480
470 GOTO 500
480 PRINT "NUMBER MUST BE BETWEEN 1 AND 6 --- ";
490 INPUT N(I1) :GOTO 460
500 NEXT I1
510 FOR I2 = 1 TO X
520 IF B(I2)=0 THEN 950
530 NEXT I2
540 FOR I3 = 1 TO X
550 IF B(I3)>A(I3) THEN 580
560 NEXT I3
570 GOTO 630
580 PRINT "DON'T TRY TO BET MORE THAN YOU HAVE, PLEASE!!!"
590 FOR I4 =1 TO X
600 PRINT "PLAYER #";I4,"HAS $";A(I4)
610 NEXT I4
620 GOTO 440
630 D1 = INT(6*RND(1)+1)
640 D2 = INT(6*RND(2)+1)
650 D3 = INT(6*RND(3)+1)
660 FOR M1 = 1 TO X
670 IF D1=N(M1) THEN A(M1)=A(M1)+B(M1)
680 IF D2=N(M1) THEN A(M1)=A(M1)+B(M1)
690 IF D3=N(M1) THEN A(M1)=A(M1)+B(M1)
700 IF N(M1)=D1 OR N(M1)=D2 OR N(M1)=D3 THEN 720
710 A(M1)=A(M1)-B(M1)
720 NEXT M1
730 PRINT,, "...I ROLLED..."; D1 ;".*." ;D2 ;".*."; D3
740 FOR M2 = 1 TO X
750 PRINT "PLAYER #"; M2; " HAS A TOTAL OF $"; A(M2)
760 NEXT M2
770 FOR M3 = 1 TO X
780 IF A(M3)>500 THEN 850
790 NEXT M3
800 FOR M4 = 1 TO X
810 IF A(M4)=0 THEN 890
820 NEXT M4
830 PRINT : PRINT
840 GOTO 440
850 PRINT "CONGRATULATIONS TO PLAYER #"; M3; "YOU HAVE JUST ";
860 PRINT "BROKEN THE BANK."
870 PRINT "THANKS FOR THE GAME ..."
880 GOTO 900
890 PRINT "SORRY BUT PLAYER #"; M4; "IS BUSTED."
900 GOTO 960
910 PRINT "SHALL WE ALL START OVER AGAIN?"
920 INPUT "YES OR NO"; S$
930 IF S$ = "YES" THEN 390
940 GOTO 1010
950 PRINT "CONGRATULATIONS FOR QUITTING WHILE YOU ARE AHEAD."
960 FOR I5 = 1 TO X
970 PRINT "PLAYER #"; I5; " ENDS UP WITH ...$"; A(I5)
980 NEXT I5
990 PRINT : PRINT
1000 GOTO 910
1010 PRINT,"THANK YOU FOR THE GAMES..."
1020 END