100 REM
110 REM	PROGRAM WRITTEN BY   P. M. DONINI
120 REM	GOODYEAR ATOMIC CORP.
130 REM	PIKETON, OHIO
140 REM	
150 REM	SUBMITTED TO DECUS	30-JUL-73
160 REM
170 DEF FNM(Y,D) = Y-D*INT(Y/D)
180 PRINT "THE METHOD I AM GOING TO USE WAS DEVELOPED BY THE "
190 PRINT "CHINESE AND FIRST PUBLISHED IN THE FIRST CENTURY A.D.,"
200 PRINT "IN A BOOK ENTITLED SUAN-CHING (WHICH MEANS ARITHMETIC)."
210 PRINT : PRINT : PRINT
220 Z=1
230 READ I1,I2,I3
240 LET N= I1 * I2 * I3
250 LET J = I2
260 PRINT "*** PLAYER ***"
270 PRINT : PRINT
280 PRINT "I WANT YOU TO THINK OF A NUMBER LESS THAN OR EQUAL TO "
290 PRINT N;". WRITE THIS NUMBER DOWN AND DIVIDE BY ";I1;"."
300 PRINT "NOW GIVE ME THE REMAINDER LEFT OVER, THEN HIT <RETURN>";
310 INPUT K
320 PRINT "NOW DIVIDE YOUR ORIGINAL NUMBER BY ";J;" AND GIVE ME"
330 PRINT "THIS REMAINDE.";
340 IF J>= I3 THEN 370
350 INPUT L
360 J=I3 : GO TO 320
370 INPUT M
380 K1 = (((I1-3)/I1)*N)*K
390 L1 = (((I2-2)/I2)*N)*L
400 M1 = (((I3-1)/I3)*N)*M
410 X= K1+ L1 +M1
420 X1% = FNM(X,N)
430 PRINT "NOW I AM HAPPY TO TELL YOU THAT THE NUMBER YOU HAVE"
440 PRINT "CHOSEN WAS ... ";X1%
450 PRINT
460 PRINT "WOULD YOU LIKE TO TRY AGAIN (1=YES, 0=NO)";
470 INPUT A
480 IF A=1 THEN 510
490 PRINT " THANK YOU AND GOOD BYE"
500 GO TO 580
510 Z=Z+1
520 IF Z>5 THEN GO TO 540
530 GO TO 230
540 Z=1
550 RESTORE
560 GO TO 230
570 DATA 5,7,9,4,8,9,5,6,8,6,8,9,4,7,8
580 END