1  ! PROGRAM CORR, VERSION 1A (31-AUG-73)
   ! 
2  ! PROGRAM CORR COMPUTES THE MATRIX OF PRODUCT-MOMENT CORRELATIONS.
   ! IT IS ONE OF THE SEVERAL PROGRAMS AND FILES WHICH COMPOSE COSAP,
   ! LAWRENCE UNIVERSITY'S CONVERSATIONALLY ORIENTED STATISTICAL
3  ! ANALYSIS PACKAGE.  COSAP IS DISTRIBUTED FOR EDUCATION USE, ON
   ! THE CONDITION THAT IT NOT BE SOLD, RENTED OR LEASED FOR PROFIT.
   !
4  ! IF YOU DESIRE FURTHER INFORMATION ABOUT COSAP, PLEASE CONTACT THE
   ! LAWRENCE UNIVERSITY COMPUTER CENTER, APPLETON, WISCONSIN, 54911.
   !
10 DIM N%(30)  ! FUNCTION TO CREATE FILE EXT. BASED ON JOB#
25 DEF FNZ$ : IF N%(0)=30% THEN 40 
    ELSE CHANGE SYS(CHR$(6)+CHR$(9)+CHR$(0)) TO N% : 
   Z8$=".J"+RIGHT(NUM$(N%(1)/2%),2%)
40 FNZ$=Z8$! EXTENSION IS".J"+JOB #
55 FNEND
100 OPEN "DAT1"+FNZ$ AS FILE 1
110 OPEN L1$(1%) AS FILE 2
112 OPEN "DAT2"+FNZ$ AS FILE 3
115 DIM#1,X(200,50),H$(30)=2,C(50,50),M4(0),M5(0),M9(0),N(0),J9(0),
    I4(0),I7(0),N6(0),X2(50),L1$(8)=32%
120 DIM#2,N$(50%)=8
130 DIM #3,S(50),R(50,50)
145 DEF FNR(Q):INPUT Z$:Q=INSTR(1,Z$,"SOS"):IF Q>0 THEN 190 
160 Q=VAL(Z$):GOTO 205 
175 GOTO 205 
190 Q=808
205 FNR=Q:FNEND
220 !
235 FOR I=1 TO M9(0):S(I)=SQR(C(I,I)):NEXT I
265 PRINT:PRINT"THE MATRIX OF PRODUCT-MOMENT CORRELATION COEFFICIENTS"
    " IS:":PRINT
270 PRINT TAB(9);
275 PRINT USING "  \    \" N$(I);FOR I=1 TO M9(0)
280 FOR I=1 TO M9(0):FOR J=1 TO M9(0):R5=S(I)*S(J)
295 IF R5>0 THEN 325 
310 R(I,J)=0:GOTO 340 
325 R(I,J)=C(I,J)/R5
340 R(J,I)=R(I,J):NEXT J
370 PRINT:PRINT N$(I);SPACE$(9%-LEN(N$(I)));
385 PRINT USING "###.####" R(I,K);FOR K=1 TO M9(0)
400 PRINT:NEXT I
415 K$=SYS(CHR$(7)) : N$=LEFT(K$,8) : S0=VAL(RIGHT(K$,9)) :
    CLOSE 1,2,3 : KILL "DAT2"+FNZ$ : CHAIN N$S0
430 END