1  ! PROGRAM CSPDEM, VERSION 1A (31-AUG-73)
   !
2  ! PROGRAM CSPDEM IS A SAMPLE PROGRAM TO SHOW HOW TO CREATE A FILE
   ! WHICH CAN BE CONVERTED TO A COSAP DATABANK BY RUNNING THE PROGRAM
   ! CSPCVT.
3  ! PROGRAM CSPDEM IS A SUPPLEMENTAL PROGRAM FOR THE COSAP PACKAGE;
   ! IT IS DISCUSSED (ALONG WITH THE PROGRAM CSPCVT) IN SECTION 3
   ! OF THE USER'S GUIDE TO COSAP
4  ! COSAP ITSELF IS LAWRENCE UNIVERSITY'S CONVERSATIONALY ORIENTED
   ! STATISTICAL ANALYSIS PACKAGE.  COSAP AND ITS SUPPLEMENTAL PROGRAMS
   ! ARE DISTRIBUTED FOR EDUCATIONAL USE, ON THE CONDITION THAT THEY
5  ! NOT BE SOLD, RENTED OR LEASED FOR PROFIT.  
   !
   ! IF YOU DESIRE FURTHER INFORMATION ABOUT COSAP, PLEASE CONTACT THE
6  ! LAWRENCE UNIVERSITY COMPUTER CENTER, APPLETON, WISCONSIN, 54911
   !
10 ! THIS PROGRAM GENERATES RANDOM NUMBERS TO PRODUCE 20 OBSERVATIONS
   ! EACH FOR 5 VARIABLES, STORING THEM IN A VIRTUAL CORE FILE FOR
   ! FURTHER PROCESSING BY PROGRAM CSPCVT.
15 OPEN "MYDAT.TST" FOR OUTPUT AS FILE 1%
     ! CREATE NEW FILE CALLED "MYDAT.TST"
20 DIM #1, N$(50%)=8%,N%(50%),X(200%,50%)
     ! THIS IS THE REQUIRED FORMAT FOR THE DIMENSION STATEMENT, 
     ! WHERE
21   ! 1 IS THE DESIRED VIRTUAL CORE FILE NUMBER (BETWEEN 1 AND 12)
     ! N$ IS THE VECTOR OF VARIABLE NAMES (MAXIMUM OF 50)
          (NO VARIABLE NAME MAY BE LONGER THAN 8 CHARACTERS.)
22   ! N%(0%) IS THE NUMBER OF VARIABLES IN THE FILE (MAXIMUM OF 50)
     ! N%(I%) IS THE NUMBER OF OBSERVATIONS (VALUES) OF VARIABLE I,
          FOR I%=1,2,...,N%(0%)
23   !     (NOTE THAT, FOR V.1A OF COSAP, THE IDENTITY 
            N%(1%)=N%(2%)=...=N%(N%(0%))
            MUST HOLD.)
24   ! X IS THE MATRIX OF DATA, ARRANGED BY ROW:
           X(R,C), WHERE R=1,2,...,N%(I%)
                   AND   C=1,2,...,N%(0%)
25   ! REMEMBER THAT THE MAXIMUM NUMBER OF VALUES PER VARIABLE IS 200
       (THAT IS, N%(I%)<=200 FOR ALL I).
28 RANDOMIZE
     ! GENERATE RANDOM NUMBERS
30 N%(0%)=5%
      ! THERE WILL BE FIVE VARIABLES IN THIS FILE
40 FOR I%=1% TO 5%
      ! FIVE VARIABLES WILL NOW BE GIVEN VALUES
50 READ N$(I%)
      ! READ THE VARIABLE NAMES, ONE BY ONE
60 N%(I%)=20%
      ! THERE WILL BE 20 OBSERVATIONS (VALUES) OF EACH OF THE 5
      ! VARIABLES
70 FOR J%=1% TO 20% : X(J%,I%)=RND : NEXT J%
      ! THE DATA CONSISTS OF RANDOM NUMBERS FROM THE RND FUNCTION
80 NEXT I%
      ! AND THAT'S ALL THERE IS TO IT!!!
90 CLOSE 1%
      ! CLOSE THE FILE
95 DATA FIRST,SECOND,THIRD,FOURTH,FIFTH
96     ! HERE ARE THE FIVE VARIABLE NAMES (JUST AS EXAMPLES);
       ! AS REQUIRED BY COSAP, NO NAME HAS MORE THAN 8 CHARACTERS
100 END