1  ! PROGRAM DFQSD1, VERSION 1A (31-AUG-73)
   !
2  ! PROGRAM DFQSD1 IS ONE OF THE PROGRAMS FOR DISCRIMINANT ANALYSIS.
   ! IT IS ONE OF THE SEVERAL PROGRAMS AND FILES WHICH COMPOSE COSAP,
   ! LAWRENCE UNIVERSITY'S CONVERSATIONALLY ORIENTED STATISTICAL
3  ! ANALYSIS PACKAGE.  COSAP IS DISTRIBUTED FOR EDUCATIONAL USE, ON
   ! THE CONDITION THAT IT NOT BE SOLD, RENTED OR LEASED FOR PROFIT.
   !
4  ! IF YOU DESIRE FURTHER INFORMATION ON COSAP, PLEASE CONTACT THE
   ! LAWRENCE UNIVERSITY COMPUTER CENTER, APPLETON, WISCONSIN, 54911
   !
10 DIM N%(30)  ! FUNCTION TO CREATE FILE EXT. BASED ON JOB#
25 DEF FNZ$ : IF N%(0)=30% THEN 40 
    ELSE CHANGE SYS(CHR$(6)+CHR$(9)+CHR$(0)) TO N% : 
   Z8$=".J"+RIGHT(NUM$(N%(1)/2%),2%)
40 FNZ$=Z8$! EXTENSION IS".J"+JOB #
55 FNEND
85 OPEN "DAT1"+FNZ$ AS FILE 1
100 OPEN "DISC2"+FNZ$ AS FILE 2
115 OPEN "DISC1"+FNZ$ AS FILE 3
130 DIM#1,X(200,50),H$(30)=2,C(50,50),M4(0),M5(0),M9(0),N(0),J9(0),
          I4(0),I7(0),N6(0),X2(50),L1$(8)=32%
145 DIM#2,N2(50),M2(50),T9(0),L6(0),G9(0)
160 DIM#3,R(50,50),X3(50,50),F9(50),S(50)
175 G9=G9(0): L6=L6(0)
190 PRINT:PRINT"DO YOU WISH TO EVALUATE THE DISCRIMINANT FUNCTION FOR EACH VARIABLE";
205 INPUT N$: IFN$="YES" THEN 265 
220 IF N$<>"SOS" THEN 490 
235 PRINT:PRINT"ANSWER YES IF YOU WISH TO COMPUTE THE LARGEST FUNCTION 
250 GOTO 190 
265 PRINT
280 PRINT "CASE     LARGEST    ASSOCIATED     LARGEST"
295 PRINT" NO.     FUNCTION   PROBABILITY   FUNCTION NO."
310 K=0
325 FOR I=1 TO G9:PRINT:PRINT"GROUP "I:H=N2(I):FOR J=1 TO H
340 K=K+1:FOR K1=1 TO G9:F9(K1)=S(K1):FOR K2=1 TO L6:K8=M2(K2)
355 F9(K1)=F9(K1)+X3(K1,K2)*X(K,K8):NEXT K2:NEXT K1:L=1:S2=F9(1)
370 FOR K1=2 TO G9
385 IF S2>=F9(K1) THEN 415 
400 L=K1 : S2=F9(K1)
415 NEXT K1
420 P=0
430 FOR K1=1 TO G9:P=EXP(F9(K1)-S2)+P:NEXT K1:P=1/P
445 F3$="###    #####.####  #####.#####         ###"
460 PRINT USING F3$,J,S2,P,L
475 NEXT J:NEXT I:K$=SYS(CHR$(7))
490 N$=LEFT(K$,8) : S0=VAL(RIGHT(K$,9)):CLOSE 1,2 : KILL"DISC1"+FNZ$
505 CHAIN N$ S0
520 END