1  ! PROGRAM ESTA, VERSION 1A (31-AUG-73)
   !
2  ! PROGRAM ESTA COMPUTES ELEMENTARY STATISTICS FOR A DATABANK.
   ! IT IS ONE OF THE SEVERAL PROGRAMS AND FILES WHICH COMPOSE COSAP,
   ! LAWRENCE UNIVERSITY'S CONVERSATIONALLY ORIENTED STATISTICAL 
3  ! ANALYSIS PACKAGE.  COSAP IS DISTRIBUTED FOR EDUCATIONAL USE, ON
   ! THE CONDITION THAT IT NOT BE SOLD, RENTED OR LEASED FOR PROFIT.
   !
4  ! IF YOU DESIRE FURTHER INFORMATION ABOUT COSAP, PLEASE CONTACT THE
   ! LAWRENCE UNIVERSITY COMPUTER CENTER, APPLETON, WISCONSIN, 54911.
   !
10 DIM N%(30)  ! FUNCTION TO CREATE FILE EXT. BASED ON JOB#
25 DEF FNZ$ : IF N%(0)=30% THEN 40 
    ELSE CHANGE SYS(CHR$(6)+CHR$(9)+CHR$(0)) TO N% : 
   Z8$=".J"+RIGHT(NUM$(N%(1)/2%),2%)
40 FNZ$=Z8$! EXTENSION IS".J"+JOB #
55 FNEND
130 OPEN "DAT1"+FNZ$ AS FILE 1
145 OPEN L1$(1%) FOR INPUT AS FILE 5%
160 DIM#1,X(200,50),H$(30)=2,C(50,50),M4(0),M5(0),M9(0),N(0),
          J9(0),I4(0),I7(0),N6(0),X2(50),L1$(8)=32%
175 DIM #5%, N$(50%)=8%,M1$(50%)=64%,O%(50%),P%(50%),D$(50%)=8%,
        T(50%),D(10000%)
190 F$="#####.### #####.### #####.###   #####.##  #####.##   #####.##"
205 PRINT:PRINT"THIS PROGRAM COMPUTES ELEMENTARY STATISTICS.":PRINT
220 PRINT"VARIABLE    MEAN    STD. DEV   STD.ERROR   MAXIMUM   MINIMUM   RANGE"
235 F9=SQR(N(0)):FOR J=1 TO M9(0)
250 !TEST IF ANY VARIABLE IS NEG OR ZERO
265 IF  C(J,J)>0 THEN 295 
280 V6,S5=0:GOTO 310 
295 V6=SQR(C(J,J)/(N(0)-1)):S5=V6/F9
310 L6=X(1,J):G2=L6:FOR I=1 TO N(0)
325 IF X(I,J)>=L6 THEN 355 
340 L6=X(I,J)
355 IF G2>=X(I,J) THEN 385 
370 G2=X(I,J)
385 NEXT I
400 R1=G2-L6
415 PRINT N$(J);SPACE$(9%-LEN(N$(J))); :
      PRINT USING F$,X2(J),V6,S5,G2,L6,R1
430 NEXT J
445 K$=SYS(CHR$(7)):N$=LEFT(K$,8):S0=VAL(RIGHT(K$,9)):CLOSE 1
460 CLOSE 5% :  CHAIN N$ S0
475 END