1  ! PROGRAM FQPC, VERSION 1A (31-AUG-73)
   !
2  ! PROGRAM FQPC IS A PROGRAM IN THE POLYNOMIAL REGRESSION CHAIN.
   ! IT IS ONE OF THE SEVERAL PROGRAMS AND FILES WHICH COMPOSE COSAP,
   ! LAWRENCE UNIVERSITY'S CONVERSATIONALLY ORIENTED STATISTICAL 
3  ! ANALYSIS PACKAGE.  COSAP IS DISTRIBUTED FOR EDUCATIONAL USE, ON
   ! THE CONDITION THAT IT NOT BE SOLD, RENTED OR LEASED FOR PROFIT.
   !
4  ! IF YOU DESIRE FURTHER INFORMATION ABOUT COSAP, PLEASE CONTACT THE
   ! LAWRENCE UNIVERSITY COMPUTER CENTER, APPLETON, WISCONSIN, 54911.
   !
10 DIM N%(30)  ! FUNCTION TO CREATE FILE EXT. BASED ON JOB#
25 DEF FNZ$ : IF N%(0)=30% THEN 40 
    ELSE CHANGE SYS(CHR$(6)+CHR$(9)+CHR$(0)) TO N% : 
   Z8$=".J"+RIGHT(NUM$(N%(1)/2%),2%)
40 FNZ$=Z8$! EXTENSION IS".J"+JOB #
55 FNEND
70 !****FQPC
85 OPEN "DAT1"+FNZ$ AS FILE 1
100 OPEN "STEP1"+FNZ$ AS FILE 2
115 DIM#1,X(200,50),H$(30)=2,C(50,50),M4(0),M5(0),M9(0),N(0),J9(0),
          I4(0),I7(0),N6(0),X2(50),L1$(8)=32%
130 DIM#2,B(50),O2(0),S2(0),Z2(50,50),M2(200),M(0),L2(200),B3(200),
         N2(0)
145 M=M(0):N1=M2(1):N2=N2(0)
160 FOR I=1 TO M+2:X3(I)=B3(I):NEXT I
175 M2=M+1:K2=N(0)-1:FOR I=1 TO M2:D(I)=Z2(I,M2):NEXT I:S=0
190 FOR I=1 TO M
205 PRINT:PRINT"POLYNOMIAL REGRESSION OF DEGREE"I
220 I2=I+1
235 FOR J=I2 TO M2:B2(I,J)=Z2(I,J)/Z2(I,I):NEXT J:E(I)=B2(I,M2)
250 IF I<=1 THEN 340 
265 L2=I:FOR J=2 TO I
280 L1=I:L2=L2-1:E(L2)=B2(L2,M2)
295 FOR L=2 TO J
310 E(L2)=E(L2)-B2(L2,L1)*E(L1)
325 L1=L1-1:NEXT  L:NEXT J
340 FOR J=I2 TO M2:FOR L=1 TO I
355 Z2(I2,J)=Z2(I2,J)-B2(L,I2)*Z2(L,J):NEXT L:NEXT J
370 E1=X3(M2):FOR J=1 TO I:E1=E1-E(J)*X3(J):NEXT J:S5=0
400 FOR J=1 TO I:S5=S5+D(J)*E(J):NEXT J
415 IF S5<=0 THEN 460 
430 IF D(M2)<S5 THEN 460 
445 IF S5>S THEN 490 
460 PRINT:PRINT"NO REDUCTION OF SQUARES FROM THE PREVIOUS DEGREE"
475 GOTO 760 
490 PRINT:PRINT"INTERCEPT.........."E1
505 PRINT:PRINT"REGRESSION COEFFICIENTS"
520 FOR J= 1 TO I
535 PRINT TAB(3);J;TAB(15);E(J)
550 NEXT J
565 S7=S5/I:K=K2-I:LET S4=D(M2)-S5:S6=S4/K:LET S2=SQR(S6)
580 PRINT:PRINT"STANDARD ERROR OF ESTIMATE....."S2
595 PRINT
610 PRINT "        ANALYSIS OF VARIANCE FOR POLYNOMIAL OF DEGREE"I
625 F=S7/S6
640 PRINT"SOURCE OF VARIATION   D.F.    SUM OF SQ.    MEAN SQ.    F VALUE"
655 F1$="####  #######.###   #######.### #######.###"
670 PRINT"FROM REGRESSION       ";:PRINTUSINGF1$,I,S5,S7,F
685 PRINT"DEV. FROM REGRESSION  ";:PRINTUSINGF1$,K,S4,S6
700 PRINT"         TOTALS--     ";:PRINTUSINGF1$,I+K,D(M2)
715 F=S5-S:S=S5
730 PRINT:PRINT"REDUCTION OF SUM OF SQUARES OVER PREVIOUS DEGREE"F
745 FOR J=1 TO I:B(J)=E(J):NEXT J:O2=E1:L9=I:NEXT I
760 M=L9
775 O2(0)=O2:S2(0)=S2:M(0)=M
790 I4(0)=4:CLOSE 1,2:CHAIN"RESI"
805 END