1  ! PROGRAM MRCAP3, VERSION 1A (31-AUG-73)
   !
2  ! PROGRAM MRCAP3 IS PART OF THE MULTIPLE REGRESSION ANALYSIS.
   ! IT IS ONE OF THE SEVERAL PROGRAMS AND FILES WHICH COMPOSE COSAP,
   ! LAWRENCE UNIVERSITY'S CONVERSATIONALLY ORIENTED STATISTICAL
3  ! ANALYSIS PACKAGE.  COSAP IS DISTRIBUTED FOR EDUCATIONAL USE, ON
   ! THE CONDITION THAT IT NOT BE SOLD, RENTED OR LEASED FOR PROFIT.
   !
4  ! IF YOU DESIRE FURTHER INFORMATION ABOUT COSAP, PLEASE CONTACT THE
   ! LAWRENCE UNIVERSITY COMPUTER CENTER, APPLETON, WISCONSIN, 54911
   !
10 DIM Q1%(30%) ! FUNCTION TO CREATE FILE EXT. BASED ON JOB #
20 DEF FNZ$ : IF Q1%(0%)=30% THEN 30 ELSE
     CHANGE SYS(CHR$(6%)+CHR$(9%)+CHR$(0%)) TO Q1% :
     Z8$=".J"+RIGHT(NUM$(Q1%(1%)/2%),2%)
30 FNZ$=Z8$ ! EXTENSION IS ".J" + JOB #
40 FNEND
100 OPEN "DAT1"+FNZ$ AS FILE 1% : OPEN L1$(1%) AS FILE 2% :
   OPEN "MRC"+FNZ$ AS FILE 3%
110 DIM#1%,X(200,50),H$(30)=2%,C(50,50),M4(0),M5(0),M9(0),N(0),J9(0),
           I4(0),I7(0),N6(0),X2(50),L1$(8)=32%
120 DIM #2%, N$(50%)=8%,M1$(50%)=64%,O%(50%),P%(50%),D$(50%)=8%,
        T(50%),D(10000%)
130 DIM#3%,I9%(24%),X9(71%),R9(800%),X8(1600%),A9(10%),C9(20%),
        C8(20%),H1%(8%)
140 	  N=C9(1)	: M=C9(2)
	: K=C9(4)	: N6%=C9(5)
	: T8%=C9(10)	: N2%=C9(14)
	: S5=C9(16)
150 IF N2%>N THEN 180 ELSE IF T8%<>0 THEN 170 
160 PRINT : PRINT "MULTIVARIATE ANALYSIS USING THE GENERAL LINEAR "
     "MODEL********************" : GOTO 250
170 PRINT : PRINT "GENERAL TIME SERIES ANALYSIS USING THE GENERAL "
     "LINEAR MODEL************" : GOTO 250
180 PRINT : PRINT "RECALCULATION OF LEAST SQUARES RESULTS AFTER "
     "PURGING FOR THE EFFECTS" : PRINT "OF FIRST ORDER AUTOCORRELATION"
     "******************************************"
190 FOR J2%=1 TO M : PRINT"PURGED SERIES OF "N$(H1%(I9%(8+J2%)))
200 FOR I=1 TO N : I8%=I+N*(J2%-1) 
210 I2%=I+1
220 PRINT N$(H1%(I9%(8+J2%)));" OBS. NO. ";I2%;"   ";X8(I8%) :  NEXT I
230 NEXT J2%
240 PRINT : PRINT : PRINT
250 IF T8%>0 THEN 300 ELSE IF N2%>N THEN 280 
260 PRINT"CALCULATIONS ON VARIABLES (OBSERVED SERIES)*****************"
	"************"
270 GOTO 320 
280 PRINT"CALCULATIONS ON VARIABLES (PURGED SERIES)*******************"
	"************"
290 GOTO 320 
300 PRINT"CALCULATIONS ON VARIABLES***********************************"
	"************"
320 PRINT"VARIABLE","ARITHMETIC MEAN","STANDARD DEVIATION"
330 FOR J2%=1 TO M : J=I9%(8+J2%) 
340 PRINT N$(H1%(J)),X9(J2%),,"    "X9(8+J2%) : NEXT J2%
350 PRINT
360 PRINT"MATRIX OF FIRST ORDER CORRELATION COEFFICIENTS"
370 J3%=1 : M9=M-1 : FOR J2%=1 TO M9 : J3%=J2%+J3% : J9%=J2%+1
	: J8%=0 : FOR L2%=1 TO J9% : L3%=L2%+1
	: IF L3%>J9% THEN 390 
380 L9%=J3%+J8%:PRINT"R(";:J=I9%(8+J9%):PRINT N$(H1%(J))",";:
    J=I9%(8+L2%):PRINT N$(H1%(J))")    "R9(L9%):J8%=J8%+1%:NEXT L2%
390 NEXT J2%
400 PRINT : PRINT
410 PRINT"REGRESSION ANALYSIS******************************************"
	"***********"
420 PRINT "DEPENDENT VARIABLE IS " N$(H1%(I9%(16+K+1)))
440 PRINT,,"STANDARD ERROR"
450 PRINT "VARIABLE","COEFFICIENT","OF COEFFICIENT  STUDENT'S T","
	"   D.F."
460 S9=A9(1)/S5
	: N9%=A9(8)+.05
	: PRINT "INTERCEPT",A9(1)," "S5," "S9,"  "N9%
470 FOR J=1 TO K
	: PRINT N$(H1%(I9%(16+J))),X9(16+J),X9(24+J),X9(32+J),"  "N9%
	: NEXT J
475 D9=N-M : D9=(N-1)/D9 : A4=SQR(1-(1-A9(2)*A9(2))*D9)
480 PRINT : PRINT"MULTIPLE CORRELATION COEFFICIENT (R) IS"A9(2);
     : PRINT " (ADJUSTED R=";A4;")"
485 A4=A9(3)*SQR(D9)
490 Q9=A9(2)*A9(2)
	: PRINT"COEFFICIENT OF DETERMINATION (R^2) IS "Q9
	: PRINT
	: PRINT"STANDARD ERROR OF ESTIMATE IS "A9(3);
     : PRINT " (ADJUSTED S.E. OF E.=";A4;")"
500 PRINT : PRINT
510 PRINT "ANALYSIS OF VARIANCE****************************************"
	"************"
530 PRINT : PRINT "SOURCE OF VARIATION   SUM OF SQUARES","D.F.",
	"MEAN SQUARE"
540 D7%=A9(5)+.05
	: PRINT"    REGRESSION",A9(4),D7%,A9(6)
	: PRINT"    RESIDUAL",,A9(7),N9%,A9(9)
550 PRINT
560 S8=A9(4)+A9(7)
	: N9%=A9(5)+A9(8)+.05
	: PRINT"    TOTAL",,S8,N9%
	: PRINT
570 PRINT "F RATIO IS"A9(10)
	: PRINT
	: PRINT
580 PRINT"VARIANCE-COVARIANCE MATRIX OF THE REGRESSION COEFFICIENTS***"
    "************":PRINT" (UPPER RIGHT HAND TRIANGLE ONLY)":PRINT:
    FOR M7%=1 TO M : FOR M6%=1 TO M7%
590 M5%=M6%+M*(M7%-1):IF N6%=M7% THEN 595 ELSE J=I9%(8+M7%):
    M4$=N$(H1%(J)): GOTO 600
595 M4$="INTERCEPT"
600 IF N6%=M6% THEN 605 ELSE J=I9%(8+M6%):
    M3$=N$(H1%(J)): GOTO 610
605 M3$="INTERCEPT"
610 IF M3$=M4$ THEN PRINT "VAR B("M4$")",,R9(200+M5%)
    ELSE PRINT "COV B("M4$") B("M3$")",R9(200%+M5%)
620 		NEXT M6%
	: NEXT M7%
630 PRINT : PRINT
640 !END OF MRTOS
650 	C9(1)=N	:	C9(2)=M
	: C9(4)=K	:C9(5)=N6%
	: C9(10)=T8%	:C9(14)=N2%
	: C9(16)=S5
660 CLOSE 1%,2%,3% : CHAIN "MRCAP4"
32767 END