2 ! PRINTS 941'S
5 ! PROGRAM NAME:"PRT941 - BY JAC
10 OPEN "DK1:PAYROL.MDR" AS FILE 1%:DIM #1%,M$(1500%)=128%,M%(0%),D$(0%)=8%
20 D$=D$(0%):F$=LEFT(D$,2%):F1$=RIGHT(D$,7%)
25 IF F$=" 3" THEN D1$=" 3-31-"+F1$:Q1%=1%:GOTO 45
30 IF F$=" 6" THEN D1$=" 6-30-"+F1$:Q1%=2%:GOTO 45
35 IF F$=" 9" THEN D1$=" 9-30-"+F1$:Q1%=3%:GOTO 45
40 IF F$="12" THEN D1$="12-31-"+F1$:Q1%=4%
45 CLOSE 1%:OPEN "DK1:PAYROL.MST" AS FILE 1%:DIM #1%,A$(1500%)=128%,A%(0%)
60 OPEN "DK1:PAYROL.QRT" AS FILE 2%:DIM #2%,Q$(1500%)=64%,Q%(0%)
70 OPEN "LP:" FOR OUTPUT AS FILE 3%,MODE 66%:C=1260000:N%=A%(0%):X%=10%
75 R$="##,###.##":C$="1":D$="001":GOSUB 200:GOSUB 200:GOSUB 450
90 D$="002":C$="2":GOSUB 200:GOSUB 200:GOSUB 450
100 D$="001 - FICA EXEMPT":C$="3":GOSUB 200:GOSUB 200:CLOSE 1%,2%,3%:STOP
200 J%=1%:L%=0%:GOSUB 400:FOR K%=1% TO N%
225 T=T+VAL(MID(Q$(K%),(I%-1%)*8%+2%,7%)) FOR I%=1% TO Q1%*2%
235 IF T=0% OR (MID(Q$(K%),(I%-1%)*8%+1%,1%)<>C$ AND
	MID(Q$(K%),(I%-2%)*8%+1%,1%)<>C$) THEN 290
240 IF MID(Q$(K%),(I%-2%)*8%+1%,1%)=C$ THEN A=VAL(MID(Q$(K%),(I%-2%)*8%+2%,7%))
	ELSE A=VAL(MID(Q$(K%),(I%-1%)*8%+2%,7%))
245 IF A=0% OR C-T+A<0% THEN 290 ELSE IF C-T<0% THEN A=A+C-T
260 N$=LEFT(A$(K%),24%):S$=MID(A$(K%),26%,11%)
265 PRINT #3%,TAB(X%);S$;"      ";N$;"    ";
270 PRINT #3%,USING R$,A/100%:F=F+A:PRINT #3%
275 L%=L%+1%:IF L%<22% THEN 290 ELSE GOSUB 350
290 T=0%:NEXT K%:M%=L%
300 PRINT #3%:PRINT #3%:M%=M%+1%:IF M%<22% THEN 300 ELSE GOSUB 350
305 IF D$="001" OR D$="002" THEN D3$="TAXABLE   " ELSE D3$="NONTAXABLE"
310 PRINT #3%,TAB(X%-2%);"TOTAL EMPLOYEES ";L1%;TAB(21%+X%);"TOTAL FICA ";D3$;
315 PRINT #3%,USING " ##"+R$,F1/100%:F2=F1:L1%=0%:F1=0%:RETURN
350 F$=SPACE$(52%)+"#,#"+R$+"       ####":PRINT #3%:PRINT #3%,USING F$,F/100%,L%
365 F1=F1+F:F=0%:L1%=L1%+L%:L%=0%:J%=J%+1%:GOSUB 400:RETURN
400 PRINT #3%,CHR$(132%)
405 PRINT #3%,TAB(43%+X%);D1$;TAB(62%+X%);J%
410 PRINT #3%,TAB(X%);"69-0820293-";D$
415 PRINT #3%,TAB(X%);"SCHOOL DISTRICT NO. 91, CLERK"
420 PRINT #3%,TAB(X%);"690 JOHN ADAMS PARKWAY"
425 PRINT #3%,TAB(X%);"IDAHO FALLS, IDAHO  83401"
430 PRINT #3% FOR I%=1% TO 6%
435 RETURN
450 PRINT CHR$(12%)
455 PRINT "TOTAL FICA TAXABLE INCOME";TAB(40%);
460 PRINT USING "#,#"+R$,F2/100%
465 IF C$="1" THEN D2$="NONCERTIFIED" ELSE D2$="CERTIFIED"
470 PRINT "TOTAL FICA TAX FOR ";D2$;TAB(40%);:F3=F2*117%
475 PRINT USING "#,#"+R$,F3/100000:F3=F3/2%:PRINT "ONE-HALF FICA TAX";TAB(40%);
485 PRINT USING "#,#"+R$,F3/100000:RETURN
495 END