2 ! PRINTS PRE-LIST
5 ! PROGRAM NAME:"PRTLST" - BY JAC
10 OPEN "DK1:PAYROL.MST" AS FILE 1%
15 DIM #1%,A$(1500%)=128%,A%(0%)
20 OPEN "DK1:PAYROL.SCR" AS FILE 2%
25 DIM #2%,S$(1500%)=128%,S%(0%)
30 OPEN "LP:" FOR OUTPUT AS FILE 3%,MODE 66%
35 OPEN "DK1:PAYROL.MDR" AS FILE 4%:DIM #4%,M$(1500%)=128%,M%(0%),D1$(0%)=8%
36 INPUT "INPUT PAYROLL DATE AS: MM-DD-YY";D$:N%=INSTR(1%,D$,"-")
38 IF N%<2% OR N%>3% THEN 36 ELSE IF N%=2% THEN D$=" "+D$
40 N%=INSTR(4%,D$,"-"):IF N%<5% OR N%>6% THEN 36
42 IF N%=5% THEN D$=LEFT(D$,3%)+" "+RIGHT(D$,4%)
45 D1$(0%)=D$:M1%=VAL(LEFT(D$,2%)):M2%=VAL(RIGHT(D$,7%)):CLOSE 4%
50 J%=1%:L%=0%:Q$="##,###.##":N%=A%(0%):GOSUB 300
55 FOR K%=1% TO N%
60 IF MID(A$(K%),116%,1%)="D" THEN 140
65 IF MID(S$(K%),3%,1%)<>"Y" THEN 140
70 M%=VAL(MID(S$(K%),4%,1%)):N$=LEFT(A$(K%),24%)
75 E$=MID(A$(K%),37%,6%):P%=5%:T=0%
76 FOR I%=1% TO M%
77 D%=VAL(MID(S$(K%),P%,2%)):D1%=VAL(MID(S$(K%),P%+4%,2%)):IF M2%<D1% OR
	M1%<D% AND M2%=D1% THEN P%=P%+31%:GOTO 120
78 S=VAL(MID(S$(K%),P%+8%,7%)):N1%=VAL(MID(S$(K%),P%+6%,2%)):D%=D%+N1%-1%:A=0
79 IF D%>12% THEN D%=D%-12%
80 IF D%=M1% THEN A=S-FIX(S/N1%)*N1%
90 A=A+FIX(S/N1%):T=T+A
95 PRINT #3%,"   ";N$;" ";E$;"     ";:PRINT #3%,USING Q$,A/100%;:P%=P%+15%
100 C$=MID(S$(K%),P%,3)+"-"+MID(S$(K%),P%+3%,2)+"-"+MID(S$(K%),P%+5%,1)+"-"
105 C$=C$+MID(S$(K%),P%+6%,4)+"-"+MID(S$(K%),P%+10%,4)+"."
108 C$=C$+MID(S$(K%),P%+14%,2)
110 IF M%=1% THEN PRINT #3%,"*  ";C$ ELSE PRINT #3%,"   ";C$
115 P%=P%+16%:GOSUB 350
120 NEXT I%
125 F=F+T:IF M%=1% THEN 140
130 PRINT #3%,TAB(39%);:PRINT #3%,USING Q$,T/100%;
135 PRINT #3%,"*":GOSUB 350
140 NEXT K%
145 PRINT #3%:PRINT #3%,TAB(10%);"**FINAL TOTAL**";TAB(36%);
150 PRINT #3%,USING "#,#"+Q$+"\\",F/100%,"**"
155 PRINT #3%,CHR$(129%):CLOSE 1%,2%,3%:STOP
300 PRINT #3%,CHR$(129%)
305 PRINT #3%,"  SCHOOL DISTRICT NO. 91";TAB(32%);"PRE-LIST";
310 PRINT #3%,TAB(47%);D$;TAB(60%);"PAGE ";J%
315 PRINT #3%:PRINT #3%,TAB(10%);"EMPLOYEE";TAB(27%);"EMPLOYEE";
320 PRINT #3%,TAB(55%);"GENERAL LEDGER"
325 PRINT #3%,TAB(12%);"NAME";TAB(28%);"NUMBER";TAB(42%);"AMOUNT";
330 PRINT #3%,TAB(60%);"CODE":PRINT #3%
335 RETURN
350 L%=L%+1%:IF L%<52% THEN 360
355 J%=J%+1%:L%=0%:GOSUB 300
360 RETURN
365 END