2 ! PRINTS PAYROLL JOURNAL
5 ! PROGRAM NAME:"PRTPRJ" - BY JAC
10 OPEN "LP:" FOR OUTPUT AS FILE 1%,MODE 66%
15 OPEN "DK1:PAYROL.PRJ" AS FILE 2%:DIM #2%,J$(1500%)=64%,J%(0%)
25 OPEN "DK1:PAYROL.RCP" AS FILE 3%:DIM #3%,R$(1000%)=64%,R%(0%)
35 OPEN "DK1:PAYROL.FND" AS FILE 4%:DIM #4%,F$(20%)=32%,F%(0%)
45 OPEN "DK1:PAYROL.MDR" AS FILE 5%
50 DIM #5%,M$(1500%)=128%,M%(0%),D$(0%)=8%:D1$=D$(0%):CLOSE 5%
51 DEF FNZ$(S)
52 IF ABS(S)<1E+6 THEN FNZ$=LEFT(NUM$(S)+SPACE$(10%-LEN(NUM$(S))),10%):GOTO 58
53 A1=FIX(S/1E+6):A2=((S/1E+6)-A1)*1E+6:A3$=NUM$(A1):A4$=RIGHT(NUM$(A2),2%)
54 IF LEN(A4$)<7% THEN A4$="0"+A4$:GOTO 54
55 A3$=LEFT(A3$,INSTR(2%,A3$," ")-1%)+A4$
56 FNZ$=LEFT(A3$+SPACE$(10%-LEN(A3$)),10%)
58 FNEND
60 N%=J%(0%):J1%=1%:L%=0%:Q$="##,###.##":Q%=10%:I%=1%:GOSUB 400
65 K%=1%:Z%=0%:X%=0%:D2$=LEFT(D1$,2%)+MID(D1$,4%,2%):B1$=LEFT(F$(I%),2%)
70 IF K%>N% THEN 220
75 A$=MID(J$(K%),48%,2%):IF A$=B1$ THEN 100
85 IF Z%>=0% THEN 95
90 GOSUB 450                         ! NO-PRINT FUND TOTALS
95 I%=I%+1%:B1$=LEFT(F$(I%),2%):X%=-1%:GOTO 75
100 IF X%<0% THEN X%=0%:GOSUB 400
105 N$=LEFT(J$(K%),24%):E$=MID(J$(K%),25%,6%):A=VAL(MID(J$(K%),31%,8%))
110 D3$=MID(J$(K%),39%,2%)+"-"+MID(J$(K%),41%,2%)+"-"+MID(J$(K%),43%,2%):Z%=-1%
115 C$=MID(J$(K%),45%,3%)+"-"+MID(J$(K%),48%,2%)+"-"+MID(J$(K%),50%,1%)+"-"
120 C$=C$+MID(J$(K%),51%,4%)+"-"+MID(J$(K%),55%,4%)+"."+MID(J$(K%),59%,2%)
125 PRINT #1%,TAB(Q%);N$;TAB(30%+Q%);E$;TAB(55%+Q%);
130 PRINT #1%,USING Q$,ABS(A)/100%;
135 IF A<0% THEN PRINT #1%,"CR";
140 PRINT #1%,TAB(79%+Q%);D3$;"   ";C$
145 B=B+A:K%=K%+1%:IF K%>N% THEN 170
150 A$=MID(J$(K%-1%),45%,16%):B$=MID(J$(K%),45%,16%)
155 IF A$<>B$ THEN 170        ! MORE ENTRIES W&TH SAME CODE"
160 GOSUB 480:GOTO 105      ! YES-CHECK FOR END OF PAGE
170 PRINT #1%,TAB(30%+Q%);"BUDGET CODE TOTAL";TAB(54%+Q%);
175 PRINT #1%,USING "#"+Q$,ABS(B)/100%;
180 IF B<0% THEN PRINT #1%,"CR*" ELSE PRINT #1%,"  *"
185 F=F+B:R%(0%)=R%(0%)+1%:L%=L%+2%:PRINT #1%
190 Y$=MID(J$(K%-1%),62%,1%)
200 R$(R%(0%))=D2$+"P/R JOURNAL - EXPENSE "+MID(J$(K%-1%),45%,16%)+"          "
205 R$(R%(0%))=R$(R%(0%))+"3E"+FNZ$(B)
210 B=0%:GOSUB 480:GOTO 70
220 GOSUB 450:PRINT #1%
230 PRINT #1%,TAB(Q%);"TOTAL ENTRIES";N%;TAB(30%+Q%);"ACCUMULATIVE TOTAL";
235 PRINT #1%,TAB(52%+Q%);:PRINT #1%,USING "#,#"+Q$,ABS(F1)/100%;
240 IF F1<0% THEN PRINT #1%,"CR***" ELSE PRINT #1%,"  ***"
245 PRINT #1%,CHR$(128%+1%)
250 R%(0%)=R%(0%)+1%:R$(R%(0%))=D2$+"PAYROLL SUMMARY       0000100000208001"
255 R$(R%(0%))=R$(R%(0%))+SPACE$(10%)+"3E"+FNZ$(F2):CLOSE 1%,2%,3%,4%:STOP
400 PRINT #1%,CHR$(129%):L%=0%
405 PRINT #1%,TAB(Q%);RIGHT(F$(I%),3%);TAB(31%+Q%);"PAYROLL JOURNAL - EXPENSE";
410 PRINT #1%,TAB(69%+Q%);D1$;TAB(95%+Q%);"PAGE ";J1%:PRINT #1%
420 PRINT #1%,TAB(29%+Q%);"EMPLOYEE";TAB(81%+Q%);"DATE";TAB(97%+Q%);"BUDGET"
425 PRINT #1%,TAB(3%+Q%);"EMPLOYEE NAME";TAB(30%+Q%);"NUMBER";TAB(58%+Q%);
430 PRINT #1%,"AMOUNT";TAB(79%+Q%);"MO-DY-YR";TAB(108%);"CODE":PRINT #1%:RETURN
450 PRINT #1%,TAB(30%+Q%);"FUND TOTAL";TAB(52%+Q%);
460 PRINT #1%,USING "#,#"+Q$,ABS(F)/100%;
462 IF F<0% THEN PRINT #1%,"CR**" ELSE PRINT #1%,"  **"
465 Z%=0%:F1=F1+F:F1$=LEFT(F$(I%),2%):IF F1$="01" THEN 473
468 R%(0%)=R%(0%)+1%:F2=F2+F:F=-F:IF F=0% THEN 473
470 R$(R%(0%))=D2$+"PAYROLL SUMMARY       000"+F1$+"00000223500          3E"
472 R$(R%(0%))=R$(R%(0%))+FNZ$(F)
473 F=0%
478 RETURN
480 L%=L%+1%:IF L%<52% THEN 490
485 J1%=J1%+1%:GOSUB 400
490 RETURN
495 END