100	! ADVFRQ -- ADVISOR FREQUENCY TALLY
110	! CHANGE STANDARD CLI FILENAME AND SENIOR CLASS YR
	! IN DATA STATEMENT BEFORE RUNNING
120	! 03-DEC-73	J. WARDEN	WABASH COLLEGE
130 DIM C%(3%,100%)
140 READ F1$,Y0%
150 DATA "DK0:CLF73",74
180 PRINT"ADVISOR FREQUENCY COUNT"
200 ON ERROR GO TO 1500
220 R1$=CHR$(13) :R2$=CHR$(10)
240 F8$="     \"+SPACE$(35%)+"\          \            \"
260 F7$="     \"+SPACE$(50)+"\"
280 ! READ IN PROFESSOR CODES
300 DIM P4$(20),P$(100),T$(9)
	! READ IN PROFESSOR CODES:
340  INPUT"PROF FILE";P$ : IF P$="" THEN P$="DK1:PROF15"
350 OPEN P$ FOR INPUT AS FILE 2%
360 FIELD #2%,34%*P% AS Z$,34% AS P4$(P%) FOR P%=0% TO 14%
380 IF P%<14% THEN P%=P%+1% ELSE P%=0% : GET #2%
400 IF LEFT(P4$(P%),1%)="\" THEN 480
420 I%=VAL(MID(P4$(P%),8%,2%))
440 P$(I%)=MID(P4$(P%),11%,16%)
460 GO TO 380
480 CLOSE 2%
500 F9%=0% : F7%=0%       ! INITIALIZE FLAGS
510 PRINT"WANT STANDARD FILE ";F1$;" (Y/N)";:INPUT Y$ :
	IF ASCII(Y$)=89% THEN 540
520 INPUT"CLASS LIST FILE";F1$
540 OPEN F1$ FOR INPUT AS FILE 1% :
	FIELD #1%,127%*V% AS Z$, 127% AS V$(V%) FOR V%=0% TO 3%
550 INPUT"OUTPUT TO";O$
560 OPEN O$ FOR OUTPUT AS FILE 3%
600 IF V%<3% THEN V%=V%+1% ELSE V%=0% : GET #1%
620	IF LEFT(V$(V%),1%)="\" THEN 800
640 A%=VAL(MID(V$(V%),9%,2%))
660 Y$=MID(V$(V%),7%,2%)
680 IF ASCII(Y$)=55% THEN Y%=VAL(Y$)-Y0% ELSE
	S%=S%+1% : GO TO 600
700 IF Y%<0% OR Y%>3% THEN S%=S%+1% : GO TO 600
720 C%(Y%,A%)=C%(Y%,A%)+1%
740 GO TO 600
800	! OUTPUT PHASE
820 S$="    ADVISOR           SENIORS    JUNIORS    SOPHS     FROSH"
840 T$="    \            \    #####      #####     #####     #####"
850 GOSUB 870 : GO TO 920
860 PRINT #3%, CHR$(12%)
870 PRINT #3%,"    STUDENTS PER ADVISOR BY CLASS";
	SPACE$(17%)+DATE$(0%)
880 PRINT #3%,CHR$(10%)
900 PRINT #3%,S$+CHR$(10%)
910 RETURN
920	FOR I%=0% TO 99%
925	IF I%=51% THEN GOSUB 860
930	IF LEN(P$(I%))<3% THEN 960
940 	PRINT #3%,USING T$,P$(I%),
	C%(0%,I%),C%(1%,I%),C%(2%,I%),C%(3%,I%)
960	NEXT I%
980 PRINT #3%,CHR$(26%)
1000 CLOSE 1%,3%
9999 END