1	! CODER -- CODES SUBJECT FILE 1 -> N
	! DO NOT USE AFTER REGISTRATION HAS BEGUN!!
2	! 27-AUG-73	J. WARDEN	WABASH COLLEGE
10 PRINT"SUBJECT FILE CODE ASSIGNER"
20 PRINT"DO NOT USE AFTER REGISTRATION HAS BEGUN!"
70 DEF FNF$(X%)
72 X$=MID(NUM$(X%),2%,LEN(NUM$(X%))-2%)
74 FNF$=LEFT("000",3%-LEN(X$))+X$
76 FNEND
120 N5%=1%
140 GOSUB 4000
	! LOOK UP ATTRIBUTES
180 ON ERROR GO TO 300
200 INPUT"INPUT FILE (DEV:FILE)";F1$
220 INPUT"OUTPUT FILE (DEV:FILE)";F2$
240 OPEN F1$ FOR INPUT AS FILE 1%
250 FIELD #1%,N1%*R% AS Z$,N1% AS A$(R%) FOR R%=0% TO N6%
260 OPEN F2$ FOR OUTPUT AS FILE 2%
270 FIELD #2%,N1%*S% AS Z$,N1% AS B$(S%) FOR S%=0% TO N6%
280 S%=0%
290 GO TO 390
300 IF ERR<>5% THEN ON ERROR GO TO 0
340 PRINT CHR$(7%)+"** CAN'T FIND "+F1$+" **" : RESUME 360
360 INPUT"INPUT FILE (DEV:FILE)";F1$
	! TRY FOR INPUT FILE AGAIN
380 GO TO 240
390 ON ERROR GO TO 900
395 A%=0%
400 IF R%<N6% THEN R%=R%+1% ELSE R%=0% : GET #1%
420 IF LEFT(A$(R%),1%)="\" THEN 1000	! END-OF-FILE?
440	! - - - - - - - - - - - - - -
	! SELECT OR PRINT ROUTINE HERE
450 A%=A%+1%
480	! - - - - - - - - - - - - -
490 LSET B$(S%)=LEFT(A$(R%),7%)+FNF$(A%)+RIGHT(A$(R%),11%)
500 IF S%<N6% THEN S%=S%+1% ELSE S%=0% : PUT #2%,COUNT N3%
520 GO TO 400
900 IF ERR<>11% THEN ON ERROR GO TO 0
1000 FOR H%=S% TO N6%
1100 LSET B$(H%)="\\\\\\"+SPACE$(N2%)+CHR$(13%)+CHR$(10%)
1200 NEXT H%
1250 PUT #2%, COUNT N3%
1300 CLOSE 1%,2%
1400 GO TO 9999
4000 DIM V2$(50),V2%(2,50)
4020 ON ERROR GO TO 4320
4030 F$="SUB"
4040 OPEN V1$+"$ATRIB" FOR INPUT AS FILE 1%
4060 FIELD #1%, 255%*A% AS Z$, 255% AS A$(A%) FOR A%=0% TO 1%
4080 IF A%<1% THEN A%=A%+1% ELSE A%=0% : GET #1% : R%=R%+1%
4100	IF LEFT(A$(A%),3%)="\\\" THEN
	PRINT"NO SUCH FILE TYPE" : GO TO 9999
4120 IF LEFT(A$(A%),3%)<>F$ THEN 4080
4140 V2%(2%,0%),N%=VAL(MID(A$(A%),4%,2%)) :
	N9%=VAL(MID(A$(A%),6%,1%))*2%
4160 N1%=510%/N% : N2%=N1%-8% : N3%=N%*N1% : N6%=N%-1%
4180 FOR V%=1% TO 50%
4200 V2$(V%)=MID(A$(A%),42%+(V%-1%)*4%,2%) : IF V2$(V%)="  " THEN 4280
4220 V5%=CVT$%(MID(A$(A%),44%+(V%-1%)*4%,2%))
4240	V2%(1%,V%)=ASCII(CHR$(V5%)) :
	V2%(2%,V%)=ASCII(CHR$(SWAP%(V5%)))
4260 NEXT V%
4280 V2%(1%,0%)=V%-1% : IF N5% THEN 4300 ELSE
	PRINT"CODES: "; :
	PRINT V2$(I%)+" "; FOR I%=1% TO V%-1% : PRINT
4300 CLOSE 1% : ON ERROR GO TO 0 : RETURN
4320 IF ERR<>5% AND ERR<>21% THEN 4380 ELSE RESUME 4340
4340 READ V1$ : GO TO 4040
4360 DATA DK2:,DK1:,DK0:,DK3:
4380 PRINT"THE FILE '$ATRIB' HAS BEEN DELETED;" :
	PRINT"IT MUST BE REPLACED TO PROCEED."
9999 END