1	! CSBOUT -- PRINTS NAME & HOME CITY/STATE FOR CS
10 PRINT"NAME & HOME STATE: CSB"
50 P$=P$+"." FOR I=1 TO 60
100 DEF FNF$(X%)=MID(A$(A%),V2%(1%,X%),V2%(2%,X%))
120 INPUT"CLASS YEAR WANTED";C$
125 IF C$="" THEN C$="  "
140 N5%=1% : GOSUB 4000
180 ON ERROR GO TO 300
200 INPUT"INPUT FILE (DEV:FILE)";F1$
220 INPUT"OUTPUT FILE (DEV:FILE)";F2$
240 OPEN F1$ FOR INPUT AS FILE 1%
250 FIELD #1%,N1%*A% AS Z$,N1% AS A$(A%) FOR A%=0% TO N6%
260 OPEN F2$ FOR OUTPUT AS FILE 2%
280 B%=0%
290 GO TO 390
300 IF ERR<>5% THEN ON ERROR GO TO 0
340 PRINT CHR$(7%)+"** CAN'T FIND "+F1$+" **" : RESUME 360
360 INPUT"INPUT FILE (DEV:FILE)";F1$
	! TRY FOR INPUT FILE AGAIN
380 GO TO 240
390 ON ERROR GO TO 900
395 PRINT #2%,"CLASS OF ";C$
396 PRINT #2%,CHR$(10%)
400 IF A%<N6% THEN A%=A%+1% ELSE A%=0% : GET #1%
420	IF ASCII(A$(A%))=92% THEN 1000  ! END OF FILE?
430 IF C$<>FNF$(1%) THEN 400
435 N$=FNF$(5%) : Q%=INSTR(1%,N$,"  ") : IF Q%=0% THEN Q%=29%
440 N$=LEFT(N$,Q%) : Q%=LEN(N$)
442 IF Q%-2%*(Q%/2%) THEN N$=N$+" "
450 W$=FNF$(20%) : W%=INSTR(1%,W$,"  ") : IF W%=0% THEN W%=15%
452 W$=LEFT(W$,W%-1%) : W%=LEN(W$)
454 IF W%-2%*(W%/2%) THEN W$=" "+W$ ELSE W$="  "+W$
456 W$=W$+", "+LEFT(FNF$(21%),2%)
470 C%=60%-LEN(W$)-LEN(N$)
480 PRINT #2%,N$+LEFT(P$,C%)+W$
500 IF P%<55% THEN P%=P%+1% ELSE P%=0% : GOSUB 2000
520 GO TO 400
900 IF ERR<>11% THEN ON ERROR GO TO 0
1000	! WRITE DUMMY ID CODES ON FINAL RECORDS IN BLOCK
1300 CLOSE 1%,2%
1400 GO TO 9999
2000 PRINT #2%,CHR$(12%);
2010 PRINT #2%,"CLASS OF ";C$;" (CONTINUED)"
2020 PRINT #2%,CHR$(10%)
2030 RETURN
3900	! === FILE ATTRIBUTES LOOKUP SUBROUTINE ===
4000 DIM V2$(50),V2%(2,50)
4020 ON ERROR GO TO 4320
4030 F$="CSB"
4040 OPEN V1$+"$ATRIB" FOR INPUT AS FILE 1%
4060 FIELD #1%, 255%*A% AS Z$, 255% AS A$(A%) FOR A%=0% TO 1%
4080 IF A%<1% THEN A%=A%+1% ELSE A%=0% : GET #1%
4100	IF LEFT(A$(A%),3%)="\\\" THEN
	PRINT"NO SUCH FILE TYPE" : GO TO 9999
4120 IF LEFT(A$(A%),3%)<>F$ THEN 4080
4140 V2%(2%,0%),N%=VAL(MID(A$(A%),4%,2%)) :
	N9%=VAL(MID(A$(A%),6%,1%))*2%
4160 N1%=510%/N% : N2%=N1%-8% : N3%=N%*N1% : N6%=N%-1%
4180 FOR V%=1% TO 50%
4200 V2$(V%)=MID(A$(A%),42%+(V%-1%)*4%,2%) : IF V2$(V%)="  " THEN 4280
4220 V5%=CVT$%(MID(A$(A%),44%+(V%-1%)*4%,2%))
4240	V2%(1%,V%)=ASCII(CHR$(V5%)) :
	V2%(2%,V%)=ASCII(CHR$(SWAP%(V5%)))
4260 NEXT V%
4280 V2%(1%,0%)=V%-1% : IF N5% THEN 4300 ELSE
	PRINT"CODES: "; :
	PRINT V2$(I%)+" "; FOR I%=1% TO V%-1% : PRINT
4300 CLOSE 1% : ON ERROR GO TO 0 : RETURN
4320 IF ERR<>5% AND ERR<>21% THEN 4380 ELSE RESUME 4340
4340 IF V1$="" THEN V1$="DK1:" : GO TO 4040
4380 PRINT"THE FILE '$ATRIB' HAS BEEN DELETED;" :
	PRINT"IT MUST BE REPLACED TO PROCEED."
9999 END