1000	! FTCH03 -- FETCH OVERLAY #3
	! MERGES ADDITIONS INTO MASTER FILE.
1010	! 02-JAN-74	J. WARDEN	WABASH COLLEGE
1060 CHAIN "DK1:$FETCH"
1080 PRINT"* PASS 2 ";
1100 DIM A$(63),B$(63),C$(63)
1120 S$=SYS(CHR$(7%)) : N%=ASCII(RIGHT(S$,4%))
1130 IF N%<1% OR N%>63% THEN PRINT :
	PRINT"** PLEASE START OVER **" : CHAIN "DK1:$FETCH"
1140 F$=MID(S$,7%,INSTR(7%,S$," ")-7%)
1145 F2$=F$+".TMP"
1150 L0%=CVT$%(MID(S$,27%,2%))
1170 T1%=CVT$%(MID(S$,29%,2%))
1200	IF L0%=0% AND T1%>0% THEN
	KILL F$ : NAME F2$ AS F$ : GO TO 2800
1300	N6%=N%-1% : N1%=510%/N% : N2%=N1%-8%
1310	N3%=N1%-2%
1400 ON ERROR GO TO 4000 : S0$=SYS(CHR$(6%)+CHR$(-7%))
1460 OPEN F$ AS FILE 1%
1470 OPEN F$ FOR INPUT AS FILE 2%
1480 OPEN F2$ FOR INPUT AS FILE 3%
1500 FIELD #1%, N1%*A% AS Z$, N1% AS A$(A%) FOR A%=0% TO N6%
1510 FIELD #2%, N1%*B% AS Z$, N1% AS B$(B%) FOR B%=0% TO N6%
1520 FIELD #3%, N1%*C% AS Z$, N1% AS C$(C%) FOR C%=0% TO N6%
1600	C2%=T1% : C1%=(C2%+N6%)/N% : C%=C2%-1%-(C1%-1%)*N%
1620	B2%=L0% : B1%=(B2%+N6%)/N% : B%=B2%-1%-(B1%-1%)*N%
1640	A2%=L0%+T1% : A1%=(A2%+N6%)/N% : A%=A2%-1%-(A1%-1%)*N%
1700 GET #1%, RECORD A1%
2000 GET #2%, RECORD B1%
2010 R0$=LEFT(B$(B%),6%)
2050 GET #3%, RECORD C1%
2060 C0$=LEFT(C$(C%),6%)
2100 IF C0$>R0$ THEN 2200
2120 LSET A$(A%)=B$(B%)
2130 IF A%>0% THEN A%=A%-1% ELSE
	PUT #1%, RECORD A1% : A1%=A1%-1% : A%=N6% : GET #1%, RECORD A1%
2140 B2%=B2%-1% : IF B2%<=0% THEN R0$="      " :
	GO TO 2100
2150 IF B%>0% THEN B%=B%-1% ELSE
	B%=N6% : B1%=B1%-1% : GET #2%, RECORD B1%
2160	R0$=LEFT(B$(B%),6%)
2170	GO TO 2100
2200 LSET A$(A%)=C$(C%)
2210 IF A%>0% THEN A%=A%-1% ELSE
	PUT #1%, RECORD A1% : A1%=A1%-1% : A%=N6% : GET #1%, RECORD A1%
2220 C2%=C2%-1% : IF C2%<=0% THEN PUT #1%, RECORD A1% :
	GO TO 2800
2230 IF C%>0% THEN C%=C%-1% ELSE
	C%=N6% : C1%=C1%-1% : GET #3%, RECORD C1%
2240	GO TO 2060
2800 PRINT"* DONE"
3000 ON ERROR GO TO 3100 : KILL F2$ : GO TO 3200
3100 RESUME 3200
3200 L0%=L0%+T1% : T1%=0%
3220 S$=SYS(CHR$(8%)+LEFT(S$,26%)+CVT%$(L0%)+CVT%$(T1%)+
	RIGHT(S$,31%))
3240 CHAIN "DK1:$FTCH01" 1025
4000 IF ERR=28% THEN RESUME ELSE ON ERROR GO TO 0
9999 END