100	! GPALIS - LISTING OF CUMULATIVE AVERAGES
	! AND HOURS PASSED, ETC. 4 & 9 POINT.
120	! 24-NOV-73	J. WARDEN	WABASH COLLEGE
140 N5%=1% : GOSUB 1020
160 DEF FNC(X%)=CVT$F(MID(A$(A%),V2%(1%,X%),V2%(2%,X%)))
180 PRINT"CUMULATIVE AVERAGE LISTING"
200 J%=11% : K%=24%
220 PRINT"SEMESTER &YEAR (SPRING 1972-73)"; :
	INPUT LINE H$ : H$=LEFT(H$,LEN(H$)-2%) :
	IF LEN(H$)<3% THEN 220
240 ON ERROR GO TO 940
260 F0$=     "##.### ###.#  ###.#  ###.#  ##.### ###.# ###.#  ###.#"
280 DIM F2$(13)
300 READ F2$(I%) FOR I%=0% TO 13%
320 DATA "OFF CPS","BETA   ","DELT   ","KAP SIG","LAM CHI"
340 DATA "PHIDELT","PHI GAM","PHI PSI","SIG CHI"
360 DATA "TEKE   ","KINGERY","MARTIND","MORRIS ","WOLCOTT"
380 INPUT"FILE TO BE LISTED (DEV:FILE)";F$
400 OPEN F$ FOR INPUT AS FILE 1%
420 FIELD #1%,N1%*A% AS Z$,N1% AS A$(A%) FOR A%=0% TO N6%
440 INPUT"OUTPUT TO";O$ : IF O$="" THEN O$="KB:"
460 OPEN O$ FOR OUTPUT AS FILE 2%
480 INPUT"SELECTED CLASS (<CR> FOR ALL)";C$ :
	C%=LEN(C$) : IF C%*(C%-2%) THEN 480
500 GOSUB 760
520 FOR I%=1% TO 25%
540 IF A%<N6% THEN A%=A%+1% ELSE A%=0% : GET #1%
560	IF LEFT(A$(A%),1%)="\" THEN 960
580	IF C% THEN IF MID(A$(A%),7%,2%)<>C$ THEN 540
600 PRINT #2%,MID(A$(A%),7%,2%);"  ";MID(A$(A%),13%,17%);"  ";
620 IF FNC(5%)+FNC(11%)<.001 THEN PRINT #2% : GO TO 660
640 PRINT #2%,USING F0$,FNC(5%),FNC(7%),FNC(9%),FNC(8%),
	FNC(11%),FNC(13%),FNC(15%),FNC(14%)
660 PRINT #2%
680 NEXT I%
700 PRINT#2,CHR$(12)
720 GOSUB 760
740 GO TO 520
760 PRINT #2%,"   CUMULATIVE AVERAGES         "+H$;
780 PRINT#2,"        "+DATE$(0) : PRINT#2," "
800 PRINT#2," "
820 PRINT #2%,"YR       NAME"+SPACE$(J%);
840 PRINT #2%,"CUM    HRS    HRS    HRS    CUM   CRED   CRED   CRED"
860 PRINT #2%,SPACE$(K%);
880 PRINT #2%,"9 PT   PASS   GRAD   CUM    4 PT  PASS   GRAD   CUM"
900 PRINT #2%,CHR$(10%)
920 RETURN
940 IF ERR<>11% THEN ON ERROR GO TO 0
960 PRINT #2,CHR$(26%)
980 CLOSE 1,2
1000 GO TO 1420
1020 DIM V2$(50),V2%(2,50)
1040 ON ERROR GO TO 1360
1060 F$="GPA"
1080 OPEN V1$+"$ATRIB" FOR INPUT AS FILE 1%
1100 FIELD #1%, 255%*A% AS Z$, 255% AS A$(A%) FOR A%=0% TO 1%
1120 IF A%<1% THEN A%=A%+1% ELSE A%=0% : GET #1% : R%=R%+1%
1140	IF LEFT(A$(A%),3%)="\\\" THEN
	PRINT"NO SUCH FILE TYPE" : GO TO 1420
1160 IF LEFT(A$(A%),3%)<>F$ THEN 1120
1180 V2%(2%,0%),N%=VAL(MID(A$(A%),4%,2%)) :
	N9%=VAL(MID(A$(A%),6%,1%))*2%
1200 N1%=510%/N% : N2%=N1%-8% : N3%=N%*N1% : N6%=N%-1%
1220 FOR V%=1% TO 50%
1240 V2$(V%)=MID(A$(A%),42%+(V%-1%)*4%,2%) : IF V2$(V%)="  " THEN 1320
1260 V5%=CVT$%(MID(A$(A%),44%+(V%-1%)*4%,2%))
1280	V2%(1%,V%)=ASCII(CHR$(V5%)) :
	V2%(2%,V%)=ASCII(CHR$(SWAP%(V5%)))
1300 NEXT V%
1320 V2%(1%,0%)=V%-1% : IF N5% THEN 1340 ELSE
	PRINT"CODES: "; :
	PRINT V2$(I%)+" "; FOR I%=1% TO V%-1% : PRINT
1340 CLOSE 1% : ON ERROR GO TO 0 : RETURN
1360 IF ERR<>5% AND ERR<>21% THEN 1400 ELSE RESUME 1380
1380 IF V1$="" THEN V1$="DK1:" : GO TO 1080
1400 PRINT"THE FILE '$ATRIB' HAS BEEN DELETED;" :
	PRINT"IT MUST BE REPLACED TO PROCEED."
1420 END