100	! HONORS - PRINTS OUT HONORS CANDIDATES
120	! WILL CLASSIFY BY ANSWER OR EXAM
140	! TYPE A FOR ALL,Y FOR Y,N,M; E1 FOR 1ST DAY EXAM,
160	! E2 FOR 2ND DAY EXAM
180	! 14-MAR-74	J. WARDEN	WABASH COLLEGE
200 PRINT"HONORS CANDIDATES REPORT"
220	R0$="1"
230 S0$="######.#  #####.###"
232 S1$="RAW SCORE   Z SCORE"
235 DEF FNF(X%)=CVT$F(MID(B$(B%),X%,4%))
237 DEF FNF%(X%)=CVT$%(MID(B$(B%),X%,2%))
240	! IDENTIFICATION OF JOBS
260 DIM C$(4,4)=1,C%(4)
280 DIM C3%(4)
300 READ C$(J,I) FOR I=1 TO 4 FOR J=1 TO 4
320 READ C%(I) FOR I=1 TO 4
340 READ C3%(I) FOR I=1 TO 4
360 DATA " "," "," "," "
380 DATA "Y","N","M"," "
400 DATA "E","A","W"," "
420 DATA "B","C","M","P"
440 DATA 83,8,9,10
460 DATA 1,3,3,4
480 PRINT"HONORS FILE"; : INPUT LINE H$ :
	H$=LEFT(H$,LEN(H$)-2%)
500 INPUT"OUTPUT TO";D1$ :
	IF D1$="" THEN D1$="KB:"
520 INPUT"IS FILE SORTED BY REGION (Y/N)";R$ :
	IF ASCII(R$)=89% THEN R%=1%
540 N%=6% : N1%=510%/N% : N6%=N%-1%
560 GOSUB 580 : GO TO 640
580 OPEN H$ FOR INPUT AS FILE 1%
600 FIELD #1%,N1%*B% AS Z$, N1% AS B$(B%) FOR B%=0% TO N6%
620 RETURN
640 INPUT"A, Y, E1, E2, OR S";X$
645 IF X$="" THEN 1440
650 IF ASCII(X$)=83% THEN S%=1% : PRINT"SCORE OUTPUT" : GO TO 640
660 IF S% AND (X$="A" OR X$="Y") THEN &"SCORE OUTPUT AVAILABLE ";
	"ONLY FOR E1 AND E2" : GO TO 640
680 IF X$="A" THEN V%=1 : GO TO 780
700 IF X$="Y" THEN V%=2% : GO TO 780
720 IF X$="E1" THEN V%=3% : GO TO 780
740 IF X$="E2" THEN V%=4% : GO TO 780
760 PRINT"** RETYPE PLEASE! **" : GO TO 640
780 IF Q% THEN 820
800 OPEN D1$ FOR OUTPUT AS FILE 2
820 FOR V1%=1% TO C3%(V%)
840 GOSUB 1260
860 C4$=C$(V%,V1%) : C5%=C%(V%)
880 q%=2%	! output device open
900 C2%=0%	! COUNTER
920 IF B%<N6% THEN B%=B%+1% ELSE B%=0% : GET #1%
940 IF LEFT(B$(B%),1%)="\" THEN 1140
960 IF MID(B$(B%),C5%,1%)<>C4$ THEN 920
980	IF R%=0% THEN 1020
1000	R1$=MID(B$(B%),11%,1%) : IF R1$<>R0$ THEN R0$=R1$ :
	P%=0% : GOSUB 1240
1020 PRINT #2%,LEFT(B$(B%),6%)+"    "+MID(B$(B%),8%,1%)+"  ";
	MID(B$(B%),9%,1%)+"  "+MID(B$(B%),10%,1%)+"  ";
1030 PRINT #2%,MID(B$(B%),13%,28%);
1035 IF S%=0% THEN 1055
1037 IF V%=3% THEN X1%=62% : X2%=70%
1039 IF V%=4% THEN X1%=66% : X2%=74%
1040 PRINT #2%,USING S0$,FNF(X1%),FNF(X2%)
1045	GO TO 1080
1055 PRINT #2%," ";MID(B$(B%),11%,1%);"  ";
1060 PRINT #2%,MID(B$(B%),41%,14%);" ";MID(B$(B%),55%,2%);"  ";
1070 PRINT #2%,MID(B$(B%),7%,1%);"   ";MID(B$(B%),12%,1%)
1080 P%=P%+1% : IF P%>50% THEN P%=0% : GOSUB 1240
1100 C2%=C2%+1%
1120 GO TO 920
1140 PRINT#2 : PRINT#2 : PRINT#2,"  ===>  ";C2%;" TOTAL"
1160 print#2,chr$(12)
1180 CLOSE 1% : GOSUB 580
1200 NEXT V1%
1220 GO TO 1420
1240 PRINT #2%,CHR$(12%)
1260 PRINT #2%,"HONORS CANDIDATES REPORT  (";X$;")      ";
1265	IF R% THEN PRINT #2%,"** REGION ";R0$;" **      ";
	ELSE PRINT #2%,SPACE$(20%);
1270 PRINT #2%, DATE$(0%)+CHR$(10%)
1280	! HEADER LINE SUBROUTINE
1300 PRINT #2%,"ID CODE      EXAM  NAME";SPACE$(25%);
1305	IF S% THEN &#2%,S1$ ELSE &#2%,"RG ";
	"CITY           ST  NO   OFF"
1320 PRINT #2%,"             1  2";SPACE$(53%); :
	IF S%=0% THEN &#2%,"FEE  CPS" ELSE &#2%
1340 PRINT#2
1360 P%=0%
1380 RETURN
1400	! TRY AGAIN
1420 CLOSE 1% : GOSUB 580 : GO TO 640
1440 CLOSE 1%,2%
1460 PRINT"ANALYSIS COMPLETE"
1480 END