100	! LABELX -- LABEL PRINTING PROGRAM
	! CHOICE OF SEQ ACCESS FOR ID ORDER OR RANDOM
	! ACCESS FOR ZIP OR CLASS ORDER.
120	! 11-AUG-74	J. WARDEN	WABASH COLLEGE
140 PRINT"ADDRESS LABEL PRINTER"
160 &"[SELECT IN LINES 820-860]"
200 INPUT"FILE TYPE";A$ : GO TO 200 IF LEN(A$)<>3% :
	IF A$="ALQ" THEN N%=2% ELSE N%=4%
220 N6%=N%-1% : N1%=510%/N%
240 INPUT"WANT LISTING IN ID (ALPHABETIC) ORDER (Y/N)";Y$ :
	IF ASCII(Y$)=89% THEN 280
260 GOSUB 2020
280 ON ERROR GO TO 1000
300 IF P1% THEN 380
320 INPUT"FILE TO BE LISTED";F$ : IF F$="" THEN 2840
340 OPEN F$ FOR INPUT AS FILE 1%
360 FIELD #1%, N1%*A% AS Z$, N1% AS A$(A%) FOR A%=0% TO N6%
380 INPUT"OUTPUT TO";F3$ : IF F3$=F$ THEN CLOSE 1% : GO TO 2840
400 OPEN F3$ FOR OUTPUT AS FILE 2%
420 H%=2%
460 PRINT"INSERT HEADER LINE ('RETURN' FOR NONE)"
480 INPUT LINE H1$ : H1$=LEFT(H1$,LEN(H1$)-2)
500 IF LEN(H1$)<1% THEN H1$="   "
520 PRINT"HEADER: "+H1$ : INPUT"-> CORRECT (Y/N)";F3$ :
	IF ASCII(F3$)=89% THEN 560
540 PRINT"OK, TRY AGAIN:" : GO TO 480
560 GOSUB 1140	! DECIDE ON MARKER LABELS
580 IF M5%=2% THEN GOSUB 2700	! IF CLASS SEL. OPEN FILE
590 INPUT"SKIP UNTIL PAST ID";J1$
600 GOSUB 1260		! PRINT HEADER LABEL
620 ON ERROR GO TO 1000
680 IF LEN(J1$) THEN GOSUB 1940
720	! MAIN PRINTING LOOP
740  IF P1% THEN GOSUB 2500 ELSE GOSUB 2440
760	IF ASCII(A$(A%))=92% THEN 2640
780 C4$=MID(A$(A%),7%,2%) : IF C4$=C3$ THEN 820
800     GOSUB 1680
820	! - - SELECTION ROUTINE CAN BE INSERTED HERE - -
840 	! IF [RECORD IS TO BE REJ] THEN 740
860	! - - END OF SELECTION ROUTINE - -
880 GOSUB 1380 : GO TO 720
980	! ERROR SUBROUTINE
1000 IF ERR=52% THEN RESUME 740 ELSE IF ERR=5% THEN RESUME 2380
1020 IF ERR=11% THEN 2640
1030 IF ERR<>14% THEN ON ERROR GO TO 0
1040 IF ERL>1460% AND ERL<1660% THEN RESUME 1466
1050 IF ERL>1720% AND ERL<1800% THEN RESUME 1730
1060 ON ERROR GO TO 0
1140 INPUT" WANT CLASS YR PRINTED ON EACH LABEL (Y/N)";Y1$
1160 IF Y1$="Y" THEN Y%=1% ELSE IF Y1$="N" THEN Y%=2% ELSE GO TO 1140 
1180 IF M5%=0% THEN RETURN
1200 INPUT"WANT ALL ENTRIES OR SELECTED YEARS (A/S)";Y2$
1220 IF Y2$="A" THEN M5%=1% ELSE IF Y2$="S" THEN M5%=2%
	ELSE GO TO 1200
1240 RETURN
1260	! HEADER LABEL SUBROUTINE
1280 PRINT #2%,H1$
1300 PRINT#2,DATE$(0)
1320 PRINT #2%,CHR$(10%)+CHR$(10%)+CHR$(10%)
1340 C4$=C3$ : IF LEN(C3$) THEN GOSUB 1760
1360 RETURN
1380	! MAIN LABEL PRINTING SUBROUTINE
1400 IF M6% THEN M6%=0% : RETURN  ! RESET NO PRINT FLAG
1420 Y1$(2%)=MID(A$(A%),39%,2%) : Y1$(1%)=MID(A$(A%),7%,2%)
1440 C%=C%+1%	! COUNT LABEL
1460 E$=MID(A$(A%),97,14)+"  "+MID(A$(A%),111,2)+"  "+MID(A$(A%),113,5)
1462	GO TO 1480
1464	! START OVER HERE AFTER LP: ERROR
1466 PRINT CHR$(7%);"PRINTER HUNG -- RESET IT"
1468	INPUT"READY";Q$ : IF ASCII(Q$)<>89% THEN
	PRINT #2% : GO TO 1468
1480 PRINT #2%,MID(A$(A%),13%,26%);Y1$(Y%)
1500 PRINT #2,MID(A$(A%),41%,28%)	! ADDRESS
1520 IF MID(A$(A%),69%,5%)="     " THEN 1620 
1560 PRINT #2%,MID(A$(A%),69%,24%)
1580 PRINT #2%,E$ : PRINT #2%,CHR$(10%) : RETURN
1620 PRINT #2%,E$ : PRINT #2%,CHR$(10%)+CHR$(10%) : RETURN
1680	! SELECT NEW CY - PRINT MARKER LABEL
1700 IF M5%=0% THEN RETURN ELSE IF M5%=2% THEN 1820
1720 C3$=C4$ : GO TO 1760
1730 PRINT CHR$(7%);"PRINTER HUNG -- RESET IT"
1732	INPUT"READY";Q$ : IF ASCII(Q$)<>89% THEN
	PRINT #2% : GO TO 1732
1760 PRINT #2% : PRINT #2%,"CLASS OF ";C4$
1780 PRINT #2,CHR$(10)+CHR$(10)+CHR$(10)
1800 RETURN
1820 IF C4$<C3$ THEN M6%=1% : RETURN
1840 INPUT #4%,C3$ : IF C3$="\\" THEN 2640
1860 IF C3$=C4$ THEN 1760
1880 PRINT #2% : PRINT #2%,"CLASS OF "+C3$
1900 PRINT #2%,CHR$(10%)+CHR$(10%)+CHR$(10%)
1920 GO TO 1820
1940	! SKIP RECORDS
1960 IF P1% THEN GOSUB 2500 ELSE GOSUB 2440
1980 IF LEFT(A$(A%),6%)<>J1$ THEN 1960 
2000 RETURN
2020 DIM P$(63)
2040 ON ERROR GO TO 2340
2060 INPUT"TYPE OF SORT (C,Z, OR O)";F$
2080 IF F$="C" THEN M5%=1%
2100	IF F$="C" THEN E$=".CYR" : L2%=2% : GO TO 2180
2120	IF F$="Z" THEN E$=".ZIP" : L2%=5% : GO TO 2180
2140	IF F$="O" THEN E$=".KEY" ELSE GO TO 2060
2160 INPUT" KEY LENGTH";L2% :
	IF L2%<1% OR L2%>6% THEN 2160
2180 L2%=L2%+1%
2200 INPUT"FILE TO BE LISTED (DEV:FILE)";F$ : A%=INSTR(1%,F$,".") :
	IF A% THEN F$=LEFT(F$,A%-1%)
2220 P1$=F$+E$
2240 OPEN P1$ FOR INPUT AS FILE 3%
2260 FIELD #3%,8%*P% AS Z$, 8% AS P$(P%) FOR P%=0% TO 62%
2280 OPEN F$ FOR INPUT AS FILE 1%
2300 FIELD #1%,N1%*A% AS Z$, N1% AS A$(A%) FOR A%=0% TO N6%
2320 P1%=1% : RETURN
2340 IF ERR=5% THEN RESUME 2360 ELSE ON ERROR GO TO 0
2360 IF ERL=2240% THEN PRINT"** CAN'T FIND FILE '"+P1$+"' ." :
	PRINT"   EITHER YOU MIS-TYPED THE NAME OR THE FILE HAS ";
	"NOT BEEN SORTED." : GO TO 2840
2380 IF ERL=340% THEN PRINT
	"** CAN'T FIND FILE ";F$;" **" : GO TO 320
2400 ON ERROR GO TO 0
2420 !	GET FOR SEQUENTIAL ACCESS
2440 IF A%<N6% THEN A%=A%+1% ELSE A%=0% : GET #1%
2460 RETURN
2480 !	GET FOR RANDOM ACCESS
2500 IF P%<62% THEN P%=P%+1% ELSE P%=0% : GET #3%
2520	IF ASCII(P$(P%))=92% THEN 2640
2540 I2%=CVT$%(MID(P$(P%),L2%,2%))
2560 R1%=(I2%+N6%)/N%
2580 A%=I2%-1%-(R1%-1%)*N%
2600 GET #1%,RECORD R1%
2620 RETURN
2640 CLOSE 1%,2%,3%,4%
2660 PRINT : PRINT C%;"ITEMS PRINTED"
2680 GO TO 2840
2700 ON ERROR GO TO 2780
2720 OPEN "CYFIL.TMP" FOR INPUT AS FILE 4%
2740 INPUT #4%,C3$
2760 RETURN
2780 PRINT"TO INSERT YOUR CLASS YEARS FOR SELECTION YOU MUST"
2800 PRINT"FIRST RUN THE PROGRAM 'CYEARS'"
2820 GO TO 2640
2840 END