1	! LIST3 -- PRINTS ALL INFO ON CURRENT STUDENTS
	! WITH HIGH SCHOOL PROMINENTLY DISPLAYED
	! (FOR ADMISSIONS OFFICE)
2	! 08-NOV-73	J. WARDEN	WABASH COLLEGE
50 DIM F$(14%)
55	P9%=9%	! ## ITEMS / PAGE MINUS 1
60 PRINT"CURRENT STUDENTS - ALL INFO PLUS HS CODE"
70 DATA "       ",BETA,DELT,"KAP SIG","LAM CHI",PHIDELT
71 DATA "PHI GAM","PHI PSI","SIG CHI",TEKE
72 DATA KINGERY,MARTIND,MORRIS,WOLCOTT
100 DEF FNF$(X%)=MID(A$(R%),V2%(1%,X%),V2%(2%,X%))
110 G$= "\"+SPACE$(28%)+"\      \"+SPACE$(16%)+"\"
115 G$="\      \     "+G$
117 H0$="\"+SPACE$(46%)+"\ "+DATE$(0%)
120 N5%=1%
140 GOSUB 4000
	! LOOK UP ATTRIBUTES
160 RESTORE
170 READ F$(I%) FOR I%=0% TO 13%
180 ON ERROR GO TO 300
200 F1$="DK0:CSB73[60,20]"
220 INPUT"OUTPUT FILE (DEV:FILE)";F2$
230 PRINT"HEADER LINE"; : INPUT LINE H$ :
	H$=LEFT(H$,LEN(H$)-2%)
240 OPEN F1$ FOR INPUT AS FILE 1%
250 FIELD #1%,N1%*R% AS Z$,N1% AS A$(R%) FOR R%=0% TO N6%
260 OPEN F2$ FOR OUTPUT AS FILE 2%
290 GO TO 390
300 IF ERR<>5% THEN ON ERROR GO TO 0
340 PRINT CHR$(7%)+"** CAN'T FIND "+F1$+" **" : RESUME 360
360 INPUT"INPUT FILE (DEV:FILE)";F1$
	! TRY FOR INPUT FILE AGAIN
380 GO TO 240
390 ON ERROR GO TO 900
395 GOSUB 2010
400 IF R%<N6% THEN R%=R%+1% ELSE R%=0% : GET #1%
420 IF LEFT(A$(R%),1%)="\" THEN 1000	! END-OF-FILE?
440 P$=FNF$(11%) : P$=LEFT(P$,3%)+"-"+RIGHT(P$,4%)
445 IF LEFT(P$,3%)="   " THEN P$=SPACE$(8%)
450 PRINT #2%,USING G$,FNF$(14%),FNF$(5%),FNF$(1%)
460 PRINT #2%,USING G$," ",FNF$(6%),P$
470 F%=ASCII(FNF$(4%))-48% : IF F%<1% OR F%>13% THEN F%=0%
475 S2$=FNF$(13%) : S2$=LEFT(S2$,2%)+"  "+RIGHT(S2$,3%)
480 PRINT #2%,USING G$," ",FNF$(12%)+"  "+S2$,F$(F%)
490 PRINT #2%,CHR$(10%)
500 IF Q%<P9% THEN Q%=Q%+1% ELSE Q%=0% : GOSUB 2000
520 GO TO 400
900 IF ERR<>11% THEN ON ERROR GO TO 0
1000 PRINT #2%,CHR$(26%)
1100 CLOSE 1%,2%
1400 GO TO 9999
2000 PRINT #2%,CHR$(12%);
2010 PRINT #2%,USING H0$,H$
2020 PRINT #2%,CHR$(10%)+CHR$(10%)
2030 RETURN
4000 DIM V2$(50),V2%(2,50)
4020 ON ERROR GO TO 4320
4030 F$="CSB"
4040 OPEN V1$+"$ATRIB" FOR INPUT AS FILE 1%
4060 FIELD #1%, 255%*A% AS Z$, 255% AS A$(A%) FOR A%=0% TO 1%
4080 IF A%<1% THEN A%=A%+1% ELSE A%=0% : GET #1% : R%=R%+1%
4100	IF LEFT(A$(A%),3%)="\\\" THEN
	PRINT"NO SUCH FILE TYPE" : GO TO 9999
4120 IF LEFT(A$(A%),3%)<>F$ THEN 4080
4140 V2%(2%,0%),N%=VAL(MID(A$(A%),4%,2%)) :
	N9%=VAL(MID(A$(A%),6%,1%))*2%
4160 N1%=510%/N% : N2%=N1%-8% : N3%=N%*N1% : N6%=N%-1%
4180 FOR V%=1% TO 50%
4200 V2$(V%)=MID(A$(A%),42%+(V%-1%)*4%,2%) : IF V2$(V%)="  " THEN 4280
4220 V5%=CVT$%(MID(A$(A%),44%+(V%-1%)*4%,2%))
4240	V2%(1%,V%)=ASCII(CHR$(V5%)) :
	V2%(2%,V%)=ASCII(CHR$(SWAP%(V5%)))
4260 NEXT V%
4280 V2%(1%,0%)=V%-1% : IF N5% THEN 4300 ELSE
	PRINT"CODES: "; :
	PRINT V2$(I%)+" "; FOR I%=1% TO V%-1% : PRINT
4300 CLOSE 1% : ON ERROR GO TO 0 : RETURN
4320 IF ERR<>5% AND ERR<>21% THEN 4380 ELSE RESUME 4340
4340 READ V1$ : GO TO 4040
4360 DATA DK2:,DK1:,DK0:,DK3:
4380 PRINT"THE FILE '$ATRIB' HAS BEEN DELETED;" :
	PRINT"IT MUST BE REPLACED TO PROCEED."
9999 END