1	! LOOKUP -- FINDS STUDENTS IN A GIVEN HS
100 PRINT"HIGH SCHOOL LOOKUP -- ADMISSIONS"
110 READ L% : READ S%(K%),F%(K%) FOR K%=1% TO L%
115 DATA 6
120 DATA 7,28,118,3,121,4,115,1,133,3,136,4
200 INPUT"H.S. CODE";H$
250 IF LEN(H$)<>6% THEN PRINT"CODE MUST BE 6 CHARACTERS";
	" LONG; PLEASE RETYPE!" : GO TO 200
260 INPUT"SINGLE OR DOUBLE-SPACED (S/D)";S$ : S$=LEFT(S$,1%) :
	IF S$<>"S" AND S$<>"D" THEN PRINT"PLEASE TYPE S OR D!" :
	GO TO 260
270 IF S$="D" THEN S$=CHR$(10%) ELSE S$=""
300 OPEN "DK3:ADM78" FOR INPUT AS FILE 1%
320 OPEN"KB:" FOR OUTPUT AS FILE 2%
350 N%=2% : N1%=510%/2% : N6%=N%-1%
400 FIELD #1%,N1%*A% AS Z$, N1% AS A$(A%) FOR A%=0% TO N6%
420 PRINT #2%,CHR$(10%)+CHR$(10%)
430 PRINT #2%,"CANDIDATES FROM HIGH SCHOOL "+H$+CHR$(10%)
440 PRINT #2%,DATE$(0%)
450 PRINT #2% : PRINT #2%,
	"    NAME                        RANK  CLASS   NEED  PHONE":
	PRINT #2%,
	"-----------------------         ----  -----   ----  -----"
500 IF A%<N6% THEN A%=A%+1% ELSE A%=0% : GET #1%
550	IF LEFT(A$(A%),1%)="\" THEN 800
560 X%=X%+1%
600 IF MID(A$(A%),125%,6%)<>H$ THEN 500
650	FOR K%=1% TO L%
660	PRINT #2%,MID(A$(A%),S%(K%),F%(K%));
665	IF K%=5% THEN PRINT #2%,"-";
	ELSE PRINT #2%,"    ";
670	NEXT K%
680	PRINT #2%,S$
700 GO TO 500
800 PRINT #2 : PRINT #2%,X%;" RECORDS SEARCHED"
820 CLOSE 1%,2%
999 END