1	!!!!	OUTPUT.BAS (V4A-12)	EDIT 1	06/17/74	!!!!
	!!!!	WRITTEN BY JEFFREY J. KILLEEN			!!!!
	!!!!	ASSUMPTION COLLEGE	WORCESTER,MASS.		!!!!

100 T2%=3%                                                                                !TERMINAL NUMBER OF TERMINAL WITH PHONE
110 !		T2% MUST ALWAYS BE TERMINAL TO THE
		OTHER COMPUTER
120 ON ERROR GOTO 230 : A$=SYS(CHR$(6%)+CHR$(-7%))                                        !SET ^C TRAP
130 OPEN "KB:" AS FILE 1%                                                                 !OPEN KB: WHICH USER WILL TYPE ON
140 A$=SYS(CHR$(3%))                                                                      !SET KB: TO NO ECHO
150 A$=SYS(CHR$(4%)) : GET#1% : FIELD#1%,RECOUNT AS A$                                    !SET ODT SUBMODE --- GET'INPUT'PLACE IN A$
160 IF A$=CHR$(5%) THEN 310                                                               !IF ^E EXIT FROM PROGRAM
170 IF A$=CHR$(20%) THEN 250                                                              !IF ^T GO INTO FILE TRANSFER MODE
180 IF A$=CHR$(6%) THEN
	A$=SYS(CHR$(6%)+CHR$(-4%)+CHR$(T2%)+CHR$(6%)+CHR$(13%)) :
	GO TO 150                                                                         !IF ^F FORCE CHR(6) TO 'INPUT' TO KILL IT
190 L%=LEN(A$) : X%=0%                                                                    !X% IS USED TO BACK COUNT THROUGH A$
200 IF ASCII(RIGHT(A$,L%-X%))>28% THEN A$=LEFT(A$,L%-X%+1%) ELSE
	X%=X%+1% : IF X%<>L% THEN 200 ELSE A$=CHR$(ASCII(A$))                             !PULLS OFF EXTRA CONTROL CHARS.
210 IF RIGHT(A$,L%)=CHR$(27%) THEN A$=CHR$(155%)                                          !SWITCH ESCAPE TO CHR(155) TO SAVE IT
220 A$=SYS(CHR$(6%)+CHR$(-5%)+CHR$(T2%)+A$) : GO TO 150                                   !SENDS A$ TO OTHER COMPUTER - END OF LOOP
230 IF ERR<>28% THEN ON ERROR GO TO 0 ELSE RESUME 240                                     !CHECK FOR ^C
240 A$=SYS(CHR$(6%)+CHR$(-7%)) : A$=SYS(CHR$(3%)) :
	A$=CHR$(3%) : GO TO 220                                                           !RESET ^C TRAP + NO ECHO SEND OUT ^C
250 A$=SYS(CHR$(2%))                                                                      !START OF FILE TRANSFER LOOP -- KB:=ECHO
260 PRINT " FILENAME FOR INPUT";: INPUT LINE A$ :
	A$=LEFT(A$,LEN(A$)-2%) : OPEN "NAME.DAT" AS FILE 4% :
	DIM#4%,N$(1%) : N$(1%)=A$ : CLOSE 4%                                              !GET NAME OF FILE AND PLACE IN "NAME.DAT"
270 A$=SYS(CHR$(6%)+CHR$(-4%)+CHR$(T2%)+CHR$(2%)+CHR$(13%))                               !FORCE INPUT CHR(2) FOR FILE MODE
280 INPUT#1%,A$                                                                           !WAIT FOR INPUT TO FORCE A <CR>
290 PRINT "TYPE <CR> WHEN READY" :
	A$=SYS(CHR$(6%)+CHR$(-5%)+CHR$(T2%)+CHR$(13%)) :
	INPUT#1%,A9$                                                                      !SEND <CR> TO OTHER COMPUTER - END TRANS.
300 A$=SYS(CHR$(6%)+CHR$(-4%)+CHR$(T2%)+CHR$(5%)+CHR$(5%)+CHR$(13%)) :
	GO TO 140                                                                         !END FILE TRANSFER - FORCE 'INPUT' CHR(5)
310 CLOSE 1% : A$=SYS(CHR$(2%)) : END                                                     !CLOSE KB: -- RESET ECHO