1000 ! PROGRAM NAME --> W O R D 3  -- BY KARL KNAPP
1025 DIM A$(2%),B$(2%),C$(2%),D$(2%)
1050 OPEN "SPELL" AS FILE 2%:DIM #2%,W1$(100%)=16%,W$(500%)=16%
1060 RANDOM:Z%=INT(1000%*RND(0%)):Z1%=CVT$%(W$(0%)):
	Z%=Z%-Z%/Z1%*Z1%+1%:W$(Z1%+1%)=CVT%$(Z%)
1070 GOTO 1060 IF LEN(W$(Z%))<>3%
1075 W%=CVT$%(W$(0%)):W1%=CVT$%(W$(W%+1%))
1100 PRINT "I HAVE A 3 LETTER WORD  (IT'S CLEAN)."
1200 PRINT "CAN YOU GUESS IT?"
1300 PRINT "FOR PLAYING INSTRUCTIONS, TYPE IN AN 'I' ---> ";
1400 OPEN "KB:" AS FILE 1%:FIELD #1%,K% AS Q$,1% AS M3$(K%)
	FOR K%=0% TO 10%
1450 V9$=SYS(CHR$(3%))
1500 GOSUB 29000:PRINT M4$;:GOTO 7500 IF M4$="I"
1600 !
1700 PRINT
1710 W1%=CVT$%(W$(W%+1%)):W$(W%+1%)=CVT%$(1%) IF W1%>W%
1720 W1%=CVT$%(W$(W%+1%)):A%=0% FOR K%=W1% UNTIL K%>W%
	OR LEN(W$(K%))=3%
1730 IF K%>W% THEN W$(W%+1%)=CVT%$(1%):GOTO 1720
1740 W$(W%+1%)=CVT%$(K%+1%):A$=W$(K%)
1750 PRINT "I'M READY -- GO!!!":PRINT:PRINT:PRINT
1800 A$(K%)=MID(A$,K%+1%,1%) FOR K%=0% TO 2%
1825 P%,Q%,R%,S%=0%
1850 FOR J%=0% TO 2%
1900 GOSUB 29000:GOTO 8500 IF M4$="?":GOTO 1900 IF M4$<"A" OR M4$>"Z":
	PRINT M4$;:C$(J%)=M4$+"":NEXT J%
2000 B$="":B$=B$+C$(J%) FOR J%=0% TO 2%
2200 R%=R%+1%:IF A$=B$ THEN 8000
2300 FOR K%=0% TO 2%:B$(K%)=A$(K%):D$(K%)=C$(K%):NEXT K%
2400 FOR K%=0% TO 2%:FOR J%=0% TO 2%:
       IF B$(K%)=D$(J%) AND B$(K%)<>"$" THEN 3000
2500 NEXT J%:NEXT K%:PRINT ,S%;:IF S%=2% AND P%=0% THEN 3100
2600 IF S%=3% AND Q%=0% THEN 3200
2700 PRINT:S%=0%:GOTO 1850
3000 B$(K%),D$(J%)="$":S%=S%+1%:GOTO 2500
3100 PRINT ,"YOU'RE WARM!";:P%=1%:GOTO 2700
3200 PRINT ,"YOU'RE HOT!!!";:Q%=1%:GOTO 2700
4000 GOTO 1600
4100 GOTO 1700
7500 PRINT:PRINT:PRINT "TYPE IN A SERIES OF THREE"
	+ " LETTERS AND I WILL TELL YOU HOW"
7600 PRINT "MANY TIMES THEY OCCUR IN MY"
	+ " WORD.  WHEN YOU TYPE THE EXACT"
7700 PRINT "WORD I'LL LET YOU KNOW.":PRINT
7800 PRINT "IF YOU GIVE UP TYPE A QUESTION"
	+ " MARK - (?).":PRINT:GOTO 1600
8000 PRINT ,"THAT'S IT!",R%;"TRIES  -  ";:IF R%<7% 
       THEN PRINT "FANTASTIC":GOTO 8700
8100 IF R%<12% THEN PRINT "VERY GOOD!":GOTO 8700
8200 IF R%<22% THEN PRINT "TRY HARDER!":GOTO 8700
8300 PRINT "YOU NEED MORE PRACTICE!":GOTO 8700
8500 PRINT M4$:PRINT "GIVING UP AFTER ONLY";R%;"TRIES"
8600 PRINT "THE CORRECT ANSWER WAS '";A$;"'":PRINT
8700 PRINT "ANOTHER WORD? ";:GOSUB 29000:PRINT M4$:PRINT:
	GOTO 4000 IF M4$="Y":GOTO 8800 IF M4$="N":PRINT
	"'Y' OR 'N' PLEASE!!":PRINT:GOTO 8700
8800 PRINT "THAT IS ALL":PRINT:PRINT:PRINT:CLOSE 1%,2%
9000 V9$=SYS(CHR$(2%)):GOTO 32767
29000 GOTO 29100 IF M3%=Z3%:M4$=M3$(M3%):M3%=M3%+1%:RETURN
29100 M3%=0%:V9$=SYS(CHR$(4%)):GET #1%:Z3%=RECOUNT:GOTO 29000
32767 END