1 ! PROGRAM NAME --> F I N A L  -- BY BOB HUNTSMAN
12 OPEN "KB:" AS FILE 1%:FIELD #1%,K% AS Q$,1% AS M3$(K%)
	FOR K%=0% TO 9%
20 PRINT:INPUT "NAME (CR)---> ";N$:PRINT
30 RANDOM:Q%(K%)=FNR% FOR K%=0% TO 9%
40 FOR K%=0% TO 9%:GOSUB 500:A%(K%*4%+J%)=B%(J%) FOR J%=0% TO 3%:NEXT K%
45 A%=K% IF A%(32%+K%)=3% FOR K%=0% TO 3%:A%(32%+A%)=A%(35%):
	A%(35%)=3%:Q%(8%)=2%
50 DIM Q$(9%,3%),A$(9%,3%),Q%(9%),A%(39%),B%(3%),C$(9%)
70 READ C$(K%) FOR K%=0% TO 9%:READ Q$(K%,J%) FOR J%=0% TO 3% FOR K%=0% TO 9%
80 READ A$(K%,J%) FOR J%=0% TO 3% FOR K%=0% TO 9%
94 T1%=32%:T%=23%
100 FOR K%=0% TO 9%
110 PRINT:PRINTUSING "##.  ",K%+1%;:PRINT C$(K%);Q$(K%,Q%(K%))
120 PRINT:PRINT CHR$(65%+J%);". ";A$(K%,A%(K%*4%+J%)) FOR J%=0% TO 3%:PRINT:PRINT "ANSWER:";
130 GOSUB 900:M%=ASCII(M4$)-65%:GOTO 130 IF M%<0% OR M%>3%:
	PRINT M4$;
140 IF A%(K%*4%+M%)=Q%(K%) THEN PRINT "          CORRECT!":X1%=X1%+1%:GOTO 300
150 PRINT "          WRONG -- THE CORRECT ANSWER IS ";:PRINT CHR$(65%+J%);
	 IF A%(K%*4%+J%)=Q%(K%) FOR J%=0% TO 3%:PRINT ".":GOTO 300
160 PRINT "*"+TAB(5%);LEFT(A$,62%);TAB(70%);"*":RETURN
300 NEXT K%
310 PRINT:PRINT:PRINT "THAT COMPLETES YOUR FINAL EXAM ON FRACTIONS, ";
	N$;".  YOUR":PRINT "GRADE ON THIS TEST IS:":PRINT
320 G$=CHR$(74%-X1%):G$="A+" IF X1%=10%:G$="F" IF X1%<6%:
	PRINT TAB(20%);G$:PRINT:PRINT
325 G$="F" IF C9%>0%
335 GOSUB 1800:PRINT:PRINT "*";FOR K%=1% TO 71%:PRINT
340 A$="":GOSUB 160:GOSUB 160:GOSUB 160:A$=SPACE$(T%)+"DIPLOMA":
	GOSUB 160:A$="":GOSUB 160:GOSUB 160
345 A$="THIS CERTIFIES THAT:":GOSUB 160:A$="":GOSUB 160:GOSUB 160
350 A%=T%+4%-(LEN(N$)+1%)/2%:A$=SPACE$(A%)+N$:GOSUB 160:A$="":
	GOSUB 160:GOSUB 160
360 A$="HAS COMPLETED ALL ELEVEN PROGRAMS IN THE SECOND EDITION OF":
	GOSUB 160:A$="THE PDP-11 SERIES OF FRACTION PROGRAMS, "+
	"COMPLETING THE FINAL":GOSUB 160
365 A$="EXAM WITH A GRADE OF:":GOSUB 160:A$="":GOSUB 160:GOSUB 160:
	A$=SPACE$(T%+2%)+"-"+G$+"-":GOSUB 160
370 A$="":GOSUB 160:GOSUB 160
400 A$="THIS IMPORTANT DOCUMENT WAS SIGNED, SEALED, AND DELIVERED:":
	GOSUB 160:A$="":GOSUB 160:GOSUB 160
405 A$=SPACE$(T%-1%)+DATE$(0%):GOSUB 160:A$="":GOSUB 160:GOSUB 160
410 GOSUB 160:GOSUB 160:A$="BOB HUNTSMAN"+SPACE$(T1%)+"J. A. CHRISTENSEN":
	GOSUB 160
420 A$="------------"+SPACE$(T1%)+"-----------------":GOSUB 160
425 A$="   AUTHOR   "+SPACE$(T1%)+"   BIG BOSS":GOSUB 160
430 A$="":GOSUB 160:GOSUB 160:GOSUB 160:A$="MARILYN MANNING"+
	SPACE$(T1%-3%)+"DARRYL WILLIAMS":GOSUB 160
435 A$="---------------"+SPACE$(T1%-3%)+"---------------":GOSUB 160
440 A$=" PROOF READER  "+SPACE$(T1%-3%)+"   THE WHEEL":GOSUB 160:
	A$="":GOSUB 160 FOR K%=1% TO 3%
445 A$=SPACE$(T1%/2%+4%)+"CONNIE BRYNGELSON":GOSUB 160:
	A$=SPACE$(T1%/2%+4%)+"-----------------":GOSUB 160
447 A$=SPACE$(T1%/2%+4%)+"INSPECTOR GENERAL":GOSUB 160
450 A$="":GOSUB 160 FOR K%=1% TO 3%:PRINT "*";FOR K%=1% TO 71%:PRINT:
	PRINT:PRINT
480 GOTO 32767
500 FOR A%=0% TO 3%
510 B%(A%)=FNR%:GOTO 510 IF B%(A%)=B%(B%) FOR B%=0% TO A%-1%:NEXT A%:RETURN
520 DEF FNR%:V%=INT(1000%*RND):FNR%=V%-V%/4%*4%:FNEND
900 V9$=SYS(CHR$(3%)):GOSUB 29000:V9$=SYS(CHR$(2%)):RETURN
1000 DATA "WHAT IS THE GREATEST COMMON FACTOR OF ","REDUCE "," "
1010 DATA "WHAT IS THE LEAST COMMON MULTIPLE OF "," "," "," ",
	"THE RECIPROCAL OF "
1020 DATA "THE RELATIONSHIP BETWEEN THE INVERSE AND THE RECIPROCAL IS:"," "
1040 DATA "42 AND 63?","36 AND 63?","22 AND 55?","48 AND 60?"
1050 DATA "24/30","21/49","12/20","36/63"
1060 DATA "3/4 + 2/4 =","12/5 + 6/5 =","2/2 + 1/2 =","8/6 + 5/6 ="
1070 DATA "27 AND 36?","24 AND 32?","9 AND 12?","20 AND 25?"
1080 DATA "1/5 =","2/3 =","3/7 =","5/6 ="
1090 DATA "3/4 + 2/5 =","1/2 + 2/3 =","5/6 + 2/7 =","2/3 + 4/7 ="
1100 DATA "3/4 X 2/5 =","1/2 X 2/3 =","5/6 X 2/7 =","2/3 X 4/7 ="
1110 DATA "1/2 IS:","2 IS:","4 IS:","1/4 IS:"
1120 DATA " "," "," "," "
1130 DATA "1/3 DIVIDED BY 2/3","1 DIVIDED BY 1/2","1/7 DIVIDED BY 1/4",
	"1 DIVIDED BY 1/4"
1140 DATA "7","9","11","12"
1150 DATA "4/5","3/7","3/5","4/7"
1160 DATA "1 1/4","3 3/5","1 1/2","2 1/6"
1170 DATA "108","96","36","100"
1180 DATA "3/15","12/18","9/21","10/12"
1190 DATA "1 3/20","1 1/6","1 5/42","1 5/21"
1200 DATA "3/10","1/3","5/21","8/21"
1210 DATA "2","1/2","1/4","4"
1220 DATA "THE RECIPRICAL IS ALWAYS GREATER",
	"THE INVERSE IS ALWAYS GREATER","THEY ARE ALWAYS EQUAL",
	"NONE OF THE ABOVE CONCLUSIONS IS ALWAYS TRUE"
1230 DATA "1/2","2","4/7","4"
1800 PRINT "ANSWER THE FOLLOWING QUESTIONS WITH 'Y' FOR YES.":
	PRINT:PRINT
1810 PRINT "DO YOU SWEAR TO ANSWER THE FOLLOWING QUESTIONS WITH THE TRUTH"
1815 PRINT "THE WHOLE TRUTH AND NOTHING BUT THE TRUTH? ";
1817 GOSUB 900:GOTO 1817 IF M4$<>"Y":PRINT M4$
1820 PRINT "HAVE YOU COMPLETED ALL ELEVEN PROGRAMS IN THIS SERIES? ";:
	GOSUB 900:B$=M4$+""
1822 PRINT M4$
1825 GOTO 32767 IF B$<>"Y":PRINT:PRINT "STATE YOUR FULL NAME, ";
	"INCLUDING YOUR MIDDLE INITIAL, FIRST NAME FIRST:":PRINT
1830 INPUT #1%,"(CR)---> ";N$:PRINT:PRINT
1840 RETURN
29000 GOTO 29100 IF M3%=Z3%:M4$=M3$(M3%):M3%=M3%+1%:RETURN
29100 M3%=0%:V9$=SYS(CHR$(4%)):GET #1%:Z3%=RECOUNT:GOTO 29000
32767 END