1 ! PROGRAM NAME --> F R A C A D  -- BY BOB HUNTSMAN
11 DIM B2$(3%),B2%(3%):B2$(1%)="LET'S START WITH":B2$(2%)=
	"NOW SOME":B2$(3%)="FINALLY, SOME":B2%(1%)=5%:B2%(2%)=3%:
	B2%(3%)=2%:B2%(0%)=5%:B%=0%
12 OPEN "KB:" AS FILE 1%:INPUT #1%,"NAME PLEASE (CR)---> ";N$:
	V9$=SYS(CHR$(3%)):FIELD #1%,K% AS Q$,1% AS M3$(K%)
	 FOR K%=0% TO 10%:RANDOM
31 DIM B$(7%):B$(1%)="EASY":B$(2%)="MEDIUM":B$(3%)="HARD":
	B$(4%)="WRONG":B$(5%)="RIGHT":B$(6%)="LOW":B$(7%)="HIGH"
46 DIM H%(15%):H%(1%)=1%:H%(K%)=2% FOR K%=2% TO 5%
47 H%(6%)=1%:H%(K%)=3% FOR K%=7% TO 10%
48 PRINT:PRINT "ENTER 'I' FOR INSTRUCTIONS: ";:GOSUB 29000:
	PRINT M4$:GOTO 135 IF M4$<>"I"
50 PRINT:PRINT "THE REQUIREMENTS ARE:":PRINT
55 PRINT "YOU MUST ANSWER 5 EASY PROBLEMS, 3 MEDIUM ";
	"PROBLEMS, AND 2 HARD"
56 H%(11%)=1%:H%(K%)=5% FOR K%=12% TO 15%
60 PRINT "PROBLEMS.  YOU'LL BE GIVEN THREE TRIES TO ANSWER EACH ";
	"PROBLEM; HOWEVER"
65 PRINT "ONLY PROBLEMS ANSWERED CORRECTLY THE FIRST TRY ARE ";
	"SCORED AS CORRECT"
70 PRINT "ANSWERS.  YOU MUST GET 80% OF THE EASY ONES CORRECT, 70% ";
	"OF THE MEDIUM"
75 PRINT "ONES CORRECT AND 50% OF THE HARD ONES CORRECT (THEY ARE ";
	"R E A L L Y"
85 PRINT "HARD) IN ORDER TO PASS.  IF YOU PASS, THE COMPUTER WILL TELL";
	" YOU AND"
90 PRINT "ALLOW YOU TO GO ON THE NEXT PROGRAM.  BY THE WAY, IF YOU ";
	"WANT TO KNOW":PRINT "HOW ";
95 PRINT "YOU'RE DOING ENTER '?' WHEN ASKED FOR YOUR ANSWER.  IF YOU ";
	"GIVE UP,"
100 PRINT "ENTER 'Q' FOR YOUR ANSWER AND THE PROGRAM WILL TERMINATE!!":
	PRINT:PRINT
110 PRINT "IF THE PROGRAM PRINTS OUT '(CR)--->', THAT MEANS YOU MUST":
	PRINT "HIT THE RETURN KEY AFTER YOU INPUT YOUR ANSWER.  IF ";
	"THAT IS":PRINT "NOT THERE, YOU NEED NOT HIT THE 'RETURN' KEY!!"
	:PRINT
111 RANDOM:GOTO 135
130 GOTO 1300 IF X%(B%+3%)=0%:GOTO 1300 IF B2%(B%)>X%(B%):
	GOTO 1300 IF 100%*X%(B%)/X%(B%+3%)<35%+15%*(4%-B%)
135 GOTO 1200 IF B%=3%:B%=B%+1%:PRINT:PRINT B2$(B%);" ";B$(B%);" ONES:":
	PRINT:GOTO 130
140 PRINT:PRINT "'N' FOR NONE, 'E' FOR EASY, 'M' FOR MEDIUM, OR 'H'";
	" FOR HARD!":PRINT:E1%=1%:GOTO 130
170 PRINT:INPUT "NUMBER OF PROBLEMS";X1%:X%=0%:GOTO 1300
200 GOTO 130 IF F6%=0%:F6%=0%:GOTO 230 IF B%:PRINT
	"GO BACK AND REDO PROGRAM #3, R E D U C E !!!":
	GOTO 32000
230 PRINT "REDO THE ";B$(B%);" PROBLEMS!!":
	X%(B%),X%(B%+3%),X%(B%+1%),X%(B%+4%)=0%:GOTO 200
500 U8%=U8%+1%:PRINT:PRINT N$;", HERE IS SOME HELP.  WHEN YOU WANT TO ";
	"ADD FRACTIONS":PRINT "WITH THE SAME DENOMINATOR, YOU JUST ";
	"ADD THE NUMERATORS AND":PRINT "LEAVE THE DENOMINATOR!!":
	PRINT:RETURN
555 GOTO 560 IF X3%=0%:U7%=1% IF 100%*U6%/X3%>30%
640 DEF FNN$(V%)=MID(NUM$(V%),2%,LEN(NUM$(V%))-2%)
800 X3%=X3%+1%:H5%=H5%+1% IF B%=3%:X%=X%+1%:X%(B%+3%)=X%(B%+3%)+1%:
	X%(B%)=X%(B%)+1% IF E%=3%
810 RETURN IF E%=3% OR X%(B%+3%)<3%+B2%(B%):F6%=1%:PRINT
	:B%=B%-1%:PRINT N$;" -- YOU ARE NOT DOING VERY WELL ON ";
	"THESE PROBLEMS.  YOU MUST":RETURN
900 D%=0%:FOR K1%=1% TO 4%
910 GOSUB 29000:GOTO 920 IF M4$="?":GOTO 940 IF M4$="Q":
	M%=ASCII(M4$):GOTO 910 IF (M%=13% OR M%=32%) AND D%=0%:RETURN
	IF M%=13% OR M%=32%:GOTO 910 IF M%<48% OR M%>57%:
	D%=D%*10%+M%-48%:PRINT M4$;:NEXT K1%:RETURN  
920 F4%=0%:F4%=1% IF X%(K%) FOR K%=4% TO 6%:GOTO 910 IF F4%=0%
930 X%=POS(1%):PRINT M4$;:A1%=A%:B1%=B%:GOSUB 32005:A%=A1%:B%=B1%:
	PRINT TAB(X%-4%);"---> ";:GOTO 900
940 PRINT:PRINT:PRINT "SORRY, ";N$;" -- YOU DO NOT PASS. . .":
	GOTO 32000
1000 DEF FNR%(V%,V1%)
1010 V2%=V1%-V%+1%:V3%=INT(1000%*RND):V3%=V3%-V3%/V2%*V2%+V%:FNR%=V3%
1020 FNEND
1100 DEF FNX%=X%(1%)+X%(2%)+X%(3%)
1200 PRINT:PRINT "CONGRATULATIONS, ";N$;".  YOU HAVE SUCCESSFULLY PASSED"
1210 PRINT "THE REQUIREMENTS OF THIS PROGRAM!!  YOU NOW MAY GO ON TO
1220 PRINT "THE NEXT PROGRAM NAMED -IMPROP-!!":PRINT:GOTO 32000
1300 H%=2%:I%=12%:IF B%=2% THEN H%=6%:I%=18%
1305 E%=3%:IF B%=3% THEN H%=12%:I%=25%
1310 A%=FNR%(H%,I%):B3%=FNR%(H%,I%):IF A%>B3% THEN F%=A%:A%=B3%:B3%=F%
1315 F%=FNR%(3%*B%-2%,3%*B%+3%):GOTO 1315 IF B3%*F%>B%^2%*20%:
	A%=A%*F%:B3%=B3%*F%:C%=FNC%(A%,B3%)
1320 X5%=FNR%(1%,A%-1%):PRINT:PRINT "ADD!":PRINT:PRINT "    ";
	FNN$(A%-X5%);TAB(12%);FNN$(X5%)
1325 PRINT "    ";:L%=LEN(FNN$(B3%)):PRINT "-";FOR K%=1% TO L%:
	PRINT TAB(8%);"+";TAB(12%);:PRINT "-";FOR K%=1% TO L%
1330 PRINT:PRINT "    ";FNN$(B3%);TAB(12%);FNN$(B3%);TAB(20%);
	"ENTER ANSWER BELOW:"
1335 PRINT:PRINT "NUMERATOR   (CR)---> ";:GOSUB 900:PRINT:
	A5%=D%
1340 PRINT TAB(21%);:PRINT "-";FOR K%=1% TO L%:PRINT:PRINT
	"DENOMINATOR (CR)---> ";:GOSUB 900:B5%=D%:PRINT TAB(25%);
1345 D%=FNC%(A5%,B5%):GOTO 1550 IF A5%*C%=A% AND B5%*C%=B3%
1350 IF A5%*C%=A%*D% AND B5%*C%=B3%*D% THEN 1500 ELSE PRINT
	"NO, ";N$;", THAT IS WRONG!!!!!":GOSUB 500 IF U8%<3%
1355 IF E%>1% THEN PRINT "TRY AGAIN! [";FNN$(A%-X5%);"/";
	FNN$(B3%);" + ";FNN$(X5%);"/";FNN$(B3%);"].":PRINT:
	E%=E%-1%:GOTO 1335
1360 PRINT "SORRY -- THREE TRIES IS ALL YOU GET!!"
1365 PRINT "THE CORRECT ANSWER IS ";FNN$(A%/C%);"/";FNN$(B3%/C%);"."
1370 GOSUB 800:GOTO 200
1500 PRINT "VERY GOOD -- NOW YOU MUST REDUCE IT!!":PRINT:PRINT
1502 A6%=A5%:B6%=B5%
1505 PRINT "NUMERATOR   (CR)---> ";:GOSUB 900:A5%=D%:PRINT:
	PRINT TAB(21%);:L%=LEN(FNN$(B3%/C%)):PRINT "-";
	FOR K%=1% TO L%:PRINT
1515 PRINT "DENOMINATOR (CR)---> ";:GOSUB 900:B5%=D%:PRINT TAB(25%);
1520 IF A5%*C%=A% AND B5%*C%=B3% THEN 1550 ELSE 1560
1550 PRINT "CORRECT!!":GOSUB 800:GOTO 200
1560 GOTO 1360 IF E%<2%:D%=FNC%(A5%,B5%):GOTO 1580 IF A5%*B3%=A%*B5%
1565 PRINT "NO, ";N$;" -- THAT'S NOT EQUIVALENT TO WHAT":PRINT TAB(25%);
	"YOU HAD BEFORE!!":GOTO 1590
1580 PRINT "SORRY, ";N$;" -- THAT'S NOT COMPLETELY":PRINT TAB(25%);
	"REDUCED!!"
1590 PRINT:PRINT "TRY AGAIN ! [";FNN$(A6%);"/";FNN$(B6%);"]":PRINT:
	PRINT:E%=E%-1%:GOTO 1505
1600 DEF FNC%(V%,V1%)
1610 E9%=1%:D5%=0%
1625 D5%=D5%+2%:D5%=3% IF D5%=4%:IF D5%>V% OR D5%>V1% THEN FNC%=E9%:GOTO 1640
1630 IF V%/D5%*D5%=V% AND V1%/D5%*D5%=V1% THEN E9%=E9%*D5%:
	V%=V%/D5%:V1%=V1%/D5%:GOTO 1630
1635 V%=FNQ%(V%,D5%):V1%=FNQ%(V1%,D5%):GOTO 1625
1640 FNEND
1660 DEF FNQ%(V2%,V3%)
1665 IF V2%/V3%=V3%=V2% THEN V2%=V2%/V3%:GOTO 1665
1670 FNQ%=V2%
1675 FNEND
29000 GOTO 29100 IF M3%=Z3%:M4$=M3$(M3%):M3%=M3%+1%:RETURN
29100 M3%=0%:V9$=SYS(CHR$(4%)):GET #1%:Z3%=RECOUNT:GOTO 29000
32000 PRINT:PRINT "ADDING FRACTIONS WITH COMMON DENOMINATORS":F3%=1%
32005 U$="\    \ - ## OUT OF ## ---> ###%":V9$=SYS(CHR$(2%))
	UNLESS F3%=0%
32007 PRINT:PRINT N$;" -- HERE ARE YOUR SCORES:":PRINT
32010 FOR K%=1% TO 3%:GOTO 32100 IF X%(K%+3%)=0%:PRINTUSING U$,
	B$(K%),X%(K%),X%(K%+3%),100%*X%(K%)/X%(K%+3%)
32100 NEXT K%
32220 B%=0%:B%=B%+X%(K%) FOR K%=4% TO 6%:A%=0%:A%=A%+X%(K%) 
       FOR K%=1% TO 3%:A%=100%*A%/B%
32225 IF F3%=0% THEN PRINT:PRINT "CUMULATIVE-->";A%:PRINT:RETURN
32230 B%=0%:B%=1% IF A%>60%:B%=2% IF A%>89%:DIM Z$(2%)
32240 Z$(0%)=", YOU DEFINITELY NEED MUCH MORE"
	+ " PRACTICE!!":Z$(1%)=", YOU DID ABOUT AVERAGE"
	+ " -- BUT YOU STILL NEED MORE PRACTICE!!"
32250 Z$(2%)=" -- GREAT -- YOU SEEM TO UNDERSTAND"
	+ " THESE PROBLEMS VERY WELL!!"
32260 A$=NUM$(A%):PRINT:PRINT "YOUR CUMULATIVE SCORE IS";
       LEFT(A$,LEN(A$)-1%);"%.":PRINT
32270 PRINT N$+Z$(B%):PRINT
32767 END