1 ! PROGRAM NAME --> I N V R S E  -- BY BOB HUNTSMAN
11 DIM B2$(3%),B2%(3%):B2$(1%)="LET'S START WITH":B2$(2%)=
	"NOW SOME":B2$(3%)="FINALLY, SOME":B2%(1%)=5%:B2%(2%)=3%:
	B2%(3%)=2%:B2%(0%)=5%:B%=0%
12 OPEN "KB:" AS FILE 1%:INPUT #1%,"NAME PLEASE (CR)---> ";N$:
	V9$=SYS(CHR$(3%)):FIELD #1%,K% AS Q$,1% AS M3$(K%)
	 FOR K%=0% TO 10%:RANDOM
27 DIM B$(7%):B$(1%)="EASY":B$(2%)="MEDIUM":B$(3%)="HARD":
	B$(4%)="WRONG":B$(5%)="RIGHT":B$(6%)="LOW":B$(7%)="HIGH"
30 PRINT "ENTER 'I' FOR INSTRUCTIONS:";:GOSUB 29000:PRINT M4$:GOTO 135
	IF M4$<>"I"
50 PRINT:PRINT "THE REQUIREMENTS ARE:":PRINT
55 PRINT "YOU MUST ANSWER 5 EASY PROBLEMS, 3 MEDIUM ";
	"PROBLEMS, AND 2 HARD"
60 PRINT "PROBLEMS.  YOU'LL BE GIVEN THREE TRIES TO ANSWER EACH ";
	"PROBLEM; HOWEVER"
65 PRINT "ONLY PROBLEMS ANSWERED CORRECTLY THE FIRST TRY ARE ";
	"SCORED AS CORRECT"
70 PRINT "ANSWERS.  YOU MUST GET 80% OF THE EASY ONES CORRECT, 70% ";
	"OF THE MEDIUM"
75 PRINT "ONES CORRECT AND 50% OF THE HARD ONES CORRECT (THEY ARE ";
	"R E A L L Y"
85 PRINT "HARD) IN ORDER TO PASS.  IF YOU PASS, THE COMPUTER WILL TELL";
	" YOU AND"
90 PRINT "ALLOW YOU TO GO ON THE NEXT PROGRAM.  BY THE WAY, IF YOU ";
	"WANT TO KNOW":PRINT "HOW ";
95 PRINT "YOU'RE DOING ENTER '?' WHEN ASKED FOR YOUR ANSWER.  IF YOU ";
	"GIVE UP,"
100 PRINT "ENTER 'Q' FOR YOUR ANSWER AND THE PROGRAM WILL TERMINATE!!":
	PRINT:PRINT
110 PRINT "IF THE PROGRAM PRINTS OUT '(CR)--->', THAT MEANS YOU MUST":
	PRINT "HIT THE RETURN KEY AFTER YOU INPUT YOUR ANSWER.  IF ";
	"THAT IS":PRINT "NOT THERE, YOU NEED NOT HIT THE 'RETURN' KEY!!"
	:PRINT
111 RANDOM:GOTO 135
130 GOTO 1300 IF X%(B%+3%)=0%:GOTO 1300 IF B2%(B%)>X%(B%):
	GOTO 1300 IF 100%*X%(B%)/X%(B%+3%)<35%+15%*(4%-B%)
135 Q9%=Q9%+1%:GOTO 136 IF Q9%<>1%:PRINT "ENTER 'D' FOR BRIEF ";
	"DISCUSSION:";:GOSUB 29000:PRINT M4$:GOTO 1375
	IF M4$="D"
136 GOTO 1200 IF B%=3%:B%=B%+1%:PRINT:PRINT B2$(B%);" ";B$(B%);" ONES:":
	PRINT:GOTO 130
200 GOTO 130 IF F6%=0%:F6%=0%:GOTO 230 IF B%:PRINT
	"GO BACK AND REDO PROGRAM #9, F R A C M T !!!":
	GOTO 32000
230 PRINT "REDO THE ";B$(B%);" PROBLEMS!!":
	X%(B%),X%(B%+3%),X%(B%+1%),X%(B%+4%)=0%:GOTO 200
640 DEF FNN$(V%)=MID(NUM$(V%),2%,LEN(NUM$(V%))-2%)
670 DEF FNL$:V$="":V%=A%:V%=B3% IF B3%>A%:V%=LEN(FNN$(V%)):
	V$=V$+"-" FOR V1%=1% TO V%:FNL$=V$:FNEND
800 X3%=X3%+1%:H5%=H5%+1% IF B%=3%:X%=X%+1%:X%(B%+3%)=X%(B%+3%)+1%:
	X%(B%)=X%(B%)+1% IF E%=3%
810 RETURN IF E%=3% OR X%(B%+3%)<3%+B2%(B%):F6%=1%:PRINT
	:B%=B%-1%:PRINT N$;" -- YOU ARE NOT DOING VERY WELL ON ";
	"THESE PROBLEMS.  YOU MUST":RETURN
900 D%=0%:D1%=INT(LOG10(C1%))+1%:FOR K1%=1% TO D1%
910 GOSUB 29000:GOTO 920 IF M4$="?":GOTO 940 IF M4$="Q":
	M%=ASCII(M4$):GOTO 910 IF (M%=13% OR M%=32%) AND D%=0%:RETURN
	IF M%=13% OR M%=32%:GOTO 910 IF M%<48% OR M%>57%:
	D%=D%*10%+M%-48%:PRINT M4$;:NEXT K1%:RETURN  
920 F4%=0%:F4%=1% IF X%(K%) FOR K%=4% TO 6%:GOTO 910 IF F4%=0%
930 X%=POS(1%):PRINT M4$;:A1%=A%:B1%=B%:GOSUB 32005:A%=A1%:B%=B1%:
	PRINT TAB(X%-4%);"---> ";:GOTO 900
940 PRINT:PRINT:PRINT "SORRY, ";N$;" -- YOU DO NOT PASS. . .":
	GOTO 32000
1000 DEF FNR%(V%,V1%)
1010 V2%=V1%-V%+1%:V3%=INT(1000%*RND):V3%=V3%-V3%/V2%*V2%+V%:FNR%=V3%
1020 FNEND
1100 DEF FNX%=X%(1%)+X%(2%)+X%(3%)
1200 PRINT:PRINT "CONGRATULATIONS, ";N$;".  YOU HAVE SUCCESSFULLY PASSED"
1210 PRINT "THE REQUIREMENTS OF THIS PROGRAM!!  YOU NOW MAY GO ON TO
1220 PRINT "THE LAST PROGRAM, NAMED -FRACDV-.":PRINT:GOTO 32000
1300 H%=2%:I%=39%:IF B%=2% THEN H%=40%:I%=90%
1305 IF B%=3% THEN H%=91%:I%=150%
1315 A%=FNR%(H%,I%):B3%=FNR%(H%,I%):C%=FNC%(A%,B3%):A%=A%/C%:B3%=B3%/C%
1319 DIM R$(1%):R$(0%)="INVERSE":R$(1%)="RECIPROCAL":E%=3%
1320 R%=FNR%(0%,1%):PRINT "WHAT IS THE ";R$(R%);" OF:"
1325 PRINT TAB(10%);FNN$(A%):PRINT TAB(10%);FNL$:PRINT TAB(10%);
	FNN$(B3%);TAB(20%);"ENTER ANSWER BELOW:":PRINT
1330 PRINT "NUMERATOR:";TAB(16%);:C1%=B3%:GOSUB 900:A2%=D%:PRINT:
	PRINT TAB(16%);FNL$:PRINT "DENOMINATOR:";TAB(16%);:
	C1%=A%:GOSUB 900:B2%=D%:PRINT TAB(20%);
1335 IF A%=B2% AND A2%=B3% THEN PRINT "CORRECT!!":PRINT:PRINT
	"THAT WASN'T SO HARD, WAS IT ";N$;"." IF F1%=1%:PRINT
	IF F1%=1%:F1%=0%:GOSUB 800:GOTO 200
1340 PRINT "WRONG";:E%=E%-1%:PRINT " -- TRY AGAIN";IF E%:PRINT "!!":
	PRINT:GOTO 1330 IF E%:GOTO 1370
1370 PRINT:PRINT "SORRY, ";N$;", BUT THREE GUESSES IS ALL YOU GET!!":
	PRINT:PRINT
1375 PRINT:PRINT "YOU SEE, ";N$;", THE INVERSE -- MORE PRECISELY ";
	"CALLED THE":PRINT "RECIPROCAL -- OF A NUMBER IS THE NUMBER ";
	"WHEN MULTIPLIED"
1380 PRINT "BY THE ORIGINAL NUMBER WILL EQUAL 1.  FOR EXAMPLE, 1/2 ";
	"TIMES TWO":PRINT "EQUALS 1/1 WHICH EQUALS 1, SO 1/2 ";
	"IS THE RECIPROCAL OF 2."
1385 PRINT "2 IS ALSO THE RECIPROCAL OF 1/2.  THE EASY WAY TO FIND ";
	"RECIPROCALS"
1390 PRINT "WHEN THE NUMBERS ARE IN FRACTION FORM IS TO SIMPLY TURN";
	" THE ORIGINAL":PRINT "FRACTION UPSIDE DOWN -- PUT THE ";
	"NUMERATOR IN THE":PRINT "DENOMINATOR AND THE DENOMINATOR ";
	"IN THE NUMERATOR!!"
1392 GOTO 135 IF Q9%=1%
1395 PRINT:PRINT:F1%=1%:GOTO 1400 IF X%>=X1%:
	PRINT "LET'S GO ON TO THE NEXT ONE!!":GOTO 1410
1400 PRINT:PRINT N$;", TRY SOME MORE, OK?"
1410 PRINT:PRINT:E%=E%-1%:GOSUB 800:GOTO 200
1600 DEF FNC%(V%,V1%)
1610 E9%=1%:D5%=0%
1625 D5%=D5%+2%:D5%=3% IF D5%=4%:
	IF D5%>V% OR D5%>V1% THEN FNC%=E9%:GOTO 1640
1630 IF V%/D5%*D5%=V% AND V1%/D5%*D5%=V1% THEN E9%=E9%*D5%:V%=V%/D5%:
	V1%=V1%/D5%:GOTO 1630
1635 V%=FNQ%(V%,D5%):V1%=FNQ%(V1%,D5%):GOTO 1625
1640 FNEND
1660 DEF FNQ%(V2%,V3%)
1665 IF V2%/V3%=V3%=V2% THEN V2%=V2%/V3%:GOTO 1665
1670 FNQ%=V2%
1675 FNEND
29000 GOTO 29100 IF M3%=Z3%:M4$=M3$(M3%):M3%=M3%+1%:RETURN
29100 M3%=0%:V9$=SYS(CHR$(4%)):GET #1%:Z3%=RECOUNT:GOTO 29000
32000 PRINT:PRINT "INVERSE - RECIPROCAL PROGRAM":F3%=1%
32005 U$="\    \ - ## OUT OF ## ---> ###%":V9$=SYS(CHR$(2%))
	UNLESS F3%=0%
32007 PRINT:PRINT N$;" -- HERE ARE YOUR SCORES:":PRINT
32010 FOR K%=1% TO 3%:GOTO 32100 IF X%(K%+3%)=0%:PRINTUSING U$,
	B$(K%),X%(K%),X%(K%+3%),100%*X%(K%)/X%(K%+3%)
32100 NEXT K%
32220 B%=0%:B%=B%+X%(K%) FOR K%=4% TO 6%:A%=0%:A%=A%+X%(K%) 
       FOR K%=1% TO 3%:A%=100%*A%/B%
32225 IF F3%=0% THEN PRINT:PRINT "CUMULATIVE-->";A%:PRINT:RETURN
32230 B%=0%:B%=1% IF A%>60%:B%=2% IF A%>89%:DIM Z$(2%)
32240 Z$(0%)=", YOU DEFINITELY NEED MUCH MORE"
	+ " PRACTICE!!":Z$(1%)=", YOU DID ABOUT AVERAGE"
	+ " -- BUT YOU STILL NEED MORE PRACTICE!!"
32250 Z$(2%)=" -- GREAT -- YOU SEEM TO UNDERSTAND"
	+ " THESE PROBLEMS VERY WELL!!"
32260 A$=NUM$(A%):PRINT:PRINT "YOUR CUMULATIVE SCORE IS";
       LEFT(A$,LEN(A$)-1%);"%.":PRINT
32270 PRINT N$+Z$(B%):PRINT
32767 END