05 REM - PROGRAM NAME: "EXP001"
10 REM - THIS PROGRAM READS IN PURCHASE ORDER AND INVOICE
     CARDS, FORMATS THEM INTO TRANSACTION RECORDS AND ADDS
     THEM TO THE TRANSACTION FILE.
30 OPEN "DF:TRANS.NEW" AS FILE 2
35 DIM #2,B$(5000)=46
40 OPEN "CR:" FOR INPUT AS FILE 3
45 FIELD #3, 80 AS S$
50 OPEN "LP:" FOR OUTPUT AS FILE 4
60 FOR X=1 TO 4000
70 LET A$=B$(X)
75 IF MID(A$,1,7)="9999999" THEN 210
90 NEXT X
210 PRINT #4,"LISTING OF PURCHASE ORDERS AND INVOICES ";
     DATE$(0)
220 PRINT #4, CHR$(10)         !SKIP A LINE
230 ON ERROR GOTO 640 
240 LET J=X            !X IS POINTER TO NEXT SPOT IN V.C.
250 FOR J=J TO 5000
270 GET #3
300 LET J$=MID(S$,42,7)
310 LET K$=MID(S$,3,4)
320 LET L$=MID(S$,80,1)
330 LET M$=MID(S$,7,8)          !INVOICE NUMBER
340 IF L$="0" THEN 600
350 IF L$="1" GOTO 360
355 IF L$="2" GOTO 360            !PREPAID INVOICE
356 IF L$="3" THEN 360
357 GOTO 500                      !UNDEFINED TRAN CODE
360 LET N$=MID(S$,15,7)       !DATE OF INVOICE
370 LET O$="0000000"
380 LET P$=MID(S$,35,7)    !CURRENT INVOICE AMT
390 LET Q$=MID(S$,76,4)         !VENDOR NUMBER
400 LET R$="0"                  !CLEAR STATUS
410 LET B$(J)=J$+K$+L$+M$+N$+O$+P$+Q$+R$
415 PRINT #4,J$;K$;L$,M$,N$,P$,Q$
420 GOTO 520
500 PRINT "INVALID IDENT IN COL 80"
510 PRINT S$
520 NEXT J
600 LET N$=MID(S$,35,7)
610 LET O$="       "         !BLANK OUT INVOICE AMT
620 LET P$="0000000"
630 GOTO 390
640 IF ERR=13 THEN 750        !PICK CHECK
650 IF ERR=11 THEN 700          !EOF
660 IF ERR=14 THEN 750        !HOPPER FULL
680 PRINT "ERROR =";ERR
690 GOTO 740
700 LET J$="9999999"
720 LET B$(J)=J$+K$+L$+M$+N$+O$+P$+"9999"+R$
730 CLOSE 2,3,4
740 STOP
750 SLEEP(20)
760 RESUME 270
770 END