10 REM - PROGRAM NAME* "EXP003"
      PRODUCES A VOUCHER LISTING
15 LET S%=0
16 LET E$="1"
20 OPEN "DF:TRANS.NEW" AS FILE 1
25 OPEN "DF:VENDOR" AS FILE 3
30 DIM #1,A$(5000)=46
35 DIM #3,F$(2000)=118
40 OPEN "LP:" FOR OUTPUT AS FILE 2
45 GOTO 75
50 PRINT #2,SPACE$(20);"NORTH COUNTRY UNION HIGH SCHOOL"
51 IF S%=0 THEN LET G$="UNPAID INVOICES" ELSE 
     LET G$="PREPAID INVOICES"
53 PRINT #2, SPACE$(28);G$
54 PRINT #2, CHR$(10)
56 PRINT #2,
     SPACE$(16);"SCHOOL DIRECTORS VOUCHER #:        DATE:";
     DATE$(0)
60 PRINT #2,CHR$(10)
70 PRINT #2,
     "P.O.#   INVOICE #   ACCT CODE   VENDOR #   AMOUNT $";
   "      VENDOR NAME"
71 LET C%=8
72 LET T=0.0
73 RETURN
75 GOSUB 50
80 FOR X=1 TO 5000
90 LET S$=A$(X)
95 IF MID(S$,1,7)="9999999" THEN 208
100 LET L$=MID(S$,12,1)
105 IF L$="0" GOTO 200
107 LET R$=MID(S$,46,1)
108 IF R$="8" THEN 200
110 IF L$="1" AND S%=1 THEN 200
115 IF L$="2" AND S%=0 THEN 200
117 IF L$="3" GOTO 200         !DONT PROCESS PAYROLL ITEMS
118 IF C%=51 THEN GOSUB 210
120 LET J$=MID(S$,1,7)       !ACCT NO
130 LET K$=MID(S$,8,4)       !PO #
140 LET M$=MID(S$,13,8)      !INVOICE #
160 LET P$=MID(S$,35,7)
165 LET P=VAL(P$)
166 LET T=T+P
170 LET Q$=MID(S$,42,4)            !VENDOR NUMBER
175 LET X$=MID(P$,1,5)
176 LET Y$=MID(P$,6,2)
177 GOTO 400
180 LET B$=K$+SPACE$(4)+M$+SPACE$(5)+J$+SPACE$(6)+Q$+
     SPACE$(6)+X$+"."+Y$+SPACE$(5)+Z$
190 PRINT #2, B$
191 LET C%=C%+1
200 NEXT X
205 GOTO 900
208 GOSUB 210
209 GOTO 900
210 PRINT #2
220 LET T=T/100
250 PRINT #2,SPACE$(36);"TOTAL   ";
251 PRINT #2, USING "$$###,###.##",T
300 PRINT #2               !SKIP A LINE
310 PRINT #2, SPACE$(55);"FINANCE COMMITTEE"
330 PRINT #2
340 PRINT #2,
     SPACE$(41);"APPROVED:  -------------------------"
350 FOR J=1 TO 2
360 PRINT #2
370 PRINT #2,
     SPACE$(52);"-------------------------"
375 NEXT J
380 PRINT #2, CHR$(12)    !SKIP TO NEW PAGE
381 IF MID (S$,1,7)="9999999" GOTO 385
382 GOSUB 50 
385 RETURN
390 GOTO 900
400 LET Q%=0
405 LET Q%=Q%+1
420 LET V$=F$(Q%)
430 IF MID(V$,1,4)=Q$ THEN 700
440 IF MID(V$,1,4)="9999" GOTO 500
450 IF MID(V$,1,4)<>Q$ GOTO 405
460 STOP
500 PRINT "VENDOR NO ";Q$;" CANNOT BE FOUND"
600 LET Z$=SPACE$(21)
610 GOTO 180
700 LET Z$=MID(V$,5,21)
705 LET Q$=MID(S$,42,4)
710 GOTO 180
900 IF S%=1 GOTO 2000
910 LET S%=1
920 PRINT #2, CHR$(12)          !SKIP TO NEW PAGE
935 GOTO 75
2000 CLOSE 1,2
2010 STOP
2020 END